Discussion :

[guicad]

Bonsoir
J
Je suis débutant dans le vba j'ai réussi à faire la macro ci dessous qui fonctionne mais je souhaite insérer une boucle afin incrémenter automatiquement le numéro du signet du word associé à la ligne suivante d'excel 1. Signet1 =A1 ; Signet2=A2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub Macro2()
'
' Macro2 Macro
'
'Dim wordApp As Word.Application
'Dim wordDoc As Word.Document
 
Dim WordApp As Object
Dim WordDoc As Object
Dim i As Byte
 
Set WordApp = CreateObject("word.application") 'ouvre session word et le fichier voulu
Set WordDoc = WordApp.Documents.Open("C:\Users\G38055\Desktop\test.docx") 'ouvre document Word
WordApp.Visible = False 'word masqué pendant l'operation
 
'dans le document word, il faut avoir placé des signets aux endroits qu'on veut remplir
'à l'endroit de chaque signet qui se trouve dans le fichier word on va inscrire le contenu des cellules
WordDoc.Bookmarks("Signet1").Range.Text = Cells(1, 1)
'WordDoc.Bookmarks("nom du second signet").Range.Text = Cells(numéro de ligne, numéro de colonne)
 
 
WordApp.Visible = True 'affiche le document Word
'WordDoc.PrintOut 'si on veut imprimer
 
'WordDoc.Close True 'si on veut fermer le document word en sauvegardant les données
'WordApp.Quit 'ferme la session Word
End Sub

J'ai fait l'essai avec ce code mais je ça bloaque ici WordDoc.Bookmarks("Signet" & i).Range.Text = Cells(i, 1)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
Sub Macro2()
'
' Macro2 Macro
'
Dim WordApp As Object
Dim WordDoc As Object
Dim i As Byte
 
Set WordApp = CreateObject("word.application") 'ouvre session word et le fichier voulu
Set WordDoc = WordApp.Documents.Open("C:\Users\G38055\Desktop\test.docx") 'ouvre document Word
WordApp.Visible = False 'word masqué pendant l'operation
 
'dans le document word, il faut avoir placé des signets aux endroits qu'on veut remplir
'à l'endroit de chaque signet qui se trouve dans le fichier word on va inscrire le contenu des cellules
For i = 1 To 3
        'les signets du document Word sont nommés Signet1 , Signet2 , Signet3
        WordDoc.Bookmarks("Signet" & i).Range.Text = Cells(i, 1)
    Next i
'WordDoc.Bookmarks("nom du second signet").Range.Text = Cells(numéro de ligne, numéro de colonne)
 
 
WordApp.Visible = True 'affiche le document Word
'WordDoc.PrintOut 'si on veut imprimer
 
'WordDoc.Close True 'si on veut fermer le document word en sauvegardant les données
'WordApp.Quit 'ferme la session Word
End Sub

[clementmarcotte]

Bonjour,

Si c'est toujours le même document, tu peux t'éviter de te compliquer la vie. Tu te crées un modèle de document avec tes signets. Tu emplis ton document-modèle, puis tu enregistres sous un nouveau nom et tu n'enregistres pas tom modèle. Tes signets seront toujours là.

[Invité]

J'ai fait l'essai avec ce code mais je ça bloque ici WordDoc.Bookmarks("Signet" & i).Range.Text = Cells(i, 1)

Bonjour,

Dans votre code, Word ne sait pas à quoi fait référence Cells(i,1).

Essayez ce code qui fonctionne chez moi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
 
Sub MettreAJourLesSignets()
 
Dim OngletDesDonnees As Worksheet
 
Dim WordApp As Object
Dim WordDoc As Object
Dim i As Byte
 
    Set OngletDesDonnees = ActiveSheet
    Set WordApp = CreateObject("word.application") 'ouvre session word et le fichier voulu
    Set WordDoc = WordApp.Documents.Open("C:\Users\G38055\Desktop\test.docx") 'ouvre document Word
 
    WordApp.Visible = False 'word masqué pendant l'operation
 
    With OngletDesDonnees
         For i = 1 To 3
             WordDoc.Bookmarks("Signet" & i).Range.Text = .Cells(i, 1)
         Next i
    End With
 
 
    WordApp.Visible = True 'affiche le document Word
    'WordDoc.PrintOut 'si on veut imprimer
 
    'WordDoc.Close True 'si on veut fermer le document word en sauvegardant les données
    'WordApp.Quit 'ferme la session Word
 
    Set WordDoc = Nothing
    Set WordApp = Nothing
    Set OngletDesDonnees = Nothing
 
End Sub

[clementmarcotte]

Chez moi, les deux fonctionnent tel quel ou presque. (Office 2016)

À par la modification du nom de fichier et du chemin d'accès.

Et j'ai mis .value au bout du cells()

As-tu remis ton signet dans ton document entre tes "deux macros" ? Parce que la première macro s effacé le premier signet chez-moi. Et la deuxième a probablement effacé les trois signets.

[Invité]

Dans mon précédent code, je n'avais pas été jusqu'à la sauvegarde et je n'avais pas fait attention que le document conservait toutes les valeurs précédentes.
Dans le document exemple que j'ai généré, les signets n'englobaient pas de texte, c'étaient juste des points d'insertion. Ce qui fait qu'à chaque mise à jour, la valeur du fichier Excel était bien récupérée mais le texte existant n'était pas remplacé.

j'ai donc modifié le code pour que la sélection soit étendue après le point d'insertion. Le soucis c'est qu'en liaison tardive, les paramètres wdWord ou wdSaveChanges sont considérés comme des variables et le code ne fonctionne pas et je n'ai réussi à trouver une déclaration de substitution. J'ai donc référencé la DLL Microsoft Word et déclaré des variables Word (Application, Document, Selection) et là je n'ai pas eu de problème.

Code modifié est le suivant :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
 
Option Explicit
 
' Référencer la DLL Microsoft Word
 
Sub MettreAJourLesSignets()
 
Dim OngletDesDonnees As Worksheet
 
Dim WordApp As Word.Application
Dim WordDoc As Word.Document
Dim MaSelection As Word.Selection
 
'Dim WordApp As Object
'Dim WordDoc As Object
'Dim MaSelection As Object
 
Dim i As Byte
 
    Set OngletDesDonnees = ActiveSheet
    Set WordApp = CreateObject("word.application") 'ouvre session word et le fichier voulu
    WordApp.Visible = False 'word masqué pendant l'operation
    Set WordDoc = WordApp.Documents.Open("C:\Users\G38055\Desktop\test.docx") 'ouvre document Word
 
    With OngletDesDonnees
         For i = 1 To 3
            Set MaSelection = WordApp.Selection
            WordDoc.Bookmarks("Signet" & i).Select
            With MaSelection
                .Expand unit:=wdWord  'Si wdWord ne correspond pas à la sélection essayer unit:=Sentence ou unit:=Paragraph
                .Range.Text = OngletDesDonnees.Cells(i, 1).Value
            End With
            Set MaSelection = Nothing
         Next i
    End With
 
    WordApp.Visible = True 'affiche le document Word
    'WordDoc.PrintOut 'si on veut imprimer
 
    WordDoc.Close savechanges:=wdSaveChanges 'si on veut fermer le document word en sauvegardant les données
    WordApp.Quit 'ferme la session Word
    Set MaSelection = Nothing
    Set WordDoc = Nothing
    Set WordApp = Nothing
    Set OngletDesDonnees = Nothing
 
End Sub

Selon la chaîne injectée dans le document, il est possible que la sélection du texte existant dans chaque signet ne soit que partielle. Dans ce cas, il faudra remplacer wdWord, par wdSentence ou wdParagraph.

A noter également que si les signets englobaient une zone de texte, il n'y aurait pas cette difficulté de sélection.