Discussion :

[Grim971]

Bonjour,

Je suis à la recherche d'une méthode (en VBA) pour effectuer la recherche d'un dossier dans l'arborescence d'outlook à partir des 5 premiers chiffres. Une fois le dossier trouvé, je souhaite récupérer son nom et chemin complet pour le réutiliser par la suite et exporter ce dossier en pst sur le pc.

Je suis à la recherche de pistes de réflexion car je ne vois pas du tout comment mis prendre.

Merci

[Oliv-]

Bonjour,

Pour le partie recherche , je suppose que c'est récursif ?


cette fonction récursive te renvoi un objet outlook.folder que tu pourras réutiliser

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
Option Explicit
 
 
Sub Lance_Traitement()
'---------------------------------------------------------------------------------------
' Procedure : Lance_Traitement
' Author    : Oliv
' Date      : 12/02/2016
' Purpose   :
'---------------------------------------------------------------------------------------
'
    Dim OL As Outlook.Application
    Dim olNS As Outlook.Namespace
    Dim olFolder As Outlook.Folder
Dim FolderTrouve As Outlook.Folder
 
    If UCase(Application) = "OUTLOOK" Then
        Set OL = Application
    Else
        Set OL = CreateObject("outlook.application")
    End If
    Set olNS = OL.GetNamespace("MAPI")
    Dim Nom
    Nom = InputBox("Quel dossier ?", "recherche d'un dossier")
    'soit on connait le dossier
    'Set olFolder = olNS.GetDefaultFolder(olFolderInbox).folders
 
    'soit on le choisi
    Set olFolder = olNS.PickFolder
 
    Set FolderTrouve = fgetFolderByName(Nom, olFolder, True)
    MsgBox FolderTrouve.Name & vbCr & FolderTrouve.FolderPath
End Sub
 
Function fgetFolderByName(Nom, StartFolder As Outlook.MAPIFolder, SubFolder As Boolean) As Outlook.Folder
'---------------------------------------------------------------------------------------
' Procedure : ProcessFolder
' Author    : Oliv'
' Date      : 12/02/2016
' Purpose   : Traitement récursif sur les dossiers OUTLOOK
'---------------------------------------------------------------------------------------
'
    Dim objFolder As Outlook.MAPIFolder
    Dim objitem As Object
 
    'Dim objItem As Object
    On Error Resume Next
 
    ' do something specific with this folder
    Debug.Print StartFolder.FolderPath, StartFolder.Items.Count
    Debug.Print
    If Not fgetFolderByName Is Nothing Then Exit Function
 
    If StartFolder.DefaultItemType = olMailItem Then
        '  ICI LE TRAITEMENT POUR CHAQUE DOSSIER
        If StartFolder.Name Like Nom & "*" Then
 
            Set fgetFolderByName = StartFolder
            Exit Function
        End If
 
    End If
 
    'on traite tous les sous dossiers
    If SubFolder Then
        For Each objFolder In StartFolder.Folders
            Set fgetFolderByName = fgetFolderByName(Nom, objFolder, SubFolder)
            If Not fgetFolderByName Is Nothing Then Exit For
        Next
    End If
 
    Set objFolder = Nothing
End Function

pour la suite tu veux exporter quoi les éléments de ce dossier ? y a t'il des sous dossiers ?

[Grim971]

Merci pour le code qui fonctionne très bien. Maintenant, que j'ai le chemin et le nom de ce dossier. Je souhaite l'enregistrer lui et ses sous-dossiers en PST par exemple sur D:

En tout un grand merci pour ce code que je viens de réadapter à mon besoin.

Bon WE

[Oliv-]

Pour la suite

s'il faut créer un PST : http://www.outlookcode.com/codedetail.aspx?id=642
http://www.outlookcode.com/codedetail.aspx?id=1471


pour l'export

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
 
 Set objNS = application.GetNamespace("MAPI")
 Set myNewFolder = objNS.PickFolder
FolderTrouve.CopyTo myNewFolder

[Grim971]

Merci pour le lien.

Je vais m'en sortir avec cela.