Discussion :

[solphat]

Bonjour,
j'essaie d'automatiser une action que je fais quotidiennement sur le calendrier. Je m'explique :
- Je créé un événement que je nomme "J0 : suivie d'un titre"
- Je le copie
- Je nomme le nouveau "J+3 : suivie du même titre"
- Je change la date pour 3J après.
- et je fais ainsi pour J+6, J+10

J'aimerai donc gagner du temps en voulant automatiser cela. Pour ça j'ai pensé à d'abord faire un filtre avec Automator qui me retourne un fichier TextEdit avec seulement les événements contenant dans le titre "J0" mais le problème c'est que je ne sais pas comment l'exploiter sur Applescript pour pouvoir modifier les évenements et en créer de nouveau. Mais ce n'est peut-être pas la bonne solution.

Merci de votre aide.

[PBELL]

Bonjour Solphat,
Il est facile de créer des évènements iCal (Calendrier) via un script.

Dans le script ci-dessous, j'ai du faire des hypothèses, faute d'informations précises dans ta demande :
1) L'heure de création des évènements : j'ai mis par défaut 15h30. Il est très facile de mettre une autre heure, et, compte tenu de la structure du script, tu peux changer cette heure pour chaque appel à la routine de création du script.
2) Le calendrier dans lequel tu crées ces évènements : par default "Calendar" existe toujours, je l'ai donc utilisé. Tu peux bien sûr mettre le nom d'un autre de tes calendriers.
3) Ce que l'évènement déclenche : j'ai mis une alarme sonore, sans d'ailleurs spécifier le type de son. Cela peut être bien d'autres choses (lancer un script, un email, ouvrir un fichier,...)

Le script te demande de saisir le titre et crée directement le J0, J3, J6 et J10. Je pense avoir mis suffisamment de commentaires pour que tu puisse l'adapter à tes besoins.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
set T to display dialog "Saisissez un titre pour l'évènement" default answer "Titre"
set Titre to text returned of T

set maDate to current date
set hours of maDate to 15 -- defini l'heure de l'évènement : ici 15h30
set minutes of maDate to 30
set seconds of maDate to 0

CreEvent(maDate, "J0 : " & Titre)
CreEvent(maDate + 3 * days, "J+3 : " & Titre)
CreEvent(maDate + 6 * days, "J+6 : " & Titre)
CreEvent(maDate + 10 * days, "J+10 : " & Titre)


on CreEvent(LDate, LTitre) -- crée un évènement iCal à la date LDate avec le titre LTitre)
    tell application "Calendar"
        tell calendar "Calendar" -- Calendar est le calendrier par défaut !
            set N_Event to make new eventat end with properties {description:LTitre, summary:LTitre, start date:LDate, allday event:false}
            tell N_Event
make new sound alarm at end --with properties {trigger interval:0, filepath:POSIX path of Mon_Script, trigger date:Ma_Date}
            end tell
        end tell
    end tell
end CreEvent

Cordialement

[solphat]

Merci beaucoup PBELL, cela marche parfaitement et convient à mon utilisation, j'ai cependant réussi à rajouté une requête pour le choix du calendrier ainsi que de l'heure.