Discussion :

[Jean-Matricule]

Bonjour à tous,
Ça fait un bon moment que je cherche comme stipulé ci-dessus, à remplacer des lignes dans un document texte (.ini en l’occurrence) de façon automatisé, mais fautes de trouvailles probantes, je viens demander votre aide.

Voici un extrait du document en question (appelons le data.ini)

[MAIN]
bGamepadEnable=1
bCrosshairEnabled=1
fHUDOpacity=1.0000
fSkyCellRefFadeDistance=150000.0000
[GamePlay]
bShowFloatingQuestMarkers=1
bShowQuestMarkers=1
iDifficulty=3

L'objectif serais de, en fonction d'un chois effectuer plus tôt, changer certaines valeurs dans data.ini mais en laissant tout le reste inchangé, sachant que je ne connais pas l’état actuel ni la longueur de de ces dernières, mais je connais leurs n° de la ligne et le texte qui précède.

Dans cette partie je souhaiterai remplacer fSkyCellRefFadeDistance=150000.0000 par fSkyCellRefFadeDistance=74200.0000, donc la ligne 5, le problème c'est que mes connaissance en batch sont très limités et je ne sais pas comment procéder une fois l'action choisie, donc vient la question : comment changer cette ligne en particulier ?
(je crois savoir que l'on procède de même pour des fichiers .ini que .txt, mais je n'en sais pas plus)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
@ECHO OFF

:menu
cls
echo parametres
echo 1 : fHUDOpacity                2 : bCrosshairEnable
echo 3 : fSkyCellRefFadeDistance    4 : bGamepadEnable
set /p menu=
if %menu% EQU 1 goto hud
if %menu% EQU 2 goto crosshair
if %menu% EQU 3 goto sky
if %menu% EQU 4 goto gamepad
goto menu

:sky
cls
???

voila voila, je pense avoir tous dit, j'espère que vous pourrez m'aider

[ericlm128]

Voici un exemple simple de remplacement :

Code bat :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
@echo off
 
if exist "data_tmp.ini" del /A /Q /F "data_tmp.ini"
for /f "tokens=* delims==" %%a in (data.ini) do (echo %%a | findstr /I /V /B "fSkyCellRefFadeDistance=" || echo fSkyCellRefFadeDistance=74200.0000)>>"data_tmp.ini"
move /Y "data_tmp.ini" "data.ini" >nul
 
pause

[Jean-Matricule]

ça marche parfaitement, merci beaucoup

[Jean-Matricule]

après quelques test je viens de me rendre compte que ta solution ajoute des espaces un peut partout dans le document a la fin des lignes, le problème c'est que le logiciel est sensible à ces espaces, y a t'il moyen de s'en débarrasser ?

[sachadee]

Une autre approche bien plus simple dans le traitement que tu peux étudier :


Pour la récuperation des valeurs dans un ini le plus simple est :

test.ini :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
val1=toto
val2=tata
val3=titi

GetIni.bat

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
for /f "delims=" %%a in (test.ini) do set #%%a 2>nul

echo Val1 = %#val1%
echo Val2 = %#val3%
echo Val3 = %#val3%

Si tu veux changer val3 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

set "#val3=NouvelleValeur"

et la sauvegarde du nouvelle ini :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
setlocal enabledelayedexpansion

(for /f "delims=" %%a in ('set #') do (
   set "$NewLigne=%%a"
   echo !$NewLigne:#=!
))>NewIni.ini

[ericlm128]

Oui excuse moi.

Code bat :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
@echo off
 
if exist "data_tmp.ini" del /A /Q /F "data_tmp.ini"
for /f "tokens=* delims==" %%a in (data.ini) do (echo %%a|findstr /I /V /B "fSkyCellRefFadeDistance="||echo fSkyCellRefFadeDistance=74200.0000)>>"data_tmp.ini"
move /Y "data_tmp.ini" "data.ini" >nul
 
pause

[Jean-Matricule]

merci pour vos réponses à tous les deux, j'ai retenus la solution de ericlm, je ne comprend pas exactement comment supprimer tous les espaces dans la fonction à régler le problème (j'aurai pensé qu'un seul était à supprimer). la prochaine fois que je me repencherai sur le sujet j’essaierai également la seconde méthode