Discussion :

[alsimbad]

Bonjour le forum
j'ai du mal a oeuvrer sous excel mac
je cherche a faire une formule pour trouver le nombre de lundi, mardi.. dans un mois.
j'ai une colonne avec mes date (A2:A32) et je veux connaitre le nombre de lundi du mois. j'ai écris

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=nb.si(A2:A32;joursem(A2:A32)=2)

ben ça marche pas
quelqu'un peut m'aider ?

[gFZT82]

Bonjour,

Essaie avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((JOURSEM(A2:A32;2)=1)*1)

Cordialement.

[excfl]

Bonsoir le forum,

B2 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((MOIS($A$2:$A$32)=MOIS($A$2))*--(JOURSEM($A$2:$A$32;1)=COLONNE()-1))

A tirer vers la droite.

[alsimbad]

Bonjour et merci d'avoir répondu
pour excfi
j'ai adapté un peu mais ta formule marche

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

SOMMEPROD((MOIS($A$2:$A$32)=MOIS($A$2))*--(JOURSEM($A$2:$A$32)=2))

par contre, j'avoue ne pas comprendre exactement le rôle de la formule mois(…) puisqu'on travaille sur des jours dans un seul mois


pour GFZt82 la formule est efficace et plus simple, j'ai adopté la tienne au prix d'une petite motif sur le type de retour sur joursem

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((JOURSEM(A2:A32)=2)*1)

merci a tout les deux, problème résolu

[excfl]

je cherche a faire une formule pour trouver le nombre de lundi, mardi.. dans un mois.

La formule que j'ai proposée répond à la demande initiale.

par contre, j'avoue ne pas comprendre exactement le rôle de la formule mois(…) puisqu'on travaille sur des jours dans un seul mois

Dans l'exemple proposé, il faut préciser que l'on recherche le nombre de lundi, mardi ... uniquement pour le mois de février.
Puisque j'ai complété le calendrier jusqu'au 02/03.

[excfl]

Pour avoir le nombre de jours sur l'année :

C2 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SOMMEPROD((MOIS($A$2:$A$367)=LIGNE()-1)*--(JOURSEM($A$2:$A$367;1)=COLONNE()-2))

A tirer vers la droite, puis vers le bas.

[alsimbad]

D'accord
je ne me posais pas la question tel que parce que je travaille sur une feuille mensuel ou je n'ai que le mois en cours
merci

[QuestVba]

Bonsoir,
Bête question : dois-tu tenir compte des jours ouvrés ?

[alsimbad]

Non, je te remercie QuestVba mais mon problème est résolu avec la formule de gFZT82. merci quand même