Discussion :

[roro69]

Bonjour ;
Dans un rectangle je souhaiterais pouvoir étirer du texte sur toute la largeur ; à ce jour j'utulisais le code récupérer
ici : http://www.vb-helper.com/howto_net_s...xt_to_fit.html
mais le rendu avec la méthode graphicpath n'est pas très bonne ;
j'aimerais savoir si il y aurait une solution avec la méthode drawstring ; ou autre solution

Merci pour le temps consacré et l'aide apporté

[clementmarcotte]

Bonjour,

Quelques exemples microsoftiens sur le dessin de textes:

https://code.msdn.microsoft.com/Text...-with-301363a1

https://code.msdn.microsoft.com/GDI-...ample-868202a1

https://code.msdn.microsoft.com/Draw...cters-920dbcea

Pour l'ensemble des exemples:

https://code.msdn.microsoft.com/

[roro69]

Merci beaucoup pour la réponses ; mais je cherchais par quel moyen je peut avoir le texte étirer sur tout la largeur d'une picture box ou tout autre rectangle.
Pour le moment grace au code du lien que j'ai donné ci dessus je passe par la méthode graphicpath mais le résultat n'est pas très bon donc je souhaitais savoir si on pouvait arrivé au même résultat avec un autre méthode
En tout cas merci déjà pour cette réponse et pour le temps consacré

[strikel]

Salut si j'ai bien compris tu veux avoir ton texte étiré sur toute la largeur ?
pourquoi ne pas instancier un label contenant ton texte et capter le rendu sous forme d'image que tu places dans une picturebox avec la propriété sizemode à "stretch"

[MABROUKI]

bonjour
Mis part le GDI+,je ne vois pas d'autre issue, néanmoins l'exemple cité sur le lien donne un résultat plus intéressant avec Graphics.DrawString et l'utilisation des tailles de font courantes ou "emsize" (au contraire du Height du rectangle cible)....

L'utilisation de bitmap donne un résultat de rendu déplorable avec la "pixellisation"....
Un des problèmes majeurs des fonts est que la largeur des caractères est variables ("I" n'a pas la même largeur que "W" OU "M") et inconnu via l'API...
La seule issue est donc dans les transformations GDI+...
A noter que la largeur du Pen est "scalée" dans GDI+,et pour éviter ce désagrément on lui assigne la valeur 0 (qui sera une épaisseur constante en fait égale à 1.0)...
Il faut aussi préciser le mode de rendu "smoothing" pour les dessins de rendu GDI+ ...
code .vb avec 2 PictureBoxes :le 1er utilisant Path.AddString
et le 2eme Graphics.DrawString

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
 
 
Imports System.Drawing.Drawing2D
 
Public Class Form3
    Public Sub New()
 
        ' Cet appel est requis par le concepteur.
        InitializeComponent()
 
        ' Ajoutez une initialisation quelconque après l'appel InitializeComponent().
        Pic1.Size = New Size(300, 150)
 
    End Sub
    Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
        DrawPathString()
    End Sub
    Private Sub DrawPathString()
        Using gr As Graphics = Pic1.CreateGraphics
            gr.Clear(Pic1.BackColor)
            gr.SmoothingMode = SmoothingMode.HighQuality
 
            ' Make the layout rect.
            Dim layoutRect As New RectangleF(
                5, 5,
                Pic1.ClientRectangle.Width - 10,
                Pic1.ClientRectangle.Height - 10)
 
            ' Make the Font.
            Dim myfont As Font = New Font("Arial", 10.0, FontStyle.Bold, GraphicsUnit.Pixel)
 
            ' Make the String.
            Dim s As String = "Outline Text"
 
            ' Make the StringFormat.
            Dim fmt As StringFormat = New StringFormat
            fmt.Alignment = StringAlignment.Center
            fmt.LineAlignment = StringAlignment.Center
            ' Make the path string.
            Dim path As New GraphicsPath
            path.AddString(s,
                           myfont.FontFamily,
                           myfont.Style, myfont.Size,
                           New Point(0, 0), fmt)
 
 
            ' Make a transformation to map 
            ' (xmin, ymin)-(xmax, ymax) onto
            ' the target area.
            Dim pathRect As RectangleF = path.GetBounds()
            Dim layoutPoints() As PointF = { _
                New PointF(layoutRect.Left, layoutRect.Top),
                New PointF(layoutRect.Right, layoutRect.Top),
                New PointF(layoutRect.Left, layoutRect.Bottom)
            }
            gr.Transform = New Matrix(pathRect, layoutPoints)
 
            Using textPen As New Pen(Brushes.Red, 0.0)
                gr.DrawPath(textPen, path)
            End Using
            Using textBrush As New SolidBrush(Color.BlueViolet)
                gr.FillPath(textBrush, path)
            End Using
 
            gr.ResetTransform()
            gr.DrawRectangle(Pens.Green, Rectangle.Ceiling(layoutRect))
 
        End Using
 
 
 
    End Sub
    Private Sub Button2_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button2.Click
        DrawString()
    End Sub
    Private Sub DrawString()
        Using gr As Graphics = Pic2.CreateGraphics
            gr.Clear(Pic1.BackColor)
            gr.SmoothingMode = SmoothingMode.HighQuality
 
            ' Make the layout rect.
            Dim layoutRect As New RectangleF(
                5, 5,
                Pic1.ClientRectangle.Width - 10,
                Pic1.ClientRectangle.Height - 10)
 
            ' Make the Font.
            Dim myfont As Font = New Font("Arial", 10.0, FontStyle.Bold, GraphicsUnit.Pixel)
 
            ' Make the String.
            Dim s As String = "Outline Text string"
 
            ' Make the StringFormat.
            Dim fmt As StringFormat = New StringFormat
            fmt.Alignment = StringAlignment.Center
            fmt.LineAlignment = StringAlignment.Center
 
            ' Measure string 
            Dim sizeString As SizeF = gr.MeasureString(s, myfont, layoutRect.Width)
 
 
 
            ' Make a transformation to map 
            ' (xmin, ymin)-(xmax, ymax) onto
            ' the target area.
            Dim stringRect As RectangleF = New RectangleF(5, 5, sizeString.Width, sizeString.Height)
            Dim layoutPoints() As PointF = { _
                New PointF(layoutRect.Left, layoutRect.Top),
                New PointF(layoutRect.Right, layoutRect.Top),
                New PointF(layoutRect.Left, layoutRect.Bottom)
            }
            gr.Transform = New Matrix(stringRect, layoutPoints)
 
            Using textBrush As New SolidBrush(Color.Red)
                gr.DrawString(s, myfont, textBrush, stringRect, fmt)
            End Using
 
 
            gr.ResetTransform()
            gr.DrawRectangle(Pens.Green, Rectangle.Ceiling(layoutRect))
 
        End Using
 
 
 
    End Sub
End Class

bon code....

[roro69]

Bonjour a tous
Merci pour vos réponses et le temps consacré
Mabrouki je te remercie ;
C'est ce que je voulais ;avec la méthode drawstring le résultat et beaucoup plus satisfaisant ; il ne me reste plus qu'à voir pour que le texte remplisse exactement la largeur du picturebox ; car là il laisse une marge de quelque pixel avant et après le mot( contrairement à Path qui remplit la largeur total)
Merci beaucoup