Discussion :

[cpretty]

Bonjour à tous,

Voilà mon souci, j'ai des données (texte et chiffres) sur des fichiers Excel (tableaux de calculs importants), à partir de ces tableaux de calculs je désire générer un document Word pour restitution jolie de ces données issues des tableaux Excel. J'ai créé un document Word un modèle un Template quoi tout joli pour un rendu correct.

J'ai trouver une solution très simple et très efficace pour certaines données qui est le rechercher/remplacer et qui fonctionne très bien !!!
Par contre pour le graphique c'est une autre paire de manche, je n'arrive pas à rentrer dans la feuille de calcul Excel contenant les données du graphique Word, mon graphique Word existe sur mon Template Word il est tout bien paramétrer je veux juste depuis Excel modifier les données du graphique mais je n'y arrive pas, il m'est impossible d'accéder au classeur contenant les données du graphique.

Quelqu'un a-t-il une solution ??

Merci
Céline

[jurassic pork]

hello,
je ne comprends pas tout de ce que tu nous expliques . Peux-tu nous montrer ou nous décrire ce que tu fais exactement (code VBA ou manipulation Excel) ?

Ami calmant, J.P

[kiki29]

Salut, peut-être en regardant ici : Créer un graphe et le copier dans Word. Enfin si j'ai compris qqch.

[Menhir]

je n'arrive pas à rentrer dans la feuille de calcul Excel contenant les données du graphique Word

Quand on crée un graphique Word, les données sont dans Word, même si la fenêtre qui les contient ressemble à de l'Excel.
Pour y accéder, faire un clic droit sur le graphique > Modifier les données.
On a ensuite le choix de modifier les données dans Excel, mais ça reste des données Word.

[cpretty]

Pour y accéder, faire un clic droit sur le graphique > Modifier les données.
On a ensuite le choix de modifier les données dans Excel, mais ça reste des données Word.[/QUOTE]

bonjour Menhir,

C'est exactement ceci que je veux faire mais commandé par mon programme VBA et n'y arrive pas.

Mon programme est dans Excel mais je peux très bien monter un second programme dans word pour modifier les données puis le faire appeler d'Excel en lui donnant les données issues du programme Excel, est-ce que tu peux m'aider à faire ça ??

Merci
Céline

[jurassic pork]

hello,
je m'excuse de m'insérer dans la discussion mais tu peux faire comme cela par exemple (macro dans le document word) :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
Sub ModifierDataGraphique()
' J.P Juillet 2016
Dim monGraphique As Chart
Dim feuilleDuGraphique As Excel.Worksheet
Dim objShape As InlineShape
'On cherche le graphique dans le document actif qui a le titre Test
For Each objShape In ActiveDocument.InlineShapes
        If objShape.HasChart Then
        If objShape.Title = "Test" Then Set monGraphique = objShape.Chart
        End If
Next
' On active les données pour pouvoir y accèder
monGraphique.ChartData.Activate
' On sélectionne la feuille excel du graphiquz
Set feuilleDuGraphique = monGraphique.ChartData.Workbook.Worksheets(1)
' On minimise la feuille excel ouverte
feuilleDuGraphique.Application.WindowState = xlMinimised
' on change par exemple la donnée Catégorie 1 de la série 1 (B2)
feuilleDuGraphique.Range("B2") = 3.9
' on rafraîchit le graphique
monGraphique.Refresh
' on ferme Excel
feuilleDuGraphique.Application.Quit
End Sub

Il faut ajouter la bibliothèque Excel (Microsoft Excel Object Library) dans l'éditeur VBA outils/Références.
Le titre du graphique est le champ Titre de Format de la zone graphique/Texte de remplacement.



Ami calmant, J.P

[jurassic pork]

comme tu veux faire cela à partir d'Excel, voici un exemple de macro VBA excel qui :
1 - Copie les données à utiliser dans le graphique word dans le presse-papier ( cellules A10:C13 de la feuille active)
2 - Ouvre le document Word cherche le graphique qui a pour titre Test.
3 - Colle dans la feuille Excel des données du graphique les données copiées dans le presse-papier.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Sub ModifDataGraphWord()
' J.P Juillet 2016
Dim monGraphique As Word.Chart
Dim feuilleDuGraphique As Excel.Worksheet
Dim objShape As InlineShape
Dim strFichier As String
Dim objWord As New Word.Application
'on copie les données à utiliser dans le graphique
ActiveSheet.Range("A10:C13").Copy
strFichier = "f:\temp\DocGraphique.docm"
' ouvrir un document Word
objWord.Documents.Open strFichier
' rendre Word visible
objWord.Visible = True
'On cherche le graphique dans le document actif qui a le titre Test
For Each objShape In objWord.ActiveDocument.InlineShapes
        If objShape.HasChart Then
        If objShape.Title = "Test" Then Set monGraphique = objShape.Chart
        End If
Next
' On active les données pour pouvoir y accèder
monGraphique.ChartData.Activate
' On sélectionne la feuille excel du graphique
Set feuilleDuGraphique = monGraphique.ChartData.Workbook.Worksheets(1)
' on colle les données à utiliser
feuilleDuGraphique.Range("B2").PasteSpecial
' on rafraîchit le graphique
monGraphique.Refresh
' on ferme la feuille
monGraphique.ChartData.Workbook.Close
' fermer le document (penser à sauvegarder avant)
' objWord.Documents(1).Close
' quitter l'application Word
' objWord.Quit
' libérer la mémoire
' Set objWord = Nothing
End Sub

Il faut ajouter la bibliothèque Word (Microsoft Word Object Library) dans l'éditeur VBA outils/Références.

Ami calmant, J.P