Discussion :

[Domi2]

Bonjour,

Je suis un peu "rouillé" en VBA et malgré des recherches je n'ai pas véritablement trouvé mon bonheur.

Je dois faire un publipostage sur la base d'une liste Excel et produire un document distinct par ligne Excel.

Je me suis donc basé sur l'excellent tutoriel d'Olivier Lebeau, ça fonctionne nickel !

Maintenant, on m'en demande évidemment plus.

Chaque document peut avoir de 0 à 4 adresses de "Copies" au bas du document, sous forme de liste.

Cela se présente comme ceci :

Copies :
• «COPIE_1»
• «COPIE_2»
• «COPIE_3»
• «COPIE_4»

Et donc il faudrait supprimer la totalité du "pavé" s'il n'y aucune copie ou modifier "Copies" en "Copie" si une seule copie.

J'arrive à correctement compter le nombre de copie et à fusionner mes documents avec le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Sub TestPublipost()
'Déclaration des variables
Dim iR As Integer
Dim i As Integer
Dim oDoc As Document
Dim DocName As String
Dim oDS As MailMergeDataSource
Dim iCopie1 As Integer
Dim iNbCopies As Integer
 
' Affectation des objets
Set oDoc = ActiveDocument
Set oDS = oDoc.MailMerge.DataSource
 
iR = oDoc.MailMerge.DataSource.RecordCount
'Debug.Print iR'
For i = 1 To iR
    With oDoc.MailMerge
        'Définition du premier et dernier enregistrement
        .DataSource.FirstRecord = i
        .DataSource.LastRecord = i
        ' Envoi des données dans un nouveau document
        .Destination = wdSendToNewDocument
        ' Exécution du publipostage
        .Execute
        ' Actualisation de l'enregistrement pour la sauvegarde
        .DataSource.ActiveRecord = i
        iCopie1 = IIf(.DataSource.DataFields("COPIE_1").Value = "", 0, 1)
        iCopie2 = IIf(.DataSource.DataFields("COPIE_2").Value = "", 0, 1)
        iCopie3 = IIf(.DataSource.DataFields("COPIE_3").Value = "", 0, 1)
        iCopie4 = IIf(.DataSource.DataFields("COPIE_4").Value = "", 0, 1)
        iNbCopies = iCopie1 + iCopie2 + iCopie3 + iCopie4
        MsgBox "Nombre copie(s) : " & iNbCopies, vbOKOnly + vbInformation, "Publipostage terminé"
        'Utilisation du premier champ pour obtenir le nom du document
        DocName = .DataSource.DataFields("NO_DOSSIER").Value
        'Debug.Print DocName; i'
    End With
    'Sauvegarde du document publiposté
    With ActiveDocument
        .SaveAs "xxxxxxxxxxxxxxx\" & DocName & ".docx"
        .Close
    End With
Next i
MsgBox "Nombre de documents générés : " & i - 1, vbOKOnly + vbInformation, "Publipostage terminé"
End Sub

Je ne suis évidemment pas contre la solution inverse, soit ajouter du texte et les copies en fonction du nombre de celles-ci.

Voyez-vous une solution pas trop complexe ?

Merci d'avance.

[Heureux-oli]

Salut,

Et avec un test If sur le recordcount, j'ai pas essayé, mais ça me semble être une piste honnête.

[Domi2]

Bonjour et merci,

Je ne vois pas bien ce que tu veux dire.

J'arrive à compter le nombre de copie(s).

J'ai plus de difficultés par contre à trouver une bonne solution pour personnaliser le bas de la page.

Une discussion récente m'a mis sur une piste sur une piste, mais c'est un peu tiré par les cheveux.

En fait, j'ai créé des saut de section continu, comme ceci :

Saut de section
Copie :
• «COPIE_1»
Saut de section
Copies :
• «COPIE_1»
• «COPIE_2»
• «COPIE_3»
• «COPIE_4»

Et en fonction du nombre de copie(s), je les supprime ou non :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
Sub genererDocuments()
'Déclaration des variables
Dim iR As Integer
Dim i As Integer
Dim oDoc As Document
Dim DocName As String
Dim oDS As MailMergeDataSource
Dim iCopie1 As Integer
Dim iNbCopies As Integer
 
' Affectation des objets
Set oDoc = ActiveDocument
Set oDS = oDoc.MailMerge.DataSource
 
iR = oDoc.MailMerge.DataSource.RecordCount
'Debug.Print iR'
For i = 1 To iR
    With oDoc.MailMerge
        'Définition du premier et dernier enregistrement
        .DataSource.FirstRecord = i
        .DataSource.LastRecord = i
        ' Envoi des données dans un nouveau document
        .Destination = wdSendToNewDocument
        ' Exécution du publipostage
        .Execute
        ' Actualisation de l'enregistrement pour la sauvegarde
        .DataSource.ActiveRecord = i
        iCopie1 = IIf(.DataSource.DataFields("COPIE_1").Value = "", 0, 1)
        iCopie2 = IIf(.DataSource.DataFields("COPIE_2").Value = "", 0, 1)
        iCopie3 = IIf(.DataSource.DataFields("COPIE_3").Value = "", 0, 1)
        iCopie4 = IIf(.DataSource.DataFields("COPIE_4").Value = "", 0, 1)
        iNbCopies = iCopie1 + iCopie2 + iCopie3 + iCopie4
        'MsgBox "Nombre copie(s) : " & iNbCopies, vbOKOnly + vbInformation, "Publipostage terminé"'
        'Utilisation du premier champ pour obtenir le nom du document
        DocName = .DataSource.DataFields("NO_DOSSIER").Value
        'Debug.Print DocName; i'
    End With
    'Sauvegarde du document publiposté
    With ActiveDocument
        If iNbCopies = 0 Then
            ActiveDocument.Sections(3).Range.Delete
            ActiveDocument.Sections(4).Range.Delete
        End If
        If iNbCopies = 1 Then
            ActiveDocument.Sections(4).Range.Delete
        Else
            ActiveDocument.Sections(3).Range.Delete
        End If
        .SaveAs "xxxxxxxxxxxxxxxxxxx\" & DocName & ".docx"
        .Close
    End With
Next i
MsgBox "Nombre de documents générés : " & i - 1, vbOKOnly + vbInformation, "Publipostage terminé"
End Sub

Ca fonctionne plutôt bien, mais j'ai encore un problème, c'est que je n'arrive pas à supprimer les saut de section, cela m'ennuie un peu.

Et évidemment, si je veux faire une fusion "traditionnelle", il faut que je modifie mon document.

Donc si quelque a une solution plus propre, je reste preneur.

[cerede2000]

Bonjour à toi,

J'ai trouvé cette petite Sub qui permet de virer les saut de section qui ne sont plus nécéssaires :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub RemoveUnnecessarySectionBreaksButPreservePageLayout() 
    Dim i As Integer 
    Dim rngWhere As Range 
    Dim oSec As Section 
 
    For i = ActiveDocument.Sections.Count To 2 Step -1 
        Set oSec = ActiveDocument.Sections(i) 
        Set rngWhere = oSec.Range 
 
        If oSec.Headers(wdHeaderFooterPrimary).LinkToPrevious = True Then 
            rngWhere.Paragraphs.Last.Range.ParagraphFormat.PageBreakBefore = True 
            rngWhere.Paragraphs.First.Previous.Range.Characters.Last = vbCr 
        End If 
    Next 
End Sub

As essayé sur ton cas.

[Domi2]

Bonjour,

Merci pour ce code, ça fonctionne bien.

J'ai dû un peu l'adapté à mon cas spécifique car j'ai un saut de section (2) qui ne doit pas être supprimé, ainsi que la constante de remplacement.

Du coup, j'ai modifié la boucle et la constante, ce qui donne :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
For iSection = ActiveDocument.Sections.Count To 3 Step -1
    Set oSec = ActiveDocument.Sections(iSection)
    Set rngWhere = oSec.Range
 
    If oSec.Headers(wdHeaderFooterPrimary).LinkToPrevious = True Then
        rngWhere.Paragraphs.Last.Range.ParagraphFormat.PageBreakBefore = True
        rngWhere.Paragraphs.First.Previous.Range.Characters.Last = vbNullString
    End If
Next

Le sauts de sections (3) et (4) sont bien supprimés, ainsi que le saut de section de fin de document généré par le publipostage, c'est parfait.

Par contre, maintenant, j'ai de manière systématique une deuxième page ajoutée à mes documents, avec une seule marque de paragraphe précédée d'un petit carré noir.

Une idée ?

[Domi2]

En fait, c'est cette ligne là qui posait problème :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

rngWhere.Paragraphs.Last.Range.ParagraphFormat.PageBreakBefore = True

J'aurais pu m'en rendre compte plus vite

Il me reste encore un petit détail, soit supprimé deux paragraphe en fin de document, cela ne devrait pas poser trop de difficultés, du moins je l'espère.

[cerede2000]

Ceci supprime le dernier paragraphe :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveDocument.Paragraphs(ActiveDocument.Paragraphs.Count).Range.Delete

[carden752]

Bonjour,

Pourquoi ne pas insérer les copies directement avec une condition IF? cela permettrait un affichage que si elles existent directement dans le modèle puisqu'il s'agit d'un champ de la source de données

[Domi2]

Bonjour Carden752,

J'ai effectivement fait l'essai, mais cela ne me permettait pas de supprimer les puces.

Peut-être n'ai-je pas pris suffisamment de temps pour mettre cette solution au point.

[Domi2]

Ceci supprime le dernier paragraphe :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

ActiveDocument.Paragraphs(ActiveDocument.Paragraphs.Count).Range.Delete

Parfait ! Merci beaucoup, ma mise en page en est grandement améliorée