Discussion :

[EricDgn]

Attention, ce qu'il faut ajouter dans Form_Open() est ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
'--- non, pas ceci
CurrentDb.QueryDefs("R_Pres").SQL = "SELECT IdProfesseur, DateJ, NbHeures FROM T_Presence " & _
                                    "WHERE Year([DateJ])= " & Forms!F_Planning.An & " AND Month([DateJ])=" & Forms!F_Planning.Mois
'--- mais ceci
CurrentDb.QueryDefs("R_Pres").SQL = "SELECT IdProfesseur, DateJ, NbHeures FROM T_Presence " & _
                                    "WHERE Year([DateJ])= Form_F_Planning.An AND Month([DateJ])= Form_F_Planning.Mois"

Cela se ressemble ... mais c'est vraiment très différent !
Cdt

[kabamel]

Toujours pas.
Voici la requête "R_Pres" avant ouverture du formulaire "F_Planning"

Là, il n'y a pas de problème, et maintenant la requête après ouverture du formulaire "F_Planning"

c'est là, il y a problème. le code de "F_Planning" sur ouverture

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub Form_Open(Cancel As Integer)
If DCount("*", "T_Professeur") = 0 Then
    MsgBox "Aucun enregistrement", vbInformation, "Info"
    DoCmd.Close acForm, "F_Planning"
End If
Me.FiltreMat.SetFocus
    ' Redifinition de la requête "R_Pres"
CurrentDb.QueryDefs("R_Pres").SQL = "SELECT IdProfesseur, DateJ, NbHeures FROM T_Presence " & _
                                    "WHERE Year([DateJ])= " & Form_F_Planning.An & " AND Month([DateJ])=" & Form_F_Planning.Mois
End Sub

J'espère que cette fois, vous voyez le problème
Merci pour aide

[EricDgn]

Le code qui convient est celui-ci:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Private Sub Form_Open(Cancel As Integer)
If DCount("*", "T_Professeur") = 0 Then
    MsgBox "Aucun enregistrement", vbInformation, "Info"
    DoCmd.Close acForm, "F_Planning"
End If
Me.FiltreMat.SetFocus
    ' Redifinition de la requête "R_Pres"
CurrentDb.QueryDefs("R_Pres").SQL = "SELECT IdProfesseur, DateJ, NbHeures FROM T_Presence " & _
                                    "WHERE Year([DateJ])=Form_F_Planning.An AND Month([DateJ])=Form_F_Planning.Mois" 
End Sub

Il ne faut surtout pas mettre de " & ... & " dans la partie WHERE
Cdt.

[kabamel]

A l'ouverture de "F_Planning" voici ce qui sorte :

et ça :

[EricDgn]

Après quelques essais, j'en arrive aux modifications suivantes.
a) dans F_Planning:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub Form_Open(Cancel As Integer)
    If DCount("*", "T_Professeur") = 0 Then
        MsgBox "Aucun enregistrement", vbInformation, "Info"
        DoCmd.Close acForm, "F_Planning"
    Else
        Me.Mois = Month(Date)
        Me.An = Year(Date)
        MajPlanning
        DoCmd.Maximize
    End If
    '--- et supprimer Form_Load()
End Sub

b) dans la fonction MajPlanning

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Public Sub MajPlanning()
 
'--- en dernières instructions
CurrentDb.QueryDefs("R_Pres").SQL = "SELECT IdProfesseur, DateJ, NbHeures FROM T_Presence " & _
                                    "WHERE Year([DateJ])= " & Forms!F_Planning.An & " AND Month([DateJ])=" & Forms!F_Planning.Mois
 
Forms!F_Planning!SF_Planning.Form.RecordSource = "R_NbHeureProf_Analyse croisée"   '--- nécessaire pour prise en compte R_Pres modifié
Forms!F_Planning!SF_Planning.Form.Requery
End Sub

Cordialement

[kabamel]

Je vous mettrais au courant après vérification
Merci pour ton aide

[kabamel]

Suuuuupeeeeer, Merci

[kabamel]

Salut, tout juste un ptit souci avec un fichier excel fermé que je pilote depuis Access
Si dans le feuille Excel on trouve le classeur "Kaba" on rempls par certaine valeur, sinon on crée le classeur "Kaba" et on remplis par les même valeur
je mets le code que j'ai en ce moment

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
    Dim xlApp As Excel.Application
    Dim xlSheet As Excel.Worksheet
    Dim xlBook As Excel.Workbook
    Dim i As Long
    Dim Chemin As String
    Chemin = "C:\Users\dkaba\Desktop\GEcoModf\Feuille.xlsx"
 
    If Len(Dir(Chemin)) > 0 Then
    ' Initialiser les variables
    Set xlApp = CreateObject("Excel.Application")
    Set xlBook = xlApp.Workbooks.Open(Chemin)
 
    ' Ajouter une feuille de calcul nommée Kaba
    Set xlSheet = xlBook.Worksheets.Add
 
   ' Test de l'existence d'une feuille
    If FeuilleExiste(xlBook, "Kaba") Then
        MsgBox "La feuille Kaba existe.", vbInformation
        'xlSheet.Range("A1:E6").Select
        xlSheet.Range("A1:E6").ClearContents
        ' Manipuler une cellule
    xlSheet.Cells(1, 1) = "Pilotage Excel dans Access supra"
 
    ' Manipuler une plage
    xlSheet.Range("A2:D6").Value = Date + 1
    ' Remplir la colonne E de la ligne i avec le num de la ligne (i)
    For i = 2 To 6
        xlSheet.Cells(i, 5).Value = i
    Next
 
    Else
        MsgBox "Feuille Kaba introuvable !", vbExclamation
        xlSheet.Name = "Kaba"
 
    ' Manipuler une cellule
    xlSheet.Cells(1, 1) = "Pilotage Excel dans Access supra"
 
    ' Manipuler une plage
    xlSheet.Range("A2:D6").Value = Date + 1
    ' Remplir la colonne E de la ligne i avec le num de la ligne (i)
    For i = 2 To 6
        xlSheet.Cells(i, 5).Value = i
    Next
 
    End If
 
    ' Code de fermeture
    xlBook.Save
    xlApp.Quit
    Set xlSheet = Nothing
    Set xlBook = Nothing
    Set xlApp = Nothing
 
    MsgBox "Fin de la procédure. :)"
    Else
        MsgBox "Le fichier n'a pas pu être trouvée" & vbCrLf & _
                Chemin & vbCrLf & _
                "n'est pas un chemin valide.", vbCritical + vbOKOnly
    End If

le code de la fonction existe feuille

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
Function FeuilleExiste(xlBook As Workbook, stFeuille) As Boolean
 On Error Resume Next
 FeuilleExiste = Not (xlBook.Sheets(stFeuille) Is Nothing)
End Function

j'espère être bien compri, sinon je suis à vous
Merci pour votre aide

[EricDgn]

Une proposition, à vérifier (non testée)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
    Dim xlApp As Excel.Application
    Dim xlSheet As Excel.Worksheet
    Dim xlBook As Excel.Workbook
    Dim i As Long
    Dim Chemin As String
    Chemin = "C:\Users\dkaba\Desktop\GEcoModf\Feuille.xlsx"
 
    If Len(Dir(Chemin)) = 0 Then
        MsgBox "Le fichier n'a pas pu être trouvé." & vbCrLf & _
                Chemin  & vbCrLf & _
                "n'est pas un chemin valide.", vbCritical + vbOKOnly
        Exit Sub      '--- EXIT SUB
    End If
 
    ' Initialiser les variables
    Set xlApp = CreateObject("Excel.Application")
    Set xlBook = xlApp.Workbooks.Open(Chemin)
 
   ' Test de l'existence d'une feuille
    If FeuilleExiste(xlBook, "Kaba") = False Then
        ' Ajouter une feuille de calcul nommée Kaba
        Set xlSheet = xlBook.Worksheets.Add
        xlSheet.Name = "Kaba"
        Debug.Print "La feuille Kaba ajoutée."
    Else
        Set xlSheet = xlBook.Worksheets("Kaba")
        Debug.Print "La feuille Kaba existe."
    End If
 
    With xlSheet
        .Range("A1:E6").ClearContents
        ' Manipuler une cellule
        .Cells(1, 1) = "Pilotage Excel dans Access supra"
 
        ' Manipuler une plage
        .Range("A2:D6").Value = Date + 1
        ' Remplir la colonne E de la ligne i avec le num de la ligne (i)
        For i = 2 To 6
            .Cells(i, 5).Value = i
        Next
    End With
 
    ' Code de fermeture
    xlBook.Save
    xlApp.Quit
    Set xlSheet = Nothing
    Set xlBook = Nothing
    Set xlApp = Nothing
 
    Debug.Print "Fin de la procédure. :)"

Cdt