Discussion :

[Vince7-7]

Bonjour.
Sur Oracle 11GR2.
J'ai un trigger ON DDL dans lequel j'essaie de récupérer le code de l'objet modifier. Je fais un select sur la vue ALL_SOURCE et il ne me renvoie rien.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
select text 
from all_source
where name=ora_dict_obj_name
and owner=ora_dict_obj_owner
and type = ora_dict_obj_type

en lançant la même requête hors du trigger cela me retourne bien mon code.
Quelqu'un aurait une idée du pourquoi de la chose?

[McM]

Tu peux poster ton code ?
Mon test a bien récupéré le source d'une fonction que j'ai recompilé.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
CREATE TABLE WMCDDL (username varchar2(30),
datetrig DATE,
ddl_type VARCHAR2(30),
obj_owner VARCHAR2(30),
obj_type VARCHAR2(12),
obj_name VARCHAR2(30),
src VARCHAR2(4000));
 
CREATE TRIGGER DDLTrigger
AFTER DDL ON DATABASE
BEGIN
INSERT INTO WMCDDL(USERNAME, DATETRIG, DDL_TYPE, OBJ_OWNER, OBJ_TYPE, OBJ_NAME, SRC)
SELECT ora_login_user, SYSDATE, ora_sysevent, ora_dict_obj_owner, ora_dict_obj_type, ora_dict_obj_name, text 
FROM all_source
WHERE NAME=ora_dict_obj_name
AND owner=ora_dict_obj_owner
AND TYPE = ora_dict_obj_type;
END;

[Vince7-7]

Bonjour et merci de cette réponse. Je teste ça dès lundi et je reviens vers toi pour te donner des nouvelles. Je pense que mon erreur vient du fait que je faisais un trigger BEFORE DDL.

[Vince7-7]

Bonjour.
Non ça ne marche pas. Mon trigger est créé sous SYSTEM et ne récupère pas les données dans ALL_SOURCE. J'ai essayé un AFTER DDL ON SCHEMA, AFTER CREATE Or ALTER ON SCHEMA, AFTER DDL ON DATABASE et aucun ne passe.
cette requête me retourn 0:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
SELECT count(1)
        into ln_vers
        FROM all_source
        WHERE NAME=ora_dict_obj_name
        AND owner=ora_dict_obj_owner
        AND TYPE = ora_dict_obj_type;
 
raise_application_error(-20001,ln_vers);

Le code de mon trigger est:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
CREATE OR REPLACE TRIGGER SYSTEM.ON_DDL_CODE_HI
    AFTER CREATE OR REPLACE ON DATABASE
declare
  lv_user varchar2(100);
  lv_prog varchar2(100);
  lc_text clob;  
  ln_vers number:=0;
BEGIN  
 
    if ora_dict_obj_type in ('PROCEDURE','FUNCTION','PACKAGE BODY','PACKAGE','VIEW') then 
 
        insert into backup.bck_code
        (NOM 
        ,type_code
        ,date_comp
        ,text 
        ,nom_dev)
        SELECT ora_dict_obj_name,ora_dict_obj_type,SYSDATE, text,ora_login_user
        FROM all_source
        WHERE NAME=ora_dict_obj_name
        AND owner=ora_dict_obj_owner
        AND TYPE = ora_dict_obj_type;
 
 
    end if;        
END;

[McM]

j'ai testé.. en fait quand le trigger DDL est exécuté, le dictionnaire n'est pas encore mis à jour (pas commité).
Donc tu ne peux pas lire all_source sur un CREATE.
Sur un DROP, c'est bon.

PS : Sur ma base 11.2.0.3, le REPLACE me sort une erreur ORA-04072: invalid TRIGGER TYPE

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

AFTER CREATE OR REPLACE ON DATABASE

[mnitu]

Quelque chose comme dans l'exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
 
create table mni.ddl_log
(
    owner       varchar2(30),
    log_date    date,
    object_name varchar2(30),
    object_type varchar2(30),
    action      varchar2(10),
    sql_text    Clob
);
--
create or replace trigger ac_db
After Create On Database
Declare
  sql_text DBMS_STANDARD.ora_name_list_t;
  n        PLS_INTEGER;
  l_stmt   Clob := Empty_Clob();
Begin
  --
  n := ora_sql_txt(sql_text);
  For i In 1..n Loop
    l_stmt := l_stmt || sql_text(i);
  End Loop;
  --
  Insert Into mni.ddl_log
         (
          owner,
          log_date,
          object_name,
          object_type,
          action,
          sql_text
         )
         Values
         (
          ora_dict_obj_owner,
          sysdate,
          ora_dict_obj_name,
          ora_dict_obj_type,
          ora_sysevent,
          l_stmt
         );
End;
/

[Vince7-7]

Mon problème est résolu avec la solution de Mnuti. Un grand merci pour votre aide.