Discussion :

[DenisHen]

Bonjour à la communauté,

Voilà, j'ai plusieurs feuilles avec des données différentes mais de même nature. J'ai effectuer le "regroupement" des différentes feuilles dans une autre.

J'ai donc une feuille avec des valeurs dans le désordre (de A2 à A25 par exemple) et certaines valeur sont en double. J'ai tenté un tri à bulle, mais il ne fonctionne pas...

J'aimerais savoir s'il y a un moyen de trier ces cellules (de A2 à A25) tout en supprimant les doublons ? Car en plus, il y a des doublons...

Si quelqu'un a une astuce ou un conseil, je suis preneur, car actuellement, je me noie dans un verre d'eau...

Denis...

[antonysansh]

Bonjour DenHen,

Dans Excel -> Onglet Données tu trouveras deux boutons :
1 pour le Tri et un pour la suppression des doublons.

Donc pas besoin de VB je pense.

[DenisHen]

Bonjour Anthony, et merci pour ton aide.

Le problème est que ce tri et cette suppression de doublon sont au beau milieu de plusieurs macros utilisées par mes collègues qui n'y connaisses absolument rien à Excel...

C'est pour cette raison que j'ai impérativement besoin de faire ces deux opérations (dans une feuille "masquée") en VBA.

Merci encore pour cette réponse.

Denis...

[antonysansh]

Dans ce cas tu le fais manuellement et tu utilises Excel et l'enregistreur de macro

[DenisHen]

Bon, j'ai fini par faire un tri à bulle suivi d'une gestion de doublons et ce, sur plusieurs colonnes...

Si quelqu'un en aurait besoin, ça donne ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
    IMin_Tableau = 2: ColEtat = 1
    Do While Sheets("CfgRegionEtat").Cells(1, ColEtat).Value <> ""
        IMax_Tableau = 2: IMax_Tableau = 2
        Do While Sheets("CfgRegionEtat").Cells(IMax_Tableau, ColEtat).Value <> ""
            IMax_Tableau = IMax_Tableau + 1
        Loop
        IMax_Tableau = IMax_Tableau - 1
        Inversion = True
        While Inversion = True
            Inversion = False
            For I_Test = (IMin_Tableau + 1) To IMax_Tableau
                If Sheets("CfgRegionEtat").Cells(I_Test - 1, ColEtat) > Sheets("CfgRegionEtat").Cells(I_Test, ColEtat) Then
                    ' Echange du contenu des échelons
                    W_Long = Sheets("CfgRegionEtat").Cells(I_Test - 1, ColEtat)
                    Sheets("CfgRegionEtat").Cells(I_Test - 1, ColEtat) = Sheets("CfgRegionEtat").Cells(I_Test, ColEtat)
                    Sheets("CfgRegionEtat").Cells(I_Test, ColEtat) = W_Long
                    Inversion = True
                End If
            Next I_Test
        Wend
        ColEtat = ColEtat + 1
    Loop
 
    LignEtat = 2: ColEtat = 1
    Do While Sheets("CfgRegionEtat").Cells(1, ColEtat).Value <> ""
        LignEtat = 2
        Do While Sheets("CfgRegionEtat").Cells(LignEtat, ColEtat).Value <> ""
            If Sheets("CfgRegionEtat").Cells(LignEtat, ColEtat).Value = Sheets("CfgRegionEtat").Cells(LignEtat + 1, ColEtat).Value Then
                Sheets("CfgRegionEtat").Cells(LignEtat, ColEtat).Select
                Selection.Delete Shift:=xlUp
                LignEtat = LignEtat - 1
            End If
            LignEtat = LignEtat + 1
        Loop
        ColEtat = ColEtat + 1
    Loop

[joe.levrai]

Bonjour,

voici une double proposition, que j'utilise dans plusieurs projets :

1) Une fonction pour gérer les doublons

Elle copie une plage vers une feuille ardoise
Effectue un removeduplicate (doublon sur la colonne 1 uniquement dans l'exemple) et la fonction retourne le Range de la feuille ardoise qui contient la liste sans doublon

Il est assez simple de modifier les fonctionnalités pour récupérer un tableau de données plutôt qu'une plage

Une autre méthode (pour éviter une feuille ardoise de travail) consistera à utiliser un dictionary afin de n'obtenir que les données uniques

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Function SansDoublon(Plage As Range) As Range
' Récupération d'une plage Excel ne contenant que des valeurs sans doublon
' (les valeurs proviennent d'une plage "source" passée en argument de la fonction)
 
    ' utilisation de la feuille ardoise
    With FEUILLE_ARDOISE
        ' nettoyage
        .Cells.Delete
        ' copie de l'ensemble des valeurs à partir de A1
        Plage.Copy .Cells(1, 1)
        ' utilisation de la fonction excel "supprimer les doublons"
        .Cells(1, 1).CurrentRegion.RemoveDuplicates Columns:=1, Header:=xlNo
        ' on renvoie à la fonction la plage de la feuille ardoise qui contient les valeurs sans doublon
        Set SansDoublon = .Cells(1, 1).CurrentRegion
    End With
End Function

2) Tri Alphabétique

Cet exemple est un tri de contrôle (combobox ou listbox), où on a la possibilité de trier en fonction du type de valeur.
L'algorithme de base du tri provient de Jacques BoisGontier (méthode quick sort) qu'on trouve facilement sur son site (véritable caverne d'Ali BABA)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
Sub TriControle(Controle As MSForms.Control, Optional DateNombre As String)
 
' tri de la combobox/listbox par ordre croissant
' fonctionne pour : DATE / CHIFFRES / AUTRES TYPES (String)
 
' la différence pour chaque type de données sera pilotée par les fonctions de conversion
' DATE : utilisation de CDate()
' NOMBRE : utilisation de CLng()
' AUTRES (texte) : pas de conversion de données
With Controle
    Select Case DateNombre
        Case "DATE"
            For k = 0 To .ListCount - 1
                For j = 0 To .ListCount - 1
                    If CDate(.List(k)) < CDate(.List(j)) Then
                        Chaine = .List(k)
                        .List(k) = .List(j)
                        .List(j) = CDate(Chaine)
                        Chaine = ""
                    End If
                Next j
            Next k
        Case "NOMBRE"
            For k = 0 To .ListCount - 1
                For j = 0 To .ListCount - 1
                    If CLng(.List(k)) < CLng(.List(j)) Then
                        Chaine = .List(k)
                        .List(k) = .List(j)
                        .List(j) = CLng(Chaine)
                        Chaine = ""
                    End If
                Next j
            Next k
        Case Else
            For k = 0 To .ListCount - 1
                For j = 0 To .ListCount - 1
                    If .List(k) < .List(j) Then
                        Chaine = .List(k)
                        .List(k) = .List(j)
                        .List(j) = Chaine
                        Chaine = ""
                    End If
                Next j
            Next k
    End Select
End With
 
End Sub

Ce ne sont que des exemples, à adapter au contexte du projet où il est positionné

[RastaBomboclat]

Bonsoir,

Juste pour compléter, par rapport à ton premier poste où tu disais:
"J'aimerais savoir s'il y a un moyen de trier ces cellules (de A2 à A25) tout en supprimant les doublons ? Car en plus, il y a des doublons..."
Voici les quelques lignes de l’enregistreur de macro que j’ai juste retoucher.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub OrdoneAlphabetEtElimineDoublon()
    Range("A2").Select
        Range(Selection, Selection.End(xlDown)).Select
        With Selection
            .RemoveDuplicates Columns:=1, Header:=xlNo
        End With
 
    Range("A2").Select
        Range(Selection, Selection.End(xlDown)).Select
            ActiveWorkbook.Worksheets("Sheet1").Sort.SortFields.Add Key:=Range("A2"), _
            SortOn:=xlSortOnValues, Order:=xlAscending, DataOption:=xlSortNormal
        With ActiveWorkbook.Worksheets("Sheet1").Sort
            .SetRange Selection
            .Header = xlNo
            .MatchCase = False
            .Orientation = xlTopToBottom
            .SortMethod = xlPinYin
            .Apply
        End With
End Sub

Si ça aide...

[patricktoulon]

purée joe pour le tri et les doublons vba pour vba il y a les outils pour ca !!!
celle ci te supprime les doublons et te donne la liste dans l'ordre le tout en une fois
a

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
Sub Exemple_ArrayList_1()
    Dim LsDB As Object, i As Integer
 
    'Set LsDB = CreateObject("System.Collections.ArrayList")'lsdb.sort pour la trier si on se sert de cet object
    Set LsDB = CreateObject("System.Collections.SortedList")    ' pas besoins de trier il le fait tout seul sur cet object
    For Each cel In Sheets(1).Range("A1:A25").Cells
        If Not LsDB.containskey(cel.Text) Then LsDB.Add cel.Text, i
    Next
    Debug.Print "nombre de noms sans doublons : " & LsDB.Count
    Debug.Print " ***** nombres  DES ITEMS "; LsDB.Count
    For i = 0 To LsDB.Count - 1
        Debug.Print LsDB.Getkey(i)
    Next
 
End Sub

[joe.levrai]

Cool,

j'avais déjà vu cet objet il me semble dans un sujet ou deux sur le forum, mais j'ai jamais utilisé.

après, tu me connais, mode bourrin et un jour ... ça s'enjolive.

comme du bon vin


Bon, je vais pouvoir m'y mettre et manipuler ça, merci encore

Juste une question (histoire de gagner du temps dans les tests et la prise en main) : cet objet peut trier de quelle façon ? Sur des chaines de caractères ? Des dates ? Des nombres ?
Ou alors on est limité aux comparaisons de chaines ?

[patricktoulon]

il tri tout !je crois pour les date je n'ai pas essayé je vais faire le test

non les dates ca le fait pas il faut convertir en long je crois pour faire les test

[joe.levrai]

ouais, bosse un peu

naméo


je regarderai plus profondément le sujet quand j'aurai le temps de convertir mes différents projets ... je dois déjà les passer sous VM pour des lancements auto sur serveur. On fera mumuse ensuite

[patricktoulon]

tiens ne regarde plus voila

bosse un peu j't'enfoutrais moi

cet object fonction come le dictionary
(cle/valeur)
il te suffit de mettre la date en long dans les clé et la date en string dans la valeur
et apres le tri tu recupere par le GetByIndex(i) pour la date en string

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Exemple_ArrayList_1()
    Dim LsDB As Object, i As Integer,cel as range
 
    'Set LsDB = CreateObject("System.Collections.ArrayList")'lsdb.sort pour la trier si on se sert de cet object
    Set LsDB = CreateObject("System.Collections.SortedList")    ' pas besoins de trier il le fait tout seul sur cet object
    For Each cel In Sheets(1).Range("B1:B25").Cells
        'MsgBox CLng(cel.Value)
        If Not LsDB.containskey(CLng(cel.Value)) Then LsDB.Add CLng(cel.Value), cel.Text
    Next
    Debug.Print "nombre de noms sans doublons : " & LsDB.Count
    Debug.Print " ***** nombres  DES ITEMS "; LsDB.Count
    For i = 0 To LsDB.Count - 1
        Debug.Print LsDB.GetByIndex(i) & "  --  " & LsDB.Getkey(i)
    Next
 
End Sub

bosse un peu pfiuuuuuuu!!! j't'enfoutrais moi

action reaction c'est comme ca chez moi tu suis?, hahahahaha!!!!!

[boisgontierjacques]

Bonsoir,

Les objets ArrayList et SortedList ne sont pas rapides.

En PJ, une classe + rapide

Boisgontier

[Marc-L]

Bonjour !

Patrick, quand il n'y a pas des dizaines de milliers de données (Jacques a - toujours - raison …),
même pour trier au lieu de SortedList je lui préfère la collection ArrayList car
non seulement elle dispose aussi d'un tri mais surtout elle peut directement alimenter une variable tableau sans boucle !


______________________________________________________________________________________________________
Je suis Paris, Charlie, …