Discussion :

[CIRE3]

bonjour les experts

je reviens d'aujourd'hui de vacances et me voilà confondrai à un probléme dans ma base

lorsque la date dans ma requête est 05/01/[B]2016[/B , Access devrait mettre S1 ... et là Non . Il met semaine 02 !!
voici mon code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Semaine: Format([Date Demandée Commande];"ww")

je n'arrive pas à trouvé l'erreur car pour 2014 et 2015 tout se passé bien

Merci encore pour aide

cordialement
Eric

[jimbolion]

CIRE3

Pas si simple que çà, la semaine est définie par une règle que voici :

https://fr.wikipedia.org/wiki/Num%C3...O_des_semaines

donc pour reprendre l'essentiel :

Si le 1er janvier de l'année est un :
jeudi, alors les lundi 29, mardi 30 et mercredi 31 décembre de l‘année civile précédente font partie de l’année ISO ;
mercredi, alors les lundi 30 et mardi 31 décembre de l‘année civile précédente font partie de l’année ISO ;
mardi, alors le lundi 31 décembre de l‘année civile précédente fait partie de l’année ISO ;
lundi, alors il n'y a pas de différence avec l’année ISO durant presque toute l’année civile, sauf son dernier jour le lundi 31 décembre (ou les deux derniers jours les lundi 30 et mardi 31 décembre si l’année civile est également bissextile) qui sera compté (seront comptés) dans l’année ISO suivante ;
dimanche, alors le dimanche 1er janvier de l’année fait partie de l'année précédente ISO ;
samedi, alors les samedi 1er et dimanche 2 janvier de l‘année font partie de l‘année précédente ISO ;
vendredi, alors les vendredi 1er, samedi 2 et dimanche 3 janvier de l'année font partie de l‘année précédente ISO.

le 1er Janvier 2016 tombant un vendredi il fait partie de l'année ISO précédente soit année n-1

le premier jour de la semaine commençant un dimanche soit le 3.01.2016, la semaine pour la journée du 05/01/2016 tombe donc la semaine 2

bon faut réfléchir à tout çà, mais la logique est là

Cordialement

[Hervé le vieux]

Bonjour,
Voici une petite fonction que j'ai écrite en... 1989 et qui te donne les détails du "pourquoi" (à l'époque j'avais encore des vieux calendriers :

'===============================================================================
Public Function NumSemaine(Julian As Date) As Integer

'CREATION : 16 février 1999 (adaptée d'une fonction écrite en turbo
' Pascal le 25 février 1989 par H. Mary)
' REVISION :
'
' Description:
'
' Cette fonction retourne le numéro de la semaine correspondant a une date
'donnée. Le numéro de la semaine est déterminé conformement à la Norme fran-
'çaise NF Z 10-022 (septembre 1972), elle même conforme à la recommandation
'internationale ISO/R 2015 (janvier 1971) :
' * un numéro de semaine représente toujours un intervalle de 7 jours ;
' * Pour le numérotage des semaines, le lundi est considéré comme le premier
' jour de la semaine ;
' * La première semaine qui doit porter le numéro un dans une année civile
' donnée est la première qui contienne au moins 4 jours de cette année ;
' * Le premier jour de la semaine étant le lundi, la semaine numéro un de
' l'année est celle qui contient le premier jeudi de janvier ;
' * La semaine qui comprend le 1er janvier doit être rattachée à l'année
' qui contient le plus grand nombre de jours de cette semaine ; suivant
' le cas elle doit porter le numéro 52 (ou parfois 53) de l'année n, ou
' le numéro 01 de l'année N+1.
'
'Jeu d'essai pour la vérification :
'
' 1970 Lundi 28 décembre semaine 53
' 1970 Mardi 29 décembre "
' 1970 mercredi 30 décembre "
' 1970 Jeudi 31 décembre "
'==================================
' 1971 Vendredi 01 janvier "
' 1971 Samedi 02 janvier "
' 1971 Dimanche 03 janvier semaine 53
' -------------
' 1971 Lundi 04 janvier semaine 01
' 1971 Mardi 05 janvier "
' ...
' 1971 Dimanche 26 décembre semaine 51
' -------------
' 1971 Lundi 27 décembre semaine 52
' 1971 Mardi 28 décembre "
' 1971 mercredi 29 décembre "
' 1971 Jeudi 30 décembre "
' 1971 Vendredi 31 décembre "
'==================================
' 1972 Samedi 01 janvier "
' 1972 Dimanche 02 janvier semaine 52
' -------------
' 1972 Lundi 03 janvier semaine 01
' 1972 Mardi 04 janvier "
' ...
' 1972 Vendredi 29 décembre semaine 52
' 1972 Samedi 30 décembre "
' 1972 Dimanche 31 décembre semaine 52
'==================================-------------
' 1973 Lundi 01 janvier semaine 01
' 1973 Mardi 02 janvier "
' 1973 mercredi 03 janvier "
' 1973 Jeudi 04 janvier "
' ...
' 1973 Vendredi 28 décembre semaine 52
' 1973 Samedi 29 décembre "
' 1973 Dimanche 30 décembre semaine 52
' -------------
' 1973 Lundi 31 décembre semaine 01
'===================================
' 1974 Mardi 01 janvier "
'
' INFORMATIONS RECUES :
'
' Julian : Date a situer dans une semaine.
'
' VARIABLES MODIFIEES : Néant
'
' MODULES APPELEES :
'
' JourAnnée, NumSemaine (1 niveau de recursivite)
'
' EXCEPTIONS ET CONDITIONS :
'
' * Si l'année est inférieure à 100, elle est supposée faire partie du 20 éme
' siècle pour pouvoir determiner si elle est bissextile.
' * La fonction ne realise aucune verification sur les elements de date
' qui lui sont fournis.
' * Lorsque la date correspond a une semaine de l'année precedente ou suivante,
' la fonction retourne une valeur NEGATIVE, egale au numéro de la semaine
' correspondante (-52 ou -53 pour l'année precedente, -1 pour l'année suivante).
'
'-------------------------------------------------------------------------------

Const Jeudi = 4 'Jeudi est le 4ème jour pour le calcul des numéros de
'semaine.

Dim Année As Integer
Dim J As Integer
Dim Jour As Integer
Dim Mois As Integer
Dim N As Integer

N = JourAnnée(Julian)
Call DateEnJMA(Julian, Jour, Mois, Année)
J = Weekday(DateSerial(Année, Janvier, 1), vbMonday)

'Débuter le comptage des semaines au Lundi le plus proche de la date
'indiquée

If J > Jeudi Then N = N + J - 8 Else N = N + J - 1
If N <= 0 Then
'Moins de 4 jours avant le premier Lundi de l'année : déterminer
'le numéro de la derniere semaine de l'année precedente

NumSemaine = -NumSemaine(DateSerial(Année - 1, Decembre, 31))
Else
'Calculer le numéro de la semaine (division entière du jour par
'le nombre de jours d'une semaine -7-, augmentée de 1 semaine si
'le reste de la division n'est pas nul)
N = N \ 7 + Abs((N Mod 7) <> 0)
NumSemaine = N
If N > 52 Then
'Determiner si 53 ème semaine (plus de 3 jours de la
'semaine dans l'année), ou si premiere semaine de l'année
'suivante.

N = JourAnnée(DateSerial(Année, Decembre, 31)) + J - 8
If N Mod 7 < 4 Then NumSemaine = -1
End If 'N > 52
End If 'N <= 0

End Function 'NumSemaine

[jimbolion]

Hervé le vieux re

oups le code sans la balise code

peu importe la fonction écrite, tu ne dois obéir qu'à une seule règle : celle dictée par les lois en cours...

donc le calcul effectué par Access répond aujourd'hui à ces règles et doivent être appliquées en tant que telles

Jimbolion

[Hervé le vieux]

Pour faire bonne mesure, voici les fonctions qui sont référencés par la précédente... dont certaines existent désormais dans VBA (ce qui n'était pas le cas dans Access 97) :


'===============================================================================
Function JourAnnée(Julian As Date) As Integer

'CREATION : 16 février 1999 (adaptée d'une fonction écrite en turbo
' Pascal le 25 février 1989 par H. Mary)
'REVISIONS :
'DESCRIPTION :
' Cette fonction retourne le numéro du jour de l'année correspondant a
' une date donnée. La détermination de ce jour est réalisée de la façon
' suivante:
'
'La fonction ajoute au nombre de jours écoulés depuis le début du mois
'en cours, le nombre de jour écoulés depuis le début de l'année en cours
'jusqu'à la fin du mois précèdent.
' Si le mois en cours est postérieur a Février, la fonction ajoute le
' jour supplémentaire de ce mois si l'année en cours est bissextile.
'
'INFORMATIONS RECUES:
' Julian : Date pour laquelle on cherche le numéro du jour.
'
' VARIABLES MODIFIEES : Néant;
'
' MODULES APPELEES :
' DateEnJMA, JoursDansMois
'
' EXCEPTIONS ET CONDITIONS :
'
'-------------------------------------------------------------------------------

Dim Année As Integer
Dim Jour As Integer
Dim Mois As Integer

Call DateEnJMA(Julian, Jour, Mois, Année)
For Mois = Mois To Fevrier Step -1
Jour = Jour + JoursDansMois(Mois - 1, Année)
Next Mois
JourAnnée = Jour

End Function 'JourAnnée

'===============================================================================
Public Function JoursDansMois(ByVal Mois As Integer, _
ByVal Année As Integer) As Integer

'CREATION : 16 février 1999 (adaptée d'une fonction écrite en turbo
' Pascal le 16 janvier 1993 par H. Mary)
'REVISIONS :
'DESCRIPTION :
' Cette fonction retourne le nombre de jours du mois dans l'année
'indiquée.
'
'INFORMATIONS RECUES:
' Année : Année à laquelle appartient le mois dont on cherche le nombre
' de jours
' Mois : Mois dont on cherche le nombre de jours
'
' VARIABLES MODIFIEES : Néant
'
' MODULES APPELEES :
' EstBissextile
'
' EXCEPTIONS ET CONDITIONS :
'
'-------------------------------------------------------------------------------

If Année < 100 Then Année = Année + 1900
Select Case Mois
Case 1, 3, 5, 7, 8, 10, 12
JoursDansMois = 31
Case 4, 6, 9, 11
JoursDansMois = 30
Case 2
JoursDansMois = 28 + Abs(EstBissextile(Année))
Case Else
JoursDansMois = 0
End Select

End Function 'JoursDansMois

'===============================================================================
Public Sub DateEnJMA(ByVal Julian As Date, _
ByRef Jour As Integer, _
ByRef Mois As Integer, _
ByRef Année As Integer)

'CREATION : 16 février 1999
'REVISIONS :
'DESCRIPTION :
'
' Cette procédure retourne l'année, le jour et le mois de la date qui lui est
'fournie.
'
'INFORMATIONS RECUES :
' Année : Année dans laquelle on cherche la date du jour
' numéroJour : numéro du jour dans l'Année
'
'VARIABLES MODIFIEES :
' Jour, Mois, Année
'
'ROUTINES APPELEES :
' JoursDansMois, EstBissextile.
'
'EXCEPTIONS ET CONDITIONS :
'
' * Si la date fournie est invalide, la procédure retourne 0 pour le jour, le
' mois et l'année.
'
'-------------------------------------------------------------------------------

If Not IsDate(Julian) Then
Jour = 0
Mois = 0
Année = 0
Else
Année = Year(Julian)
Mois = Month(Julian)
Jour = Day(Julian)
End If
End Sub 'DateEnJMA

[jimbolion]

Hervé le vieux re

Pour faire bonne mesure, voici les fonctions qui sont référencés par la précédente... dont certaines existent désormais dans VBA (ce qui n'était pas le cas dans Access 97) :

Ne parlons plus de bonne mesure ! As tu bien lu les règles sur le calcul de la semaine ?

Lorsque ces rèles seront lues, nous entamerons la lecture de ton code

Jimbolion

[Riton47]

Bonjour,

J'utilise cette fonction pour mes tableaux de bord ou autres au quotidien ;-)
C'est une formule que j'avais trouvé sur excelabo.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Function NOSEM(D As Date) As Long
   D = Int(D)
   NOSEM = DateSerial(Year(D + (8 - Weekday(D)) Mod 7 - 3), 1, 1)
   NOSEM = ((D - NOSEM - 3 + (Weekday(NOSEM) + 1) Mod 7)) \ 7 + 1
End Function

A+
Bonne journée

[jimbolion]

Hervé le vieux bonjour,

Mon esprit embrumé d'hier soir m'a laissé pensé que tu étais à l'initiative de ce fil de discussion.

Toutes mes excuses pour les réponses fournies mais il n'en demeure pas moins que Access te permets de renvoyer la semaine ("ww") en cours sans nécessairement utiliser de fonctions supplémentaires !

Donc

Jimbolion

[nico84]

Bonjour à tous,

Histoire de ramener ma science aussi sur ce sujet délicat, il existe autant de normes de n° de semaine que de pays
Pour ma part, en France et en VBA, j'utilise la formule suivante avec une certaine réussite jusqu'ici :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Public Function semaine(ByVal d as date) As String
semaine = Format(d, "ww", 2, 2)
End Function

[CIRE3]

bonjour les experts

un gros trou de mémoire .
Comment faire appelle à la fonction dans une requête ? j'ai nommé le module M_semaine
puis j'ai mis dans la requête ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

semaine: Format([Date Demandée Commande];"ww";2;2)

le résultat est toujours le même date 05/01/2016 = semaine 02 ( au lieu de S1 )

si je mets le signe semaine = etc .. erreur car il met la semaine d'aujourd'hui .
comment activé la fonction ? en l'appelant à l'ouverture de la base Call M_semaine (mais ça ne fonction pas )
je ne peux pas essayer les autres codes si je ne sais pas cette base.

Merci sincèrement à tous pour votre aide.

Cordialement
Eric

[jimbolion]

CIRE3,

il n'y a rien à faire puisque le 05/01/2016 correspond bien à la semaine 2, reprendre ma réponse #2.

i le 1er janvier de l'année est un :
jeudi, alors les lundi 29, mardi 30 et mercredi 31 décembre de l‘année civile précédente font partie de l’année ISO ;
mercredi, alors les lundi 30 et mardi 31 décembre de l‘année civile précédente font partie de l’année ISO ;
mardi, alors le lundi 31 décembre de l‘année civile précédente fait partie de l’année ISO ;
lundi, alors il n'y a pas de différence avec l’année ISO durant presque toute l’année civile, sauf son dernier jour le lundi 31 décembre (ou les deux derniers jours les lundi 30 et mardi 31 décembre si l’année civile est également bissextile) qui sera compté (seront comptés) dans l’année ISO suivante ;
dimanche, alors le dimanche 1er janvier de l’année fait partie de l'année précédente ISO ;
samedi, alors les samedi 1er et dimanche 2 janvier de l‘année font partie de l‘année précédente ISO ;
vendredi, alors les vendredi 1er, samedi 2 et dimanche 3 janvier de l'année font partie de l‘année précédente ISO.

la solution de Riton semble bien fonctionner dans ton cas

à insérer dans un module :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Public Function NOSEM(D As Date) As Long
   D = Int(D)
   NOSEM = DateSerial(Year(D + (8 - Weekday(D)) Mod 7 - 3), 1, 1)
   NOSEM = ((D - NOSEM - 3 + (Weekday(NOSEM) + 1) Mod 7)) \ 7 + 1
End Function

et tu peux appeler cette fonction de cette manière :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Semaine = NOSEM([Date Demandée Commande])

Attention dans ce cas le 1.01.2016 appartient à la semaine 53 de l'année n-1

Cordialement

jimbolion

[CIRE3]

bonjour les experts

j'ai respecté à la lettre la procédure Module + code et le résultat est pour toutes les date -1
et le code de la requête met automatiquement ceci

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Expr: [Semaine]=NOSEM([Date Demandée Commande])

Je sens que le résultat est pas loin . J'ai passé des heures dessus aujourd'hui et impossible

Merci à tous pour votre aide

cordialement
Eric

[jimbolion]

CIRE3,

oui tu y es presque...

la logique de ton expression renvoie -1 car tu fais une double égalitée

donc

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Semaine: NOSEM([Date Demandée Commande])

++

jimbolion

[CIRE3]

bonjour les experts

un grand MERCI pour votre aide.

Cordialement
Eric

[jimbolion]

CIRE3

A bientôt pour de nouvelles aventures

bonne continuation

jimbolion