Discussion :

[Nono32]

Bonjour à Tous,

J'ai effectué :

1-effectuer un formulaire avec une liste déroulante et un bouton pour effectuer la requête
2-une requête dans laquelle je paramètre le champ Etat

D'habitude cela fonctionne mais aujourd'hui, rien ne vas pourriez-vous me guider pour trouver
mon erreur.

Merci d'avance du temps précieux que vous consacrerez à m'aider

[argyronet]

Bonjour,

Il faut éviter le critère pointant sur un champ de formulaire...

Le mieux est de passer un paramètre où ta requête à en guise de paramètre un mot clé, par exemple [Etat].

De ce fait, tu rédiges ton code comme suit :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Public Function OpenParamQuery(ByVal QueryName As String, ByVal ParameterName As String, ByVal ParameterValue As String) As DAO.Recordset
Dim oQDF                                               As DAO.QueryDef
Dim blnHasRecords                                      As Long
 
    On Error GoTo L_ErrOpenParamQuery
    Set oQDF = CurrentDb.QueryDefs(QueryName)
    With oQDF
        .Parameters(ParameterName) = ParameterValue
        Set OpenParamQuery = .OpenRecordset
        If OpenParamQuery.EOF Then
            err.Raise 3021
        End If
    End With
 
    On Error GoTo 0
L_ExOpenParamQuery:
    Set oQDF = Nothing
    Exit Function
 
L_ErrOpenParamQuery:
    Set OpenParamQuery = Nothing
    Resume L_ExOpenParamQuery
End Function

et tu le testes avec adapatation pour ton cas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub test_OpenParamQuery()
Dim strParameterValue                                  As String
Dim strParameterName                                   As String
Dim strQueryName                                       As String
Dim oRS                                                As DAO.Recordset
    'Définit les paramètres
    strQueryName = "_TestQCommunesParCodePostal"
    strParameterName = "CodePostal"
    strParameterValue = "80120"
    'Appelle la fonction qui retourne un Recordset
    Set oRS = OpenParamQuery(strQueryName, strParameterName, strParameterValue)
    'Retourne le résultat
    If Not oRS Is Nothing Then
        'Le code que tu veux faire...
        oRS.MoveLast
        MsgBox "C'est bon, ça match !!!" & vbCrLf & "Il y a " & oRS.RecordCount & " communes trouvées.", vbInformation
    Else
        MsgBox "Pas de correspondance avec le critère " & strParameterValue, vbExclamation
    End If
End Sub

Argy

[Nono32]

Bonjour Argy et merci pour ta réponse,

J'ai essayé ta solution et cela fonctionne merci encore

Nono32