Requete sur aucun enregistrement

**cjay974** · 13/10/2015, 08h15

Bonjour

j'ai une table planning et une table formateur

Dans ma table planning je rentre des dates et des formateurs ce qui me permet de voir où sont mes formateurs jour/jour
(toutes les dates ne sont pas renseignées, il y à des journées non renseignées)

je souhaiterais savoir si il était possible de lancer une requête entre 2 dates ( entre #01/10/15# et #31/10/15#) mais m'affichant TOUTES les dates pour 1 formateur et non pas seulement celles qui ont un enregistrement.

exemple de ce que je veux :
01/10/15 formateur x
02/10/15 formateur x
03/10/15
04/10/15 formateur x...

ce que j'obtient a ce jour:
01/10/15 formateur x
02/10/15 formateur x
04/10/15 formateur x...
(la date du 03/10/15 qui est vide n'apparait pas)

merci de votre aide

**ClaudeLELOUP** · 13/10/2015, 09h22

Bonjour,

Je ne comprends pas ta question.

Veux-tu la liste des 31 dates d'octobre avec chaque formateur ?

1/10 formateur A
...
...
31/10 formateur A
1/10 formateur B
...
...
31/10 formateur B
...

**cjay974** · 13/10/2015, 10h07

Bonjour Claude LELOUP

ma requête filtre entre 2 dates et sur le nom du formateur (ca pas de soucis)

Effectivement je veux afficher les 31 dates pour ce formateur même les dates où je n'ai aucun enregistrement

Si pas possible par requête voir pour un affichage dans un état ou un formulaire car juste besoin d'avoir un visuel sur le formateur sur la période pour ces dispo ou indispo

merci

**ClaudeLELOUP** · 13/10/2015, 10h25

Si je comprends ton but, je ferais comme ceci : un formulaire dans lequel l'utilisateur
- choisit un formateur dans une liste déroulante
- inscrit une date début et une date fin
- clique un bouton => la liste des dates de l'intervalle s'affiche avec l'affectation (ou blanc) du formateur à ces dates.

C'est ça ?

**cjay974** · 13/10/2015, 11h01

c'est exactement cela

merci de ton aide

**ClaudeLELOUP** · 13/10/2015, 11h09

Dans la db jointe (Access2000), veux-tu ajouter un échantillon des tables nécessaires et reposter le zip.

Prends la précaution que les données personnelles soient fictives.

Cela me permettra de te construire un exemple.

**cjay974** · 13/10/2015, 11h37

ci joint un bout de ma base refaite pour exemple

**ClaudeLELOUP** · 13/10/2015, 14h44

Voici un exemple

Une table tDatesInter qui sera régénérée à chaque demande

Pour la source, une requête qui sera créée à la volée, par exemple pour l’intervalle 1/10/15 => 15/10/15 et le formateur « a »

Code associé au bouton « Afficher »

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Option Compare Database
Option Explicit
 
Private Sub btAfficher_Click()
 Dim dDate As Date
 Dim sSql As String
 'Vérifier les données de la demande
 If IsNull(Me.cboFormateur) Then MsgBox "Vous devez choisir un formateur": Exit Sub
 If Nz(Me.txtAu, #1/1/1900#) < Nz(Me.txtDu, #1/1/2100#) Then MsgBox "Les dates sont incohérentes": Exit Sub
 DoCmd.SetWarnings False
 dDate = Me.txtDu
 'Vidanger
 DoCmd.RunSQL "Delete * From tDatesInter;"
 'Regarnir
 Do While dDate <= Me.txtAu
   DoCmd.RunSQL "INSERT INTO tDatesInter ( DateInter ) SELECT #" & Format(dDate, "mm/dd/yyyy") & "# AS Expr1;"
   dDate = dDate + 1
 Loop
 DoCmd.SetWarnings True
 'Construire la source
 sSql = "SELECT planning.formateur, tDatesInter.DateInter, nz([matiere],""Disponible"") AS Occupation " _
            & "FROM planning RIGHT JOIN tDatesInter ON planning.date = tDatesInter.DateInter " _
            & "WHERE (((planning.formateur)=""" & Me.[cboFormateur] & """ Or (planning.formateur) Is Null));"
 Me.RecordSource = sSql
 'Afficher
 Me.txtDateInter.Visible = True
 Me.txtOccupation.Visible = True
End Sub

**cjay974** · 13/10/2015, 15h09

Claude

merci pour tout c'est exactement cela que j'avais besoin, je vais l'adapter maintenant a ma base

merci de t'être penché sur ma demande

Bonne continuation

MERCI à toi et au site

**cjay974** · 23/10/2015, 12h08

Bonjour Claude

je me suis permis de rouvrir cette discussion, car je ne m'en étais pas rendu compte, il manque des dates qui ne s'affiche pas.
dans ton précédent post regarde sur l'image de ton formulaire il manque la date du 05/10/15 et sur mon adaptation, il me manque des dates aussi.

La table est bien vidée à chaque fois et re-remplie avec toutes les dates
C'est au niveau de la requête qu'il manque des dates dans le résultat.

Merci d'avance de ton aide

Bonne journée

**ClaudeLELOUP** · 23/10/2015, 15h51

Bonjour,

je me suis permis de rouvrir cette discussion, car je ne m'en étais pas rendu compte, il manque des dates qui ne s'affiche pas.

Tu as bien fait, car il y a une erreur de raisonnement dans la requête :

En effet, la requête ne ramènera pas les dates libres pour le formateur alors qu'un autre formateur est actif à cette date.

Je cherche une autre solution...

**cjay974** · 23/10/2015, 17h17

Merci a toi Claude

j'attends ton retour avec impatience

bon courage

**ClaudeLELOUP** · 23/10/2015, 21h32

Cette fois, je crois qu’on y est !

Pour la source, une requête qui sera créée à la volée, par exemple pour l’intervalle 1/10/15 => 15/10/15 et le formateur « a »

Code associé au bouton « Afficher »

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
 
Option Compare Database
Option Explicit
 
Private Sub btAfficher_Click()
 Dim dDate As Date
 Dim sSql As String
 Dim q As QueryDef
 'Vérifier les données de la demande
 If IsNull(Me.cboFormateur) Then MsgBox "Vous devez choisir un formateur": Exit Sub
 If Nz(Me.txtAu, #1/1/1900#) < Nz(Me.txtDu, #1/1/2100#) Then MsgBox "Les dates sont incohérentes": Exit Sub
 DoCmd.SetWarnings False
 dDate = Me.txtDu
 'Vidanger
 DoCmd.RunSQL "Delete * From tDatesInter;"
 'Regarnir
 Do While dDate <= Me.txtAu
   DoCmd.RunSQL "INSERT INTO tDatesInter ( DateInter ) SELECT #" & Format(dDate, "mm/dd/yyyy") & "# AS Expr1;"
   dDate = dDate + 1
 Loop
 DoCmd.SetWarnings True
 'Construire la source
 sSql = "SELECT [DateInter], nz(DLookUp(""matiere"",""planning"",""formateur =""""" & Me.cboFormateur & """"" and date =#"" & Format([DateInter], ""mm/dd/yyyy"") & "" #""),""Disponible"") AS Occupation FROM tDatesInter;"
 Me.RecordSource = sSql
 'Afficher
 Me.Section("Détail").Visible = True
End Sub

La db exemple est ici : http://claudeleloup.developpez.com/&...cjay974%20.mdb

**cjay974** · 27/10/2015, 13h08

Bonjour Claude

Merci ca marche nickel
bravo a toi et encore merci de ton aide

A bientôt pour de nouvelles aventures

Requete sur aucun enregistrement [AC-2003]

Requêtes et SQL.

Discussions similaires

Partager

Partager