Discussion :

[Christophe P.]

Bonjour,

je sais afficher ou cacher un élément (étiquette, zone de texte, de date, etc.) mais je voudrais en regrouper plusieurs de la même manière que les boutons radio dans un groupe d'options. Ceci afin de les cacher tous ensembles sans avoir à les cacher les uns après les autres.

De plus, quand je cache un élément (avec visible = false), il reste une zone vide (à l'endroit où se trouve l'élément caché) qui peut être importante. J'aimerai pouvoir "déplier / plier" un groupe afin que les éléments en dessous remontent et qu'il n'y ai plus d'espace vide.

Quelqu'un a déjà fait ça ?

[poupougnou]

Je l'ai déjà fait sur le détail, en indiquant que si le champs présent dans le détail est vide, le détail ne s'affiche pas, dans ce cas précis la place est libérée. Peut-être que cela fonctionne aussi sur un groupe.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
Private Sub Détail_Format(Cancel As Integer, FormatCount As Integer)
If IsNull(Me.L_OBSERV) Then
Détail.Visible = False
Else
Détail.Visible = True
End If
End Sub

[Christophe P.]

Merci.
Je n'ai pas l'habitude de manipuler l'IHM d'Access, comment fait-on un groupe (autre que le groupe d'options) ?

[ClaudeLELOUP]

Bonjour,

Tu nous parles d'un état ou bien d'un formulaire ?

[loufab]

Bonjour,
Il n'y a pas de notion de groupe d'objet dans la conception d'IHM (elle a disparue dans une version précédente).

Pour agir sur plusieurs contrôles au cour d'un même process, il faut les nommer de manière à le pouvoir.

Exemple :

txtNom_1
txtPrenom_1
txtAge_1


Tu pourras faire une boucle de ce type

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
For each ctrl in me.controls
     if ctrl.name like "*_1" then
        ctrl.visible = false
     endif
next

Si tu as déjà nommé tes controles et que tu ne veux pas y revenir, tu peux simplement utiliser la propriété remarque.
Tu mets dedans "GROUPE_1"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
For each ctrl in me.controls
     if ctrl.tag = "Groupe_1" then
        ctrl.visible = false
     endif
next

Bref ! comme tu le vois beaucoup de possibilités.
Une autre consiste à tester la position (top, left) pour définir une pseudo-zone de groupement. Personnellement je ne m'y aventure pas. Trop complexe et trop de contrainte lié à la définition des écrans.

Cordialement,

[loufab]

De plus, quand je cache un élément (avec visible = false), il reste une zone vide (à l'endroit où se trouve l'élément caché) qui peut être importante. J'aimerai pouvoir "déplier / plier" un groupe afin que les éléments en dessous remontent et qu'il n'y ai plus d'espace vide.

J'avais raté ça.

Il faut travailler avec les top, left... bon amusement.

[Christophe P.]

Merci à tous de m'avoir éclairé sur ce joli bazar !

[ClaudeLELOUP]

Juste pour le fun !









Et un peu de code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
Option Compare Database
Option Explicit
Dim lHauteurZone As Long
 
 
Private Sub Form_Open(Cancel As Integer)
  Dim ctl As Control
  lHauteurZone = Me.TrBas.Top - Me.TrHaut.Top
  'Mémoriser les propriétés d'origine
  For Each ctl In Me.Section("Détail").Controls
    ctl.Tag = ctl.Top & "|" & ctl.Tag
  Next ctl
End Sub
 
Private Sub Form_Current()
  Dim ctl As Control
  Dim tSplit() As String
  'Rétablir les propriétés d'origine
  For Each ctl In Me.Section("Détail").Controls
    tSplit = Split(ctl.Tag, "|")
    ctl.Top = tSplit(0)
    If tSplit(1) = "À cacher" Then ctl.Visible = True
    'Et s'il faut cacher
    If Me.ccMontrer = False Then
        Select Case tSplit(1)
          Case "À cacher"
            ctl.Visible = False
          Case "À remonter"
            ctl.Top = tSplit(0) - lHauteurZone
        End Select
    End If
  Next ctl
End Sub
 
Private Sub ccMontrer_AfterUpdate()
  Call Form_Current
End Sub

Résultat

[Christophe P.]

Merci. Je crois que je vais utiliser quelque chose qui ressemble à ça. Comme je regrette de ne pas pouvoir faire ça en Web !