Projet de création d'une base pour envoyer des mails avec pièces jointes

**Malick** · 27/08/2015, 18h18

Actuellement, le responsable des ressources humaines édite tous les mois les bulletins de salaire des employés. L'assistant se charge ensuite de faire le tour de la société afin de remettre à chaque agent son bulletin ; ce qui constitue pour moi une perte de temps.

Mon objectif : créer une base de données Access qui permettra d’envoyer automatiquement à chaque employé son bulletin de salaire mensuel par mail via Outlook.

L'idée pour moi est de générer chaque mois les bulletins de salaire à partir du logiciel de paie. Les bulletins ainsi générés seront stockés dans un dossier, cela après avoir renommé chaque bulletin de façon à faciliter son identification par la future base de données (exemple de nom : aaaammjj-Mle).

Il s'agira ensuite d'attaquer le dossier afin d'identifier le bulletin de la période pour chaque employé et le lui envoyer automatiquement via Outlook.

Pensez-vous qu'un tel projet est faisable ?

Merci d'avance pour vos avis.

**ClaudeLELOUP** · 27/08/2015, 21h19

Bonsoir Malick,

Ai-je bien compris ?
Il suffit d’une table qui contient l’adresse e-mail de chaque employé.
Ensuite un peu de code pour lire un à un les fichiers contenus dans un répertoire pour les joindre à un mail ?

**Malick** · 27/08/2015, 21h23

Bonsoir Claude,

Merci pour ce retour.

C'est exactement l'idée, sachant que chaque employé ne devra recevoir que son bulletin du mois concerné.

**ClaudeLELOUP** · 27/08/2015, 21h28

Où coinces-tu dans la réalisation ?
L'écriture du code pour confectionner les e-mails ?

**Malick** · 27/08/2015, 21h35

Pour le moment, je doutais de la faisabilité d'une telle base pour faire cela. Maintenant je peux passer à la pratique et proposer un modèle, car j'envisage d'y intégrer les fonctions et les départements.

Qu'en penses-tu ?

Edit : voici mon modèle :

Nom : modele.png
Affichages : 239
Taille : 22,4 Ko

**ClaudeLELOUP** · 27/08/2015, 21h48

je doutais de la faisabilité d'une telle base pour faire cela.

Je crois que c'est relativement simple, s'il s'agit seulement d'envoyer les e-mails, dans la mesure où un logiciel a livré un bulletin de paie sous forme magnétique pour chacun.

**Malick** · 27/08/2015, 21h55

Je crois que c'est relativement simple, s'il s'agit seulement d'envoyer les e-mails, dans la mesure où un logiciel a livré un bulletin de paie sous forme magnétique pour chacun.

Je l'espère bien.

Donc je pense que je peux partir sur le modèle présenté dans mon post précédent ? Si oui, je vais commencer à remplir les tables pour faire les tests.

**ClaudeLELOUP** · 27/08/2015, 21h57

Fais signe si tu as besoin d'aide.

À +

**Malick** · 27/08/2015, 21h59

Fais signe si tu as besoin d'aide.

C'est entendu, je laisse la discussion ouverte.

Merci beaucoup et à bientôt

Bonne soirée.

Malick

**Malick** · 28/08/2015, 17h35

Claude

Pour information :
Je viens de renseigner ma table, maintenant à partir de cette dernière, j'ai créé une requête R_MailEmployes qui sera la source pour envoyer les bulletins ; cela pour ne pas travailler directement sur la table.

Ensuite, je construis un formulaire qui a pour source la requête R_MailEmployes. Sur ce formulaire, je crée un bouton BtnEnvoyerBulletin à laquelle j'affecte le code. Il s'agira de parcourir la requête et envoyer un mail avec le bulletin correspondant.

Nom : Sans titre.png
Affichages : 317
Taille : 32,8 Ko

Maintenant j'ai ce bout de code que j'ai trouvé sur internet et qui, après quelques modifications, fonctionne en envoyant un mail directement via Outlook avec le corps du texte souhaité :

Code vba :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Sub EnvoiBulletinSalaire()
  ' Déclaration d'une variable Application de l'objet Outlook :
    Dim MonOutlook As Object
    Set MonOutlook = Outlook.Application
    Dim EMail As Object
  Set EMail = MonOutlook.CreateItem(olMailItem)
  EMail.To = "employe@societe.sn"
  EMail.Body = "Merci de bien vouloir trouver en pièce jointe votre bulletin de salaire du mois d'août 2015"
  EMail.Subject = "Bulletin de salaire "
  EMail.Send
  Set EMail = Nothing
End Sub

Je continue mes tests pour intégrer les pièces jointes.

@+

**ClaudeLELOUP** · 28/08/2015, 19h50

Bonjour Malick,

Il s'agira de parcourir la requête et envoyer un mail avec le bulletin correspondant.

Je ferais plutôt l’inverse.
Je suppose que les fiches de paie (sans doute des fichiers PDF) sont logées dans un répertoire.
Je lirais un à un les fichiers du répertoire et d’après le nom du fichier, je chercherais (Dlookup) dans la table l’adresse du destinataire pour lui envoyer l’e-mail.

**Malick** · 28/08/2015, 20h00

Bonjour Claude
Merci pour ce retour.

Je ferais plutôt l’inverse.

Je suis d'accord avec cette dernière.

Je suppose que les fiches de paie (sans doute des fichiers PDF) sont logées dans un répertoire.

C'est exactement le cas.

Je lirais un à un les fichiers du répertoire et d’après le nom du fichier, je chercherais (Dlookup) dans la table l’adresse du destinataire pour lui envoyer l’e-mail.

Super. Pour cela est-ce que je peux partir du code de mon précédent post ?

**Malick** · 28/08/2015, 21h05

Question :

Est-ce qu'après la lecture des fichiers du répertoire on doit enregistrer le nom et le chemin de chaque fichier dans une table T créée d'avance ?

**ClaudeLELOUP** · 28/08/2015, 22h09

Regarde cet exemple

Voici un bout de code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
Option Compare Database
Option Explicit
 
Public Declare Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
 
 
Public Sub MailPaie()
  On Error GoTo GestionErreurs
  Dim obFSO As Scripting.FileSystemObject
  Dim obRep As Scripting.Folder
  Dim obFichier As Scripting.File
  Dim sContactNom As String
  Dim sAdresse As String
  Dim obOutlook As Outlook.Application
  Dim obMonMessage As Object
  'Assigner l'objet Outlook
  Set obOutlook = New Outlook.Application
 
  'Lire les fichiers
  Set obFSO = New Scripting.FileSystemObject
  Set obRep = obFSO.GetFolder(CurrentProject.Path & "\Fiches")
  For Each obFichier In obRep.Files
    'Recherche du nom
    sContactNom = Mid(obFichier.Name, 10, Len(obFichier.Name) - 13)
    'Chercher l'adresse
    sAdresse = DLookup("Courriel", "tContacts", "ContactNom=""" & sContactNom & """")
    'Composer le message
    Set obMonMessage = obOutlook.CreateItem(0) 'ouvrir une structure de message
    obMonMessage.To = sAdresse
    obMonMessage.Subject = "Votre fiche de paie"
    obMonMessage.Body = "blabla"
    obMonMessage.Attachments.Add CurrentProject.Path & "\Fiches\" & obFichier.Name
    obMonMessage.Send
    Sleep 2000 'pause de 2 sec pour l'envoi
AuSuivant:
  Next obFichier
 
Liberer:
  Set obFichier = Nothing
  Set obRep = Nothing
  Set obFSO = Nothing
  Set obOutlook = Nothing
GestionErreurs:
  Select Case Err.Number
    Case 0 ' pas d'erreur
      Exit Sub
    Case 94 ' pas trouvé ou pas d'adresse mail
      MsgBox "Pas trouvé l'adresse de : " & sContactNom & " !"
      Resume AuSuivant
    Case Else
      MsgBox "Erreur dans MailPaie N° " & Err.Number & " " & Err.Description
  End Select
End Sub

Tu peux tester dans la fenêtre d'exécution <CTRL+G>

**Malick** · 28/08/2015, 22h17

Merci Claude,

Je teste la base et je te tiens au courant.

**Malick** · 28/08/2015, 22h24

C'est exactement ce dont j'avais besoin.

Maintenant je vais essayer d'adapter ton code à ma base et voir ce que ça donne.

Concernant le nom des fiches de paie, pour harmoniser avec ton code, je pense qu'il faudra que de fasse un code qui renomme tous les fichiers suivant le format proposé, car manuellement cela pourrait être difficile (plus de 50 employés). Est-ce qu'il serait possible de le faire directement dans le code proposé ?

Si oui, je vais tenter de le faire et te proposer quelque chose pour que tu puisses corriger si cela ne marche pas.

Dans cette partie du code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
'Chercher l'adresse
    sAdresse = DLookup("Courriel", "tContacts", "ContactNom=""" & sContactNom & """")

Je pense que faire la recherche du courriel sur la base du Matricule serait plus sécurisant, car il peut y avoir des employés avec le même nom et le même prénom.
Dans ce cas aussi, il faudra remplacer le nom de la fiche de paie par le numéro de matricule (exemple: aaaammjj-Matricule soit 20151231-01 pour l'employé numéro 1).

beaucoup encore.

**ClaudeLELOUP** · 29/08/2015, 06h20

Bonjour Malick,

Concernant le nom des fiches de paie, pour harmoniser avec ton code, je pense qu'il faudra que de fasse un code qui renomme tous les fichiers suivant le format proposé, car manuellement cela pourrait être difficile (plus de 50 employés). Est-ce qu'il serait possible de le faire directement dans le code proposé ?

Je n'ai pas compris ta question.

sur la base du Matricule

Bien sûr ! L'exemple que je te donne est rudimentaire et vaut seulement pour illustrer la méthode.

**Malick** · 30/08/2015, 04h43

Bonjour Claude

Envoyé par ClaudeLELOUP

Bonjour Malick,

Je n'ai pas compris ta question.
.

En fait, pour faire la recherche avec DLookup en se basant sur le numéro de matricule, je pense que le nom des fiches aussi devra contenir le numéro de matricule au moment de l’exportation via le logiciel de paie. Donc pas de code pour modifier les noms comme je le pensais.

Je vais continuer l’adaptation de ton code à ma base, je te tiendrai au courant de mon avancement.

Merci

**ClaudeLELOUP** · 30/08/2015, 06h52

Bonjour,

je pense que le nom des fiches aussi devra contenir le numéro de matricule au moment de l’exportation via le logiciel de paie.

... mais tu n'as sans doute pas la main : le nom du fichier individuel avec la feuille de paie est ce qu'il est ! Déjà, il permet certainement d'identifier le bénéficiaire.

C'est toi qui vas devoir concevoir la table Access qui permet de faire le lien unique entre le nom du fichier qui contient la fiche et l'e-mail du bénéficiaire.

**Malick** · 30/08/2015, 20h21

Envoyé par ClaudeLELOUP

Bonjour,

... mais tu n'as sans doute pas la main : le nom du fichier individuel avec la feuille de paie est ce qu'il est ! Déjà, il permet certainement d'identifier le bénéficiaire.

C'est toi qui vas devoir concevoir la table Access qui permet de faire le lien unique entre le nom du fichier qui contient la fiche et l'e-mail du bénéficiaire.

Super Claude, je n’avais pas pensé à faire cette adaptation au niveau de ma table Access.

Je te tiens au courant de l’avancement des travaux.