Discussion :

[bernardmichel]

Bonsoir,

Occupé à créer une application qui va envoyer des mails via Outlook, je sèche lamentablement pour le remplissage de 3 champs Outlook.

Ci-dessous un printscreen traduisant mon besoin d'information:
Pièce jointe 182384

Mon code pour remplir les autres champs est le suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
    ' Composition et envoi du mail via Outlook
    Set obj = CreateObject("Outlook.application")
    Set objItem = obj.CreateItem(olAppointmentItem)
    With objItem
        .MeetingStatus = olMeeting          ' Type réunion
        .Recipients.Add Me.Email            ' Ajout destinataire
        '.???..... Pour définir le lieu de l'événement
        '.???..... Pour définir la date de début de l'événement
        '.???..... Pour définir la date de fin de l'événement
        .Start = Debut                     ' Début
        .Duration = Duree                  ' Durée
        .Subject = Sujet                    ' Sujet
        .Body = Message                     ' Texte
        .ReminderSet = True                 ' rappel
        .ReminderMinutesBeforeStart = 10    ' rappel x minutes avant
        .BusyStatus = olOutOfOffice         ' absent du bureau
        .Display                            ' affichage pour validation
        .Save
        '.Send
    End With

Donc, ma demande est: Que faut-il mettre pour remplacer les ???... et obtenir ce qui est défini en vert dans mon code ?

Un grand merci d'avance :-)

[loufab]

Bonjour,

C'est du code Outlook.

Je transfère.

Cordialement,

[Oliv-]

Bonjour,
l'aide de OUTLOOK est là pour cela
cherche "AppointmentItem, membres de l’objet"

et tu trouveras (.location .start .end).

Tu peux aussi utiliser les espions dans VBE ou la fenêtre variable locales

[bernardmichel]

Bonjour et merci pour l'info.

Ce que j'ai oublié de dire c'est que mon code est sur Access avec lequel j'envoie un mail via Outlook...

Est-ce que la référence donnée est valable dans ce cas ?

J'avais déjà essayé .location, mais cela générait un message d'erreur après une longue attente...

Merci d'avance.

[bernardmichel]

Re...

Concernant les dates, j'avais simplement oublié d'ajouter la date de la convocation à l'heure de la convocation. C'est corrigé et cela fonctionne.

Maintenant, ne me reste plus qu'à trouver comment remplacer .location puisque cela ne fonctionne pas.

Afin de vous donner les plus d'éléments possible, voici le code en entier:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Private Sub btnMail_Click()
Dim obj         As Outlook.Application
Dim objItem     As Object
Dim frm         As Form
Dim Sujet       As String
Dim Message     As String
Dim DateDebut   As Date
Dim Debut       As Date
Dim Duree       As Integer
 
    Set frm = Me!frmConvocation_sf.Form
    Sujet = "Convocation visite médicale"
    Message = frm!Textmail
    DateDebut = frm!DateVisite
    Debut = DateDebut + frm!Heure
    Duree = IIf(frm!Duree = "1H", 60, 30)
 
    ' Teste la saisie des composants du mail
    If Estvide(frm!cboChoix) Or Estvide(frm!cboLieu) Or Estvide(frm!DateVisite) Or Estvide(frm!Duree) Or Estvide(frm!Heure) Then
        MsgBox ("Veuillez renseigner l'intégralité des champs")
        Exit Sub
    End If
 
    ' Composition et envoi du mail via Outlook
    Set obj = CreateObject("Outlook.application")
    Set objItem = obj.CreateItem(olAppointmentItem)
    With objItem
        .MeetingStatus = olMeeting          ' Type réunion
        .Recipients.Add Me.Email            ' Ajout destinataire
        '.Location = frm!cboLieu
        .Start = Debut                      ' Début
        .Duration = Duree                   ' Durée
        .Subject = Sujet                    ' Sujet
        .Body = Message                     ' Texte
        .ReminderSet = True                 ' rappel
        .ReminderMinutesBeforeStart = 10    ' rappel x minutes avant
        .BusyStatus = olOutOfOffice         ' absent du bureau
        .Display                            ' affichage pour validation
        .Save
        '.Send
    End With
    Set objItem = Nothing
    Set obj = Nothing
    Set frm = Nothing
 
End Sub

Et en plus, voici le message d'erreur généré en utilisant " .location "

Pièce jointe 182439

[Oliv-]

Cela dépend si tu es en "late binding" complet ou pas c'est à dire as tu dans les REFERENCES de VBE (côtè ACCESS) une référence à "MICROSOFT OUTLOOK 15.0 OBJECT LIBRARY" ?

si ce n'est pas le cas toutes tes CONSTANTES "OUTLOOK" sont inconnues, tu peux vérifier en mettant "Option Explicit" en haut de tes modules.

[bernardmichel]

Merci Oliv,

Oui, tous mes codes sont précédés de "Option Explicit".

Mais, j'ai trouvé :-)

Il fallait déclarer:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim objItem     As Outlook.AppointmentItem

en lieu et place de:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim objItem     As Object

Et cela fonctionne à merveille.

Merci pour tes pistes, elles m'ont été très utiles :-))

Bernard.