Discussion :

[webosama80]

Bonjour à tous,

J'arrive maintenant à faire quelques trucs en vba sous Outlook.
Cependant en l'absence d'enregistreur de macro sous outlook, je souhaiterais savoir comment faire pour insérer une image (c:\monimage.jpeg) dans un nouveau mail à l'endroit où mon curseur est actif.

Merci d'avance

[Oliv-]

Bonjour,
Il faut utiliser les macros WORD !

En instanciant un objet wordeditor

ici un exemple qui colle le contenu du presse papier

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
Sub Paste_wordeditor()
 
    Dim outlookwordeditor
    Dim appOutlook As Outlook.Application
    Dim oMail As Outlook.MailItem
 
    ' Set appOutlook = CreateObject("Outlook.Application")
    Set appOutlook = Application
    Set oMail = appOutlook.ActiveInspector.CurrentItem
    Set outlookwordeditor = oMail.GetInspector.WordEditor
 
    'ICI on utilise les intructions WORD précédée de outlookwordeditor.
    Set wdSelection = outlookwordeditor.Application.Selection
    wdSelection.PasteAndFormat Type:=wdFormatOriginalFormatting
 
End Sub

[webosama80]

Bon c'est bon j'ai trouvé, voici le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Sub InsertMyImage()
 
'-----Répertoire temporaire de l'image
Dim MyUserProfile
Dim ADR As String
MyUserProfile = Environ("userprofile")
ADR = MyUserProfile & "\AppData\Local\Temp\snapshot.jpeg"
Dim ViewPointInfoTxt
ViewPointInfoTxt = "ce que vous voulez"
 
'-----Insertion de l'image dans outlook
Dim OlApp As New Outlook.Application
Dim objShape
If TypeName(OlApp.ActiveWindow) = "Inspector" Then
    If OlApp.ActiveInspector.IsWordMail And OlApp.ActiveInspector.EditorType = olEditorWord Then
        Set objShape = OlApp.ActiveInspector.WordEditor.Application.Selection.InlineShapes.AddPicture( _
         FileName:=ADR, LinkToFile:=False, SaveWithDocument:=True)
        With objShape
            .ScaleHeight = 50
            .ScaleWidth = 50
            .AlternativeText = ViewPointInfoTxt
        End With
    End If
End If
 
End Sub

Merci encore pour votre aide