Discussion :

[stdonat]

Bonjour

Je pense avoir noté l'essentiel de mon probléme dans le titre.

Grace au forum et au tuto:

http://silkyroad.developpez.com/VBA/VisualBasicEditor/

, j'arrive a remplacer un module dans un fichier xlsm, grace a du code d'un autre fichier.

Mon problème, c'est que les 60 fichiers (identiques) on tous leur code VBA protégé par MDP.

j'essaye de transmettre le mot de passe via un parametre mais cela ne marche pas...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
        Set Wb = Workbooks.Open(Repertoire & "\" & Fichier)
 
        Application.VBE.MainWindow.Visible = True, password="toto"
'on enleve le module
        With ThisWorkbook.VBProject.VBComponents
            .Remove .Item("Procédures")
        End With

Merci de vos lumiéres

[joe.levrai]

Bonjour,

j'utilise des méthodes à base de sendkeys

éviter d'être dans le VBE quand la macro tourne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
mdp = "test"
Set Application.VBE.ActiveVBProject = Workbooks("test.xlsm").VBProject
SendKeys mdp & "~~"
Application.VBE.CommandBars(1).FindControl(ID:=2578, recursive:=True).Execute

si quelqu'un a une méthode sans SendKeys ou Message, je suis preneur

[stdonat]

Merci Joe,
ton code me permet bien d'ouvrir mon fichier xlsm et d'enlever la protection du VBA, mais lorsque j'essaye de retirer un module via;

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
With Wb.VBProject.VBComponents
            .Remove .Item("Procédures")
        End With

j'ai toujours le message d'erreur

Erreur d'exécution '50289';
Impossible d"'effectuer cette opétaion tant que le projet est protégé.

, pourtant dans VBE je constate bien que mon code VBA n'est plus protégé par MDP...
une idée...

[joe.levrai]

Bonjour,

peux-tu montrer le code complet en ayant intégré ma piste ?

je pense à un problème de temporisation (ça serait cool et simple) ou la nécessité de décocher "projet verrouillé" dans les propriétés (galère car faut remettre en place à la fermeture du fichier !)

[stdonat]

Merci ça avance mais...
Je viens de rajouter une pause (même 2)en effet je n'ai plus de message d'erreur mais par contre ma procédure "Procédures" n'est pas supprimée et je me retrouve avec une deuxième procédure "Procédures1"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
Sub Export_Import_Module()
    Dim Fichier As String, Repertoire As String
    Dim Wb As Workbook
    Dim i As Byte
 
    Application.ScreenUpdating = False
 
    'Adaptez le répertoire des classeurs à modifier
    Repertoire = "O:\Formation"
    'Fichier = Dir(Repertoire & "\*.xlsm")
    Fichier = "Formation_Accueil.xlsm"
 
    'Boucle sur les classeurs du répertoire cible
    Do While Fichier <> ""
        Set Wb = Workbooks.Open(Repertoire & "\" & Fichier)
 
    'on enléve le mdp VBA
        Application.VBE.MainWindow.Visible = True
        mdp = "tyty"
        Set Application.VBE.ActiveVBProject = Wb.VBProject
        SendKeys mdp & "~~"
        Application.VBE.CommandBars(1).FindControl(ID:=2578, recursive:=True).Execute
 
        'une petite pause..
        Application.Wait Now + TimeValue("0:00:03")
 
    'on enleve le module
        With Wb.VBProject.VBComponents
            .Remove .Item("Procédures")
        End With
 
        'une petite pause..
        Application.Wait Now + TimeValue("0:00:03")
'on rajoute le module (et les usf...)
        With Wb.VBProject '
            .VBComponents.Import "C:\Users\Desktop\Procédures.bas"
        End With
 
        Wb.Close True
        Fichier = Dir
    Loop
 
    Application.ScreenUpdating = True
 
    MsgBox "Opération terminée."
End Sub

pourquoi ?

[joe.levrai]

Il faut peut être enregistrer le classeur juste après la suppression du module, peut être qu'Excel conserve en cache le module supprimé ?

[stdonat]

Merci mais en fait le

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

remove item

semble ne pas fonctionner, même en enregistrant juste après le remove, et en supprimant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
'on rajoute le module (et les usf...)
        With Wb.VBProject '
            .VBComponents.Import "C:\Users\Desktop\Procédures.bas"
        End With

j'ai toujours ma procédures attaché a mon fichier

[joe.levrai]

Et si tu ne fais qu'une suppression sans refaire un import, le module reste quand même ?

j'ai jamais eu de souci de ce type, mais faut dire que j'ai jamais détruit un module.


EDIT : euh je viens de relire TRES attentivement ton code

c'est pas plutôt comme ça ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
'on enleve le module
With Wb.VBProject
.VBComponents.Remove .VBComponents("Procédures")
End With

[stdonat]

Oui meme si j'enleve l'import le module n'est pas supprimé. pas plus avec ton code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
'on enleve le module
With Wb.VBProject
.VBComponents.Remove .VBComponents("Procédures")
End With

qu'avec le miens

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
    'on enleve le module
        With Wb.VBProject.VBComponents
            .Remove .Item("Procédures")
        End With

Why ???

[clementmarcotte]

Bonjour,

Si je me fie à ce que je vois il y a un espace de trop dans la ligne.

Sinon, tu peux toujours essayer VBA Code Cleaner.

[joe.levrai]

tu m'as presque fait douter Clément

il n'y a pas d'espace supplémentaire

par acquis de conscience :

- j'ai crée un nouveau classeur
- mis un module standard "Procédures"

lancé le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub oo()
Dim Wb As Workbook
Set Wb = ThisWorkbook
 
With Wb.VBProject.VBComponents
    .Remove .Item("Procédures")
End With
 
End Sub

Résultat : module supprimé !


Résultat identique avec le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub ooBIS()
Dim Wb As Workbook
Set Wb = ThisWorkbook
 
With Wb.VBProject
    .VBComponents.Remove .VBComponents("Procédures")
End With
 
End Sub

[stdonat]

Merci à vous pour votre aide précieuse.

J'ai compris et résolu mon problème...

La procédure que j’essayais de supprimer étant appelé dans le Workbook.before close de mon classeur cela se "mordait un peu la queue"...
Le code final est donc bien celui là avec le rajout du Application.Enable events = false en début et true en fin:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
Sub Export_Import_Module()
    Dim Fichier As String, Repertoire As String
    Dim Wb As Workbook
    Dim i As Byte
 
    Application.ScreenUpdating = False
 
    'Adaptez le répertoire des classeurs à modifier
    Repertoire = "O:\Formation"
    'Fichier = Dir(Repertoire & "\*.xlsm")
    Fichier = "Formation_Accueil.xlsm"
 
    'Boucle sur les classeurs du répertoire cible
    Do While Fichier <> ""
    Application.EnableEvents = False
        Set Wb = Workbooks.Open(Repertoire & "\" & Fichier)
 
    'on enléve le mdp VBA
        Application.VBE.MainWindow.Visible = True
        mdp = "tyty"
        Set Application.VBE.ActiveVBProject = Wb.VBProject
        SendKeys mdp & "~~"
        Application.VBE.CommandBars(1).FindControl(ID:=2578, recursive:=True).Execute
 
        'une petite pause..
        Application.Wait Now + TimeValue("0:00:03")
 
    'on enleve le module
        With Wb.VBProject.VBComponents
            .Remove .Item("Procédures")
        End With
 
        'une petite pause..
        Application.Wait Now + TimeValue("0:00:03")
'on rajoute le module (et les usf...)
        With Wb.VBProject '
            .VBComponents.Import "C:\Users\Desktop\Procédures.bas"
        End With
 
        Wb.Close True
        Fichier = Dir
    Loop
    Application.EnableEvents = True
    Application.ScreenUpdating = True
 
    MsgBox "Opération terminée."
End Sub