Discussion :

[étudiant11]

Bonjour à tous
J'ai besoin de votre aide
J'ai un tableau de ce genre



et je veux avoir un tableau comme celui ci

sachant que publicité1 = count(publicité) pour chaque variété et tarif1= somme(tarif) pour chaque variété et que j'ai une dizaine de variétés
Pièce jointe 176815

[hossward]

Bonjour,
Essayes ce code pour voir si ça donne le bon résultat :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
 
data resultat (drop=tarif publicite rename=(publicite1=publicite tarif1=tarif)) ;
 set tatable;
 by variete notsorted ;
 if first.variete then do ; publicite1=0 ; tarif1=0 ; end ;
 publicite1+1;   tarif1+tarif ;
 if last.variete then output ;
run;

Ward

[étudiant11]

Merci, j'ai eu le résultat mais j'ai eu ce message d'erreur

[étudiant11]

Il ya un autre problème , par exemple si j'ai cette table

voila le résultat que me donne ce code

il fait pas la somme selon la variété pour toute la table dans ce cas

[étudiant11]

J'ai ajouté ce code pour résoudre le problème , je sais pas si y a une solution meileure

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
proc sql noprint ;
   create table resultats as
      select Q25,sum(Q2) as cumul_q2, sum(Q46) as cumul_Q46
      from resultat
      group by Q25
   ;
quit ;

[étudiant11]

S'il vous plait, est ce que c'est possible d'avoir un tableau pareil à partir de mon tableau initial?

[hossward]

Merci, j'ai eu le résultat mais j'ai eu ce message d'erreur

C’est normal car la variable « publicite » n’existe pas dans ta table initiale !

[hossward]

Il ya un autre problème , par exemple si j'ai cette table

voila le résultat que me donne ce code

il fait pas la somme selon la variété pour toute la table dans ce cas

C’est aussi normal parce que j’ai utilisé l’instruction « NOTSORTED » en croyant que ta table initiale a été triée au préalable et ce n’était pas le cas.
Donc, il faut réellement trier la table « by Q25 ». Voici le code avec ton exemple:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
data pub ;
input Q25 $ Q2 $ Q46 ;
cards ;
lait  tv 150
lait  radio 100
janbon tv 150
janbon press 50
janbon radio 145
lait  radio 100
janbon tv 20
;  run ;  

proc sort data=pub ; by Q25 ; run ;

data result (drop=Q2 Q46) ;
 set pub;
 by Q25 ;
 if first.Q25 then do ; Freq_Q2=0; Cummul_Q46=0 ; end ;
 Freq_Q2+1;   Cummul_Q46+Q46 ;
 if last.Q25 then output ;
run;

Ward

[hossward]

Je sais pas si y a une solution meileure

J’ai rectifié ton code SQL pour qu’il fonctionne correctement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
proc sql noprint ;
   create table resultats as
      select Q25, count(Q2) as cumul_q2, sum(Q46) as cumul_Q46
      from pub 
      group by Q25 ;
quit ;

Ward

[hossward]

S'il vous plait, est ce que c'est possible d'avoir un tableau pareil à partir de mon tableau initial?

Qui :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
proc sort data=pub ; by Q25 Q2 ; run ;
 
data resultats;
 set pub;
  by Q25 Q2 ;
 if first.Q2 then Somme=0;
 Somme+Q46;
if last.Q2 then output ;
run;		 
 
option missing=0 ;
proc transpose DATA=resultats out=out_result(drop=_name_)  ;
	BY Q25;
	var Somme;
	id Q2;
run;

Cordialement Ward

[étudiant11]

merci infiniment ward pour vos réponses , ça marche

[étudiant11]

S'il vous plait est ce qu'il y a des procédures qui peuvent me donner le résultat directement??

[hossward]

S'il vous plait est ce qu'il y a des procédures qui peuvent me donner le résultat directement??

Oui, il y a proc SUMMARY et proc TRANSPOSE dans ce cas là.
Proc SUMMARY remplace le code proposé dans le cadrant #8 et tu peux utiliser directement cette procédure sans trier la table PUB.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
data Pub   ;
input Q25 $ Q2 $ Q46 ;
cards ;
lait  tv 150
lait  radio 100
janbon tv 150
janbon press 50
janbon radio 145
lait  radio 100
janbon tv 20
;  run ;  
 
proc summary data=Pub nway;
class Q25 Q2 ;
var Q46;
output out=Summary_Table(drop=_type_ _freq_)  sum=somme;
run;   
 
option missing=0 ;
proc transpose DATA=Summary_Table out=Transpose_Table(drop=_name_)  ;
BY Q25;
var Somme;
id Q2;
run;

Cordialement
Ward

[étudiant11]

Sil vous plait, cette forme de tableau je peux l'avoir aussi avec une procédure ??

à partir de cette table


J'ai eu le résultat en utilisant proc summary et proc transpose, simplement je n'ai pas eu le fusionnement que je dois avoir au niveau de la variété.
C'est ce que j'ai eu

Que puis je faire ?

[m.brahim]

Bonjour,

Sil vous plait, cette forme de tableau je peux l'avoir aussi avec une procédure ??

Avec proc tabulate:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
data test;
input variete $ mois $ marque $ investi ;
 
cards;
lait 1 oo 400
lait 2 bf 1400
chocolat 3 ml 145
lait 3 oo 147
biscuit 2 kj 256
chocolat 2 mp 589
biscuit 1 hg 58
lait 3 bf 145
biscuit 2 kj 456
;run;
 
proc format ;
value $ moiss
'1'='Janvier'
'2'='Février'
'3'='Mars';
run;
proc tabulate data=test;
 
class variete mois marque;
var investi;
table variete*marque , mois=''*investi=''*sum='' all=''*investi='Total'*sum='';
format mois  $moiss.;
run;

Cordialement

[étudiant11]

Merci brahim ça me donne le résultat que je cherche voila ce que j'ai eu

Mais est ce que je peux mettre marque en même ligne avec les mois c-à-d

[m.brahim]

Avec quelques modifications, voici ce que j'ai réussi à faire.

Est ce cela répond à ta question?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
 
ODS RTF file='c:\sas\test.rtf' ; 
proc tabulate data=test  S=[FOREGROUND=BLACK CELLWIDTH=200 JUST=C];
 
class variete mois marque;
classlev marque /s=[CELLWIDTH=100];
var investi;
table variete=''*marque='', mois=''*investi=''*sum='' all=''*investi='Total'*sum=''/  box={label='marque'  s=[ JUST=R ]}  rts=25   ;
format mois  $moiss. ;
run;
ods rtf close;

Cordialement

[étudiant11]

merci brahim oui ça marche