Discussion :

[AlexFred]

Bonjour,
j'ai une base sas avec des formats et des labels associés.
Le nom des formats correspond au nom des variables suffixés par "_F"

J'aimerais renommer les variables, mais aussi les labels et les formats.

J'ai une base sas de correspondance des variables entre ancien_nom et nouveau_nom.
Y a t-il une possibilité de changer ces 3 éléments.

Je suppose que c'est un problème qui a dû se poser à pas mal de personnes.
D'avance merci.

[Fabien G.]

Bonjour AlexFred,

Regarde avec la fonction "call symputx" (ou par un proc sql si tu préfères) pour mettre tous tes anciens et nouveaux noms et labels en macros variables.
Et avec une petite boucle "do to" tu fais x instructions "rename" et "label".
Il doit y avoir des bouts de programme "touts faits" dans d'anciens messages sur le forum ou sur le net.
Exemple : http://www2.sas.com/proceedings/sugi29/052-29.pdf

Bon courage !

[m.brahim]

Bonjour,

Je te propose cette solution:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
 
data test2;
set sashelp.class;
run;
 
/*table de référence*/
data test1;
input anc_noms $ nv_noms $  nv_format $ ;
cards;
name namen $10.
age agen 10.
sex sexn $2.
weight weightn 15.
height heigthn 10.
;run;
 
/* renommer les variables*/
DATA _null_ ;
  SET test1 end=LAST;
  IF _n_=1 then call execute ('proc datasets lib=WORK ;   modify test2; rename') ;
 
  call execute ( compress (anc_noms) !! '=' !! compress (nv_noms) );
 
 
  IF last then call execute (';quit;');
run ; 
 
/*modifier les labels*/
 
DATA _null_ ;
  SET test1 end=LAST;
  IF _n_=1 then call execute ('proc datasets lib=WORK ;   modify test2; label') ;
 
  call execute ( compress (nv_noms) !! '=' !! compress (nv_noms)||'_F' );
 
  IF last then call execute (';quit;');
run ;
 
 
/*modifier les formats*/
proc sql noprint;
  select catx(' ',nv_noms,nv_format) into :formats separated by ' ' from  test1;
 
quit;
proc datasets nolist ;
  modify test2;
  format &formats;
  run;
quit;

Cordialement

[AlexFred]

Bonjour,
tout d'abord merci à vous 2.

Effectivement cette méthode marche très bien pour des fomats simple du style $10., 15., ...
Mais comment faites vous avec des formats du style $name_F. qui renvoie à un catalogue de format contenant tous les anciens formats.

Il faut que je les remplace d'abord dans le catalogue qui peut en contenir quelques milliers.
Donc je me dis que soit je les remplace dans le programme sas de création du catalogue mais c'est un travail de fou, soit je les remplace directement en utilisant proc catalogue, mais j'avoue que je ne vois pas trop comment faire?
Cordialement?

[hossward]

Bonjour,
J'ai repris et modifié une partie du code précédent pour te proposer une solution qui renomme les anciens formats du style $name_F.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
 
data Classe ;
set sashelp.class;
run;	 
 
/*table de correspondance */
data corresp ;
input anc_noms $ nv_noms $ anc_format $ ;
cards;
NAME NAMEN $NAME_F.
AGE AGEN AGE_F.
SEX SEXN $SEX_F.
WEIGHT WEIGHTN WEIGHT_F.
HEIGHT HEIGHTN HEIGHT_F.
;run;	  
 
/* renommer les variables */
DATA _null;
SET corresp end=LAST;
IF _n_=1 then call execute ('proc datasets lib=WORK ;  modify Classe ; rename') ;
 call execute ( compress (anc_noms) !! '=' !! compress (nv_noms) );
IF last then call execute ('; quit ;') ;
run ; 	 
 
/* créer des nouveaux formats */
data nv_format ;
set corresp ;
if findc(strip(anc_format), '$') then nv_format=cats('$', nv_noms, '_F.') ;
else nv_format=cats(nv_noms, '_F.') ;
run;	  
 
proc format;
value   $NAMEN_F ; 
value     AGEN_F ; 
value    $SEXN_F 'M'='1' 'F'='2' ;
value  WEIGHTN_F ; 
value  HEIGHTN_F ;
run ;
 
/* renommer les formats */
DATA _null;
SET nv_format end=LAST;
IF _n_=1 then call execute ('proc datasets lib=WORK ;  modify Classe ; format') ;
 call execute ( strip(nv_noms) !! ' ' !! strip(nv_format) );
IF last then call execute ('; quit ;') ;
run ; 
 
/* Vérification */
proc contents data=Classe ; run ;

Ward