Discussion :

[Stifoun]

Bonjour la communauté,

J'ai un petit problème pour finaliser ma macro. Je n'autorise l'utilisation du programme qu'entre certaines heures
entre heure1 et heure2
entre heure3 et heure4
entre heure5 et heure 6

J'ai mis en place une fonction mais cela ne marche pas, une idée ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Function CtrlHeure() As Boolean
 
'Déclaration des variables
Dim wb1 As Workbook
Dim wsTechnique As Worksheet
 
'Déclarations des raccourcis
Set wb1 = Workbooks("Matrice FATCA.xlsm")
Set wsTechnique = wb1.Worksheets("Technique")
 
Dim heureactuelle As Date
Dim heure1 As Date
Dim heure2 As Date
Dim heure3 As Date
Dim heure4 As Date
Dim heure5 As Date
Dim heure6 As Date
 
heureactuelle = Format(Time, "hh:mm:ss")
 
heure1 = Format(wsTechnique.Range("q4"), "hh:mm:ss")
heure2 = Format(wsTechnique.Range("r4"), "hh:mm:ss")
heure3 = Format(wsTechnique.Range("q5"), "hh:mm:ss")
heure4 = Format(wsTechnique.Range("r5"), "hh:mm:ss")
heure5 = Format(wsTechnique.Range("q6"), "hh:mm:ss")
heure6 = Format(wsTechnique.Range("r6"), "hh:mm:ss")
 
Select Case heureactuelle
    Case heureactuelle > heure1 And heureactuelle < heure2
        CtrlHeure = True
    Case heureactuelle > heure3 And heureactuelle < heure4
        CtrlHeure = True
    Case heureactuelle > heure5 And heureactuelle < heure6
        CtrlHeure = True
    Case Else
        CtrlHeure = False
End Select
 
End Function

D'avance, un grand merci

[Philippe Tulliez]

Bonjour,
C'est l'utilisation du Select Case qui n'est pas correcte.
Ce n'est pas

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 Case heureactuelle > heure1 And heureactuelle < heure2

mais

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Case Is > heure1, Is < heure2

et sauf erreur de ma part, la conversion en format est inutile
Ceci fonctionne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
heureactuelle = Time   ' Format(Time, "hh:mm:ss")
heure1 = wsTechnique.Range("q4")    ' Format(wsTechnique.Range("q4"), "hh:mm:ss")

[Stifoun]

Bonjour Philippe et merci pour ta réponse,

Merci pour la révision syntaxique du case, cela me parait plus cohérent.

Le problème que je rencontre avec ceci ...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Case Is > heure1, Is < heure2

... est qu'il ne signifie pas entre ces deux heures, c'est un OR et non un AND

@+

[Stifoun]

Cela fonctionne avec cela

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Select Case heureactuelle
    Case heure1 To heure2
        CtrlHeure = True
    Case heure3 To heure4
        CtrlHeure = True
    Case heure5 To heure6
        CtrlHeure = True
    Case Else
        CtrlHeure = False
End Select

Un grand merci pour votre aide, mon utilisation du case était effectivement pas correcte

Au plaisir

[joe.levrai]

Bonjour,

tu peux réutiliser la logique de Philippe afin de réduire ton nombre de Case : le regroupement des cas qui génèrent la même action

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Select Case heureactuelle
    Case heure1 To heure2, heure3 To heure4, heure5 To heure6
        MsgBox "autorisé"
    Case Else
        MsgBox "interdit"
End Select

[Philippe Tulliez]

Bonjour Joe,
Bien vu, nettement mieux

[Stifoun]

Effectivement, c'est nickel,

Merci beaucoup à vous deux