Ordonnancement fabrication calendrier

**Commandeur** · 16/04/2015, 21h48

bonjour,

je recherche a faire un ordonnancement, je n'arrive pas a trouvé une solution.
je ne suis pas expert en vba;

voici me donnée :

table1:

jour , temps_travail, départ, fin

lundi ,10h00, 07h00, 17h00
Mardi , 10h00, 07h00, 17h00
Mercredi , 10h00, 07h00, 17h00
jeudi , 10h00, 07h00, 17h00
Vendredi , 6h00, 07h00, 13h00

table2

ordre de fabrication, désignation , qte , temps_fabrication

1,carte1,250,08h00
2,carte2,500,10h00
3,carte3,600,02h00
3,carte4,200,7h00
4,carte5,100,2h00

table3 (date de départ du planning)

Datedepart, heuredepart
15/03/15 , 07h00

Donc je souhaiterais avoir ce résultat :

odre, designation, qte , date de début ,date de fin

1,carte1,250,15/03/15 07h00 , 15/03/15 15h00
2,carte2,500,15/03/15 15h00 , 16/03/15 15h00
3,carte3,600,16/03/15 15h00 , 17/03/15 17h00
3,carte4,200,17/03/15 07h00 , 17/03/15 14h00
4,carte5,100,17/03/15 14h00 , 17/03/15 16h00

Bien sur à tenir compte des jours ferries , les week-end etc.

Si vous trouve une solution je suis preneur... Grand merci de votre aide

**Didier L** · 17/04/2015, 16h34

Bonjour,

Merci pour l’exercice

Voila ta réponse :

Table1 :
Nom : Sans titre.png
Affichages : 604
Taille : 8,1 Ko

Table2 :

Nom : Sans titre.png
Affichages : 658
Taille : 11,4 Ko

Pas besoin de la table 3

Création d'une Table4 pour stocker le résultat :
Nom : Sans titre.png
Affichages : 631
Taille : 6,6 Ko

Voila le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
Sub CreeMonCalendrier(ByVal MonDepart As Date)
Dim MesFabrications As Recordset
Dim Mafin As Date
    Set MesFabrications = CurrentDb.OpenRecordset("Select * from Table2 Order By [ordre de fabrication]", dbOpenSnapshot)
    With MesFabrications
        While Not .EOF
            Mafin = CalculDateFin(MonDepart, !temps_fabrication)
            CurrentDb.Execute "INSERT INTO Table4 (ordre, designation,qte,[date de début],[date de fin]) values (" & _
                              ![ordre de fabrication] & ",'" & !désignation & "'," & !qte & ",#" & _
                              Format(MonDepart, "mm/dd/yyyy hh:mm") & "#,#" & Format(Mafin, "mm/dd/yyyy hh:mm") & "#)"
            MonDepart = Mafin
            .MoveNext
        Wend
    End With
End Sub
 
Function CalculDateFin(ByVal Debut As Date, ByVal Temps As Integer) As Date
Dim heurefin As Date
Dim NbhRestante As Integer
Dim Mafin As Date
Dim heuredebut As Date
    heurefin = DLookup("fin", "table1", "jour='" & Format(Debut, "dddd") & "'")
    NbhRestante = Temps - (DateDiff("h", Format(Debut, "hh:mm"), heurefin))
    If NbhRestante > 0 Then
        Mafin = Debut
        While NbhRestante > 0
            Do
                Mafin = Mafin + 1
            Loop While JourChome(Mafin)
            heuredebut = DLookup("départ", "table1", "jour='" & Format(Mafin, "dddd") & "'")
            Mafin = DateAdd("h", NbhRestante, DateSerial(Year(Mafin), Month(Mafin), Day(Mafin)) + heuredebut)
            heurefin = DLookup("fin", "table1", "jour='" & Format(Mafin, "dddd") & "'")
            NbhRestante = (DateDiff("h", heurefin, Format(Mafin, "hh:mm")))
        Wend
    Else
        Mafin = DateAdd("h", Temps, Debut)
    End If
    CalculDateFin = Mafin
End Function
 
Function JourChome(ByVal pdDate As Date) As Boolean
    Select Case Format(pdDate, "w", vbMonday)
        Case 6, 7 'Samedi et dimanche
            JourChome = True
        Case Else 'Autres jour de la semaine
            If EstFerie(pdDate) Then
                JourChome = True
            Else
                JourChome = False
            End If
    End Select
End Function
 
Function EstFerie(ByVal QuelleDate As Date) As Boolean
Dim anneeDate As Integer
Dim joursFeries(1 To 11) As Date
Dim I As Integer
  anneeDate = Year(QuelleDate)
  joursFeries(1) = DateSerial(anneeDate, 1, 1)
  joursFeries(2) = DateSerial(anneeDate, 5, 1)
  joursFeries(3) = DateSerial(anneeDate, 5, 8)
  joursFeries(4) = DateSerial(anneeDate, 7, 14)
  joursFeries(5) = DateSerial(anneeDate, 8, 15)
  joursFeries(6) = DateSerial(anneeDate, 11, 1)
  joursFeries(7) = DateSerial(anneeDate, 11, 11)
  joursFeries(8) = DateSerial(anneeDate, 12, 25)
  joursFeries(9) = fLundiPaques(anneeDate)
  joursFeries(10) = joursFeries(9) + 38 ' Ascension = lundi de Pâques + 38
  joursFeries(11) = joursFeries(9) + 49 ' Lundi Pentecôte = lundi de Pâques + 49
  For I = 1 To 11
    If QuelleDate = joursFeries(I) Then
      EstFerie = True
      Exit For
    End If
  Next
End Function
 
Private Function fLundiPaques(ByVal Iyear As Integer) As Date
        'Adapté de +ieurs scripts...
        Dim L(6) As Long, Lj As Long, Lm As Long
        L(1) = Iyear Mod 19: L(2) = Iyear Mod 4: L(3) = Iyear Mod 7
        L(4) = (19 * L(1) + 24) Mod 30
        L(5) = ((2 * L(2)) + (4 * L(3)) + (6 * L(4)) + 5) Mod 7
        L(6) = 22 + L(4) + L(5)
        If L(6) > 31 Then
                Lj = L(6) - 31
                Lm = 4
        Else
                Lj = L(6)
                Lm = 3
        End If
        ' Lundi de Pâques = Pâques + 1 jour
        fLundiPaques = DateAdd("d", 1, (Lj & "/" & Lm & "/" & Iyear))
End Function

Voila le résultat pour l'appel suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

CreeMonCalendrier #3/16/2015 7:00:00 AM#

je suis parti du 16 mars car le 15 était un dimanche

Nom : Sans titre.png
Affichages : 666
Taille : 13,6 Ko

on peut ensuite vider la table manuellement et relancer la procédure avec une autre date

Exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

CreeMonCalendrier #4/16/2015 7:00:00 AM#

résultat :
Nom : Sans titre.png
Affichages : 720
Taille : 14,1 Ko

Attention le calcul sera plus complexe et ne marchera pas ainsi si tu as des temps de fabrication plus grand du style 20h ou plus !

**Commandeur** · 17/04/2015, 20h53

Merci de ton aide,

Je vais essayer de le faire ce soir, effectivement j'ai des cartes de plus 20h de boulot.

Le calcule ne vas pas marcher? ou il sera plus long a ce faire?

Quel est le maximum d'heure ? je peux faire deux lignes si besoins ,

exemple: carte1 = 25 heures
carte1 =10 heures
carte1 =15 heures

Dans tous les cas je te remercie de ton aiguillage dans mon projet

**Didier L** · 17/04/2015, 21h15

Le calcule ne vas pas marcher? ou il sera plus long a ce faire?

Non le calcul risque de ne pas marcher à chaque fois car dans l'état actuel, selon ma formule, parfois on risque de se retrouver à 00:00 ;-/

Si besoin, il suffit de retravailler la fonction

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Function CalculDateFin(ByVal Debut As Date, ByVal Temps As Integer) As Date

Je regarderai cela demain, avec une autre approche pour cette fonction

**Commandeur** · 18/04/2015, 00h16

Bonsoir,

Juste je ne trouve pas comment modifier ma date de départ en passant dans un formulaire.

sinon effectivement quant je dépasse un temps fabrication (+19h) sa part en live et je ne comprend pas.

Éventuellement c'est mettre un condition supplémentaire dans le code , si sa dépasse 19h de temps de fabrication c'est de faire 2 lignes
Mon temps fabrication ne peux pas dépassé 48

Je t'envoie mon projet.

MerciBase de données3.rar

**Didier L** · 18/04/2015, 10h20

Bonjour,

Voila une nouvelle version de la fonction "CalculDateFin".
Elle modifie également la date de début (passée par adresse) dans le cas ou cette dernière serait soit un jour chômé soit que son heure soit l'heure de fin de journée.
Bref tous les cas sont gérés

Attention tout ceci ne marche car nous sommes sur un planning avec des heures entières et que nous partons toujours d'une heure entière également!

Voila le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Function CalculDateFin(Debut As Date, ByVal Temps As Integer) As Date
Dim heurefin As Date
Dim NbhRestante As Integer
Dim Mafin As Date
Dim heuredebut As Date
    While JourChome(Debut)
        Debut = Debut + 1
    Wend
    Mafin = DateAdd("h", Temps, Debut)
    heurefin = DLookup("fin", "table1", "jour='" & Format(Debut, "dddd") & "'")
    If (DateDiff("h", Format(Debut, "hh:mm"), heurefin) = 0) Then
        Do
            Debut = Debut + 1
        Loop While JourChome(Debut)
        heuredebut = DLookup("départ", "table1", "jour='" & Format(Debut, "dddd") & "'")
        Debut = DateSerial(Year(Debut), Month(Debut), Day(Debut)) + heuredebut
        Mafin = DateAdd("h", Temps, Debut)
        heurefin = DLookup("fin", "table1", "jour='" & Format(Debut, "dddd") & "'")
    End If
    NbhRestante = Temps - (DateDiff("h", Format(Debut, "hh:mm"), heurefin))
    If NbhRestante > 0 Then Mafin = Debut
    While NbhRestante > 0
        Do
            Mafin = Mafin + 1
        Loop While JourChome(Mafin)
        heuredebut = DLookup("départ", "table1", "jour='" & Format(Mafin, "dddd") & "'")
        heurefin = DLookup("fin", "table1", "jour='" & Format(Mafin, "dddd") & "'")
        If NbhRestante <= (DateDiff("h", heuredebut, heurefin)) Then
            Mafin = DateAdd("h", NbhRestante, DateSerial(Year(Mafin), Month(Mafin), Day(Mafin)) + heuredebut)
            NbhRestante = (DateDiff("h", heurefin, Format(Mafin, "hh:mm")))
        Else
            NbhRestante = NbhRestante - (DateDiff("h", heuredebut, heurefin))
        End If
    Wend
    CalculDateFin = Mafin
End Function

Je te retourne également ta base avec un exemple de saisie de date de départ dans ton formulaire pour pouvoir créer ton calendrier a la date voulue

Base de données3.rar

**Commandeur** · 18/04/2015, 11h54

Bonjour

merci pour ta modifie, le fichier en exemple est corrompue. Je ne peux pas le lire, tu peux me le renvoyer stp

Merci bonne journée.

**Didier L** · 18/04/2015, 13h12

Voila

Base de données3.rar

**Commandeur** · 23/04/2015, 20h06

Bonjour,

J'ai bientôt fini mon projet grâce a toi, juste j'ai un soucis;

-->Quant je tape la date de départ avec l'heure , il tiens plus compte de jours ferries et le week-end.
et pour le même soucis si je le relance plusieurs fois

Deuxième question:

dans ton code ci dessous, je souhaite rajouter des champs supplémentaire est je n'arrive pas comprendre comment le faire sur ton code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
While Not .EOF
            Mafin = CalculDateFin(MonDepart, !temps_fabrication)
            CurrentDb.Execute "INSERT INTO Table4 (ordre, designation,qte,cod_article,[date de début],[date de fin]) values (" & _
                              ![ordre de fabrication] & ",'" & !designation & "'," & !qte & "," & !cod_article & ",#" & _
                              Format(MonDepart, "mm/dd/yyyy hh:mm") & "#,#" & Format(Mafin, "mm/dd/yyyy hh:mm") & "#)"
            MonDepart = Mafin
            .MoveNext
        Wend

Merci des lumieres

**Didier L** · 24/04/2015, 00h24

Quant je tape la date de départ avec l'heure , il tiens plus compte de jours ferries et le week-end.
et pour le même soucis si je le relance plusieurs fois

Quelle heure tapes tu ?
Donne moi un exemple ?

Que fais t'il si tu le relance plusieurs fois ?
Quel est ton souci ?

Si tu veux rajouter la valeur1 dans le champ1 essaye comme cela :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
 CurrentDb.Execute "INSERT INTO Table4 (ordre, designation,qte,cod_article,[date de début],[date de fin], [Champ1]) values (" & _
                              ![ordre de fabrication] & ",'" & !designation & "'," & !qte & "," & !cod_article & ",#" & _
                              Format(MonDepart, "mm/dd/yyyy hh:mm") & "#,#" & Format(Mafin, "mm/dd/yyyy hh:mm") & "#," & valeur1 & ")"

**Commandeur** · 24/04/2015, 06h43

bonjour,

je te "21/04/2015 08:00:00 " pour que mon planning commence a la date de 22/04/2015 a 15h00

**Didier L** · 24/04/2015, 09h12

je te "21/04/2015 08:00:00 " pour que mon planning commence a la date de 22/04/2015 a 15h00

Pourquoi mettre une date pour que le planning commence à une autre ???

Je ne comprends pas ?

**Commandeur** · 24/04/2015, 14h28

Je me suis trompé dans le msg,

je tape "21/04/2015 08:00:00 " pour que mon planning commence a la date de 21/04/2015 a 15h00

Nom : Sans titre.png
Affichages : 729
Taille : 142,1 Ko

Nom : Sans titre.png
Affichages : 729
Taille : 142,1 Ko

**Didier L** · 24/04/2015, 14h46

Alors pourquoi mettre 8:00 si tu veux qu'il commence à 15:00 ??

Dans mon exemple de code j'avais mis 7h00 en dur dans le programme pour que tu ne choisisse que la date et du coup il comenncait toujours à 7h00.
Mais si ce n'est pas le cas, si tu renseigne la date et l'heure, alors enlève dans le code la partie ou je rajoute les 7h00.
Mais attention de bien toujours saisir une heure "ronde" et pas des 15h30 etc ....
La fonction ne gère pas les minutes

PS: ta capture d'écran est illisible pour moi

Ecrit en trop petit

**Commandeur** · 24/04/2015, 15h14

effectivement, il me faut la date est l'heure du début

Voici mon projet, tu me diras ce que tu en pense

ordonnancement phase 03.rar ordonnancement phase 03.rar

**Didier L** · 24/04/2015, 15h53

Pas de soucis pour saisir ta date et ton heure de début dans ce cas utilise le code suivant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
CreeMonCalendrier DateDepart

Tout simplement

A quoi te servent les lignes suivantes ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
DoCmd.RunCommand acCmdSaveRecord
  stDocName = "test2"
    DoCmd.RunMacro stDocName
...

et

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
...
     DoCmd.RunCommand acCmdSaveRecord
  stDocName = "test"
    DoCmd.RunMacro stDocName
End Sub

En plus comme tu as des ordres de fabrication avec les mêmes numéro, ensuite dans ton planning, pense à trier par rapport à la date de début, car tu n'est pas sur que la procédure de création de planning prennent les ligne dans le même ordre que celui de l'affichage ou de la saisie.
Il te manque peut-être un champ dans ta table Listefab pour garantir cette ordre.
Je ne pensais pas que tu puissent avoir deux N° ordre de fabrication identique.
Car dans ce cas, tu enchaînes les actions les unes après les autres, ou elle doivent démarrer toute au même moment ???
Si c'est les unes après les autres, l'ordre as t'il une importance ?
Pourquoi ne pas les numéroter 400, 401, 402 etc ....
Ou alors rajouter une colonne ordre afin d'avoir,
400 - 1 , 400 - 2, etc ...
et dans ce cas dans la procédure de création du planning il faut rajouter le critère de tri sur cette nouvelle colonne "Ordre" en plus du "Ordre de fabrication"

**Commandeur** · 24/04/2015, 16h17

A quoi te servent les lignes suivantes ?

Le premier exécute une macro avant de lancé ton code, efface la table plannigIA et met a jour les temps de fabrication (qte*temp unitaire)
Le deuxième exécute une macro apres de lancé ton code, actualise le formulaire

L'ordre est bien unique 1 a 50 sauf si dépasse 19h, je fait deux lignes avec (10h + 9h)
c'est dommage que sa bug au delà de 19h

et supérieur a 100 c'est a cadencer( l'ordre n'est pas établie).

**Didier L** · 24/04/2015, 16h38

la dernière version ne bug plus au delas de 19h et plus

Plutôt que des macros, pour vider la table planing et mettre à jour tes formulaire utilise du code vba

exemple :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Currentdb.execute "delete * from T_planning"

et pour la mise à jour des Souformulaires :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

[MonSouformulaire].requery

**Commandeur** · 24/04/2015, 22h15

merci de tes bons conseils.

j'ai essaye avec 26 h , sa me prend plus les jours ferries

Nom : Sans titre.png
Affichages : 767
Taille : 91,8 Ko

**Didier L** · 25/04/2015, 13h46

Bonjour,
Le problème ne vient pas des 26 h car il est situé sur des lignes bien plus haut.
Je ferai un test lundi avec tes données que je regarde en débutant ce qui se passe et pourquoi il ne compte pas le premier mai comme un jour férié ?
Je ne suis pas au bureau du week-end

Alors bon weekend et à lundi

Ordonnancement fabrication calendrier [AC-2010]

Access

Discussions similaires

Partager

Partager