Discussion :

[yieiyiei]

Salut et bon weekend,

j'ai un un formulaire sans source sur lequel j'ai des onglets dans un onglet un sous formulaire avec pour source la requête "R_Sortie" et dans ce sous-formulaire un autre sous formulaire avec pour source la requête "R_détail_vente"

lorsque je charge une sortie j'affecte un "client" via l'ouverture d'un autre formulaire qui m'importe un % lié au client et je recalcule la somme d'un champ dans R_détail_vente.

Mon problème c'est qu'en faisant un me.requery, il va se placer ensuite sur le premier enregistrement de "R_sortie", pour éviter ce problème je fais me.Recalc et là je reste sur mon enregistrement.

voici le code actuel derrière un bouton placé sur mon sous formulaire "HOME" avec pour source "R_sortie"

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Me.Recalc
 
CurrentDb.Execute "UPDATE R_Détail_Vente SET R_Détail_Vente.[PVUS RR TVAC] = R_Détail_Vente.[PVU RR TVAC] WHERE R_Détail_Vente.[#Sortie] = " & (Forms![Home].Form![Fille104]![Test_N°Sortie]) 'copie les prix
CurrentDb.Execute "UPDATE R_Détail_Vente SET R_Détail_Vente.[PVUS RR HTVA] = R_Détail_Vente.[PVU RR HTVA] WHERE R_Détail_Vente.[#Sortie] = " & (Forms![Home].Form![Fille104]![Test_N°Sortie]) 'copie les prix
CurrentDb.Execute "UPDATE R_Détail_Vente SET R_Détail_Vente.[TVA S] = R_Détail_Vente.[TVA] WHERE R_Détail_Vente.[#Sortie] = " & (Forms![Home].Form![Fille104]![Test_N°Sortie])

maintenant si j'applique ça derrière l'événement de la sélection d'un client sur l'autre formulaire, ça ne marche pas :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Forms![Home].Recalc
 
CurrentDb.Execute "UPDATE R_Détail_Vente SET R_Détail_Vente.[PVUS RR TVAC] = R_Détail_Vente.[PVU RR TVAC] WHERE R_Détail_Vente.[#Sortie] = " & (Forms![Home].Form![Fille104]![Test_N°Sortie]) 'copie les prix
CurrentDb.Execute "UPDATE R_Détail_Vente SET R_Détail_Vente.[PVUS RR HTVA] = R_Détail_Vente.[PVU RR HTVA] WHERE R_Détail_Vente.[#Sortie] = " & (Forms![Home].Form![Fille104]![Test_N°Sortie]) 'copie les prix
CurrentDb.Execute "UPDATE R_Détail_Vente SET R_Détail_Vente.[TVA S] = R_Détail_Vente.[TVA] WHERE R_Détail_Vente.[#Sortie] = " & (Forms![Home].Form![Fille104]![Test_N°Sortie])

vous avez une astuce ?

[argyronet]

Bonjour,

Exploite la propriété Bookmark..., d'un Recordset.

Argy

[Didier L]

Bonjour,

Avant ton requery, il faut que tu stocke une valeur (clé si possible) de l'enregistrement sur lequel tu te trouve dans une variable locale.
Ensuite, tu fais ton requery.
Ensuite comme te le propose argyronet, tu dois te servir de la propriété bookmark de ton recordsetclone.
En effet a chaque recordset d'un formulaire, Access y associe un clone.
Sur ce clone tu peux faire une recherche, grace à la clé que tu a sauvegardé et te positionner sur le bon enregistrement.
Ensuite tu récupère la valeur du Bookmark et tu l'affecte à la propriété du recordset de ton formulaire.

Simple non

Pour t'aider voila une petite procédure qui te facilitera la tâche

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
Sub Positionne(MonForm As Form, ControlName As String, ValeurRech, TypeValeur As Integer)
On Error Resume Next
Dim MonClone As Recordset
Dim Crits As String
    Set MonClone = MonForm.RecordsetClone
    Crits = "[" & ControlName & "]="
    Select Case TypeValeur
        Case vbString
            Crits = Crits & "'" & ValeurRech & "'"
        Case vbDate
            Crits = Crits & "#" & Format(ValeurRech, "mm/dd/yyyy") & "#"
        Case vbLong
            Crits = Crits & ValeurRech
    End Select
    MonClone.FindFirst Crits
    MonForm.BookMark = MonClone.BookMark
    MonClone.Close
End Sub

A utiliser de la manière suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Positionne me,"MaClé", vnValeurSauvegarde, vbLong