Discussion :

[vince_est]

Bonjour à tous,

Je reviens vers vous afin d'obtenir de l'aide.

En effet, je n'arrive pas à obtenir ce que je souhaite.
J'ai une table qui me permet de voir tous les enregistrements liés à une activité spécifique de mon boulot.
Afin de réaliser un reporting de l'activité du service, j'ai besoin d'automatisé l'envoi du document.
Pour ce faire, je voudrais pouvoir sélectionner la date la plus récente présente dans ma table et la stocker dans une macro variable grace à la fonction
Call SymputX pour pouvoir faire appel à cette macro variable ultérieurement.

Le hic c'est que je n'arrive pas à écrire un code qui fonctionne correctement.
En gros, je me demande comment créer la variable qui m'intéresse en sélectionnant directement la date la plus récente dans ma table.
J'ai essayé avec SQL, j'ai écrit:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
proc sql;
create table test as
select max(date1) into :date2 
from table;
quit;
 
data _Null_;
set test;
call symputx ('dtjour',date2,put(dtjour,DDMMYY10.));
run;

SAS ne veut pas me créer la variable date2.

J'ai aussi fait des recherche sur l'option last mais je ne trouve pas mon bonheur.

Si vous aviez une solution pour moi, je vous en serais reconnaissant.

Merci d'avance

[m.brahim]

Bonjour,

Je te propose cette solution:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
proc sql;
select max(date) format DDMMYY10. into :date2 
from table;
quit;

Cordialement

[vince_est]

Effectivement, cela fonctionne.

Merci beaucoup

[vince_est]

Bonjour,

Je reviens vers vous car la proposition de m.brahim ne fonctionne que partiellement dans mon cas.
Je m'explique: la date la plus récente est bien stockée dans la macro variable date2 mais je n'arrive pas à
utiliser cette dernière dans mon programme.
le deboggeur de SAS me dit que le format de date est erroné.
J'ai tenté d'utiliser plusieurs format de date différents et rien à faire...

Voilà le code que je souhaite faire fonctionner:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
proc sort data=table (keep=date) nodupkey out=table2;
by date;
run;
 
proc sql;
select max(date) format DDMMYY10. into :date2 
from table2;
quit;
 
 
data table3;
set table;
where document="LA02" and (etatsdp ne "ARR" and dtetatsd = "&date2."d) and (etatsdpa = "ARR" and dtetsdpa < "&date2."d);
run;

Merci d'avance pour vos éclaircissements.

[m.brahim]

Bonjour,

Je te propose cet exemple:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
DATA entree ;
format Date date9.;
Date= '07oct2014'd;  output;
Date= '08oct2014'd;  output;
Date= '10oct2014'd;  output;
Date= '10oct2014'd;  output;
Date= '09MAR2008'd; output;
Date= '15MAR2008'd; output;
run;
 
proc sql noprint;
select max(date)  into :date2 
from entree;
quit;
 
proc sql;
create table sortie as select  date format DDMMYY10. from entree
where date=&date2
;
quit;

Cordialement

[s_a_m]

Hello,
La date récupérée par la macro variable est déjà numérique donc plus besoin de conversion.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
 
where document="LA02" and (etatsdp ne "ARR" and dtetatsd = &date2.) and (etatsdpa = "ARR" and dtetsdpa < &date2.);

Si tu souhaite récupérer la date au format caractère et utiliser la conversion avec "date(US)"D il faut que la date soit au format américain Ex: 01JAN2015, tu peux utiliser ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
 
proc sql noprint;
select put(max(date),date9.) into :date2 
from table;
quit;
data table3;
set table;
where document="LA02" and (etatsdp ne "ARR" and dtetatsd = "&date2."d) and (etatsdpa = "ARR" and dtetsdpa < "&date2."d);
run;

[vince_est]

Super, cette fois-ci, ça tourne parfaitement!

En effet, mon erreur vient de la conversion de date...

En tout cas, merci beaucoup m.brahim et s_a_m pour votre aide précieuse.

Cordialement,

Vince