Chercher mot dans une feuille, afficher résultat sur listBox

**nacereddine.mourad** · 26/02/2015, 08h22

Bonjour;

Je tiens vous remercie d’avance de votre soutien habituel,
La problématique est que: mon bouton recherche, cherche que la première colonne A, je voudrais que ma recherche soit dans toute la feuille BDD, merci.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
Private Sub CommandButton4_Click()
    i = 0
    Me.ListBox1.Clear
    Me.ListBox1.ColumnCount = 2
    Me.ListBox1.BoundColumn = 2
    Me.ListBox1.ColumnWidths = "0;150"
    With Sheets("BDD")
        .AutoFilterMode = False
        Set plage = .Range(.[A2], .Cells(.Rows.Count, 1).End(xlUp)).Resize(, 1)
        plage.AutoFilter 1, "*" & Me.TextBox14 & "*"
        Set plage = plage.Offset(1).Resize(plage.Rows.Count - 1)
        If Application.Subtotal(103, plage) > 0 Then
            Set plage = plage.Resize(, 1).SpecialCells(xlCellTypeVisible)
            For Each C In plage
                Me.ListBox1.AddItem C.Row
                Me.ListBox1.List(i, 1) = C.Value
                i = i + 1
            Next C
        End If
        .AutoFilterMode = False
    End With
    Me.TextBox12 = ""
    Me.TextBox14 = ""
    Me.TextBox15 = ""
    Me.TextBox16 = ""
    Me.TextBox8 = ""
    Me.OptionButton9.Value = False
    Me.OptionButton10.Value = False
    Me.OptionButton8.Value = False
    Me.OptionButton7.Value = False
    Me.OptionButton1.Value = False
    Me.OptionButton2.Value = False
    Me.OptionButton4.Value = False
 
    For i = 0 To N - 1
        If ListBox.Selected(i) Then
            MsgBox "la valeur suivante est sélectionnée : " & ListBox.List(i)
        End If
    Next i
 
    If ListBox1.ListCount = 0 Then
        MsgBox "Ce matériel n'existe pas dans la base de données"
    End If
 
    End Sub

Merci encor, salutations.

**Jean-Philippe André** · 26/02/2015, 10h31

Salut,

au lieu de faire des filtres, passe directement par une boucle avec la fonction Find :
par exemple

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
With Sheets("BDD")
       Set tmprange = .UsedRange.Find(what:=Me.TextBox14, LookIn:=xlFormulas, lookat:=xlPart)
            Do Until tmprange Is Nothing
                  'ta manipulation
                  Set tmprange = .UsedRange.Find(what:=Me.TextBox14, LookIn:=xlFormulas, lookat:=xlPart)
            Loop
End With

**nacereddine.mourad** · 08/03/2015, 07h13

Bonjour

lmerci pour la repense jpcheck,

a recherche prend un temps infini

**gnain** · 08/03/2015, 14h39

Bonjour,

C'est parce que il ne sort jamais de la boucle
Voici comment sortir,
Il faut mettre dans une variable le numéro de la première ligne trouvé (First_No_Ligne)
ensuite dans une autre variable on met le No de ligne à chaque fois qu'il trouve votre mot (No_Ligne)
et avec un do loop until First_No_Ligne =No_Ligne

voici le code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Dim First_No_Ligne As Integer
 Dim No_Ligne As Integer
    On Error Resume Next
     'votre mot apparaît dans ligne suivante
 
    Cells.Find(What:=TextBox14.text, After:=ActiveCell, LookIn:=xlFormulas, LookAt:= _
        xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False _
        , SearchFormat:=False).Activate
    First_No_Ligne = ActiveCell.Row
    No_Ligne = First_No_Ligne + 1
    If Err.Number Then
        On Error GoTo 0
        Exit Sub
    End If
    On Error GoTo 0
    ListBox1.AddItem ActiveCell.Row
    Do
        Cells.FindNext(After:=ActiveCell).Activate
        No_Ligne = ActiveCell.Row
        ListBox1.AddItem  ActiveCell.Row
 
    Loop Until No_Ligne = First_No_Ligne

**nacereddine.mourad** · 08/03/2015, 17h30

Bonsoir et merci gnain

À vrai dire ; je débute sur vba, je vais te demander un peu trop, si tu acceptes d’adapter ton code dans le fichier que j’ai envoyé sur le premier message (UserForm1, CommandButton4),

Le but est de chercher un mot dans la feuille BDD, est afficher le résultat sur ListBox1.
ListBox1 affiche = que la cellule de la colonne A de la même ligne du mot trouver.

Merci encor

**gnain** · 08/03/2015, 23h28

Bonjour nacereddine.mourad
Copier tout ceci dans votre commandbutton4

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
Private Sub CommandButton4_Click()
    Dim First_No_Ligne As Integer
    Dim No_Ligne As Integer
 
    Me.ListBox1.Clear
 
    On Error Resume Next
     'votre mot apparaît dans ligne suivante
 
    Cells.Find(What:=TextBox14.Text, After:=ActiveCell, LookIn:=xlFormulas, LookAt:= _
        xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, MatchCase:=False _
        , SearchFormat:=False).Activate
    First_No_Ligne = ActiveCell.Row
    No_Ligne = First_No_Ligne + 1
    If Err.Number Then
        On Error GoTo 0
        Exit Sub
    End If
    On Error GoTo 0
    ListBox1.AddItem Cells(ActiveCell.Row, 1)
    Do
        Cells.FindNext(After:=ActiveCell).Activate
        No_Ligne = ActiveCell.Row
        ListBox1.AddItem Cells(ActiveCell.Row, 1)
 
    Loop Until No_Ligne = First_No_Ligne
 
    Me.TextBox12 = ""
    Me.TextBox14 = ""
    Me.TextBox15 = ""
    Me.TextBox16 = ""
    Me.TextBox8 = ""
    Me.OptionButton9.Value = False
    Me.OptionButton10.Value = False
    Me.OptionButton8.Value = False
    Me.OptionButton7.Value = False
    Me.OptionButton1.Value = False
    Me.OptionButton2.Value = False
    Me.OptionButton4.Value = False
 
    If ListBox1.ListCount = 0 Then
        MsgBox "Ce matériel n'existe pas dans la base de données"
    End If
End Sub

**nacereddine.mourad** · 09/03/2015, 07h46

Bonjour gnain :

Le code ne marche pas, quand j’écris un mot à chercher dans TextBox14, et je click sur recherche (CommandButton4), rien ne se passe.
Essaye sur le fichier envoyé pour plus de détaille.

Merci encore pour vos efforts

**mercatog** · 09/03/2015, 10h39

L'aide sur la méthode Find de l'objet Range te donne un exemple concret

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Dim Prem As String
Dim c As Range
 
With Me.ListBox1
    .Clear
    .ColumnCount = 2
    .BoundColumn = 2
    .ColumnWidths = "0;150"
End With
 
With Worksheets("BDD").UsedRange
    Set c = .Find(Me.TextBox14, LookIn:=xlValues, Lookat:=xlPart)
    If Not c Is Nothing Then
        Prem = c.Address
        Do
            With Me.ListBox1
                .AddItem c.Row
                .List(.ListCount - 1, 1) = c.Value
            End With
            Set c = .FindNext(c)
        Loop While Not c Is Nothing And c.Address <> Prem
    End If
End With

**nacereddine.mourad** · 09/03/2015, 11h03

On se rapproche, la recherche est parfaite, merci mercatog;

mais le résultat sur la listebox1, doit affichait que la colonne A, qui correspond à la ligne du mot trouvé

merci encor

**mercatog** · 09/03/2015, 11h10

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.List(.ListCount - 1, 1) = Worksheets("BDD").Range("A" & c.Row)

Edit

ou plus élégament

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

.List(.ListCount - 1, 1) = c.Offset(, 1 - c.Column)

**nacereddine.mourad** · 09/03/2015, 11h24

Merci mercatog, merci à tous, c’est exactement ce que je cherche

**mercatog** · 09/03/2015, 11h33

Par contre tu peux toujours ajouter une condition sur TextBox14

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
Dim Prem As String
Dim c As Range
 
With Me.ListBox1
    .Clear
    .ColumnCount = 2
    .BoundColumn = 2
    .ColumnWidths = "0;150"
End With
 
If Me.TextBox14 <> "" Then
    With Worksheets("BDD").UsedRange
        Set c = .Find(Me.TextBox14, LookIn:=xlValues, Lookat:=xlPart)
        If Not c Is Nothing Then
            Prem = c.Address
            Do
                With Me.ListBox1
                    .AddItem c.Row
                    .List(.ListCount - 1, 1) = c.Offset(, 1 - c.Column)
                End With
                Set c = .FindNext(c)
            Loop While Not c Is Nothing And c.Address <> Prem
        End If
    End With
    '...
End If

**nacereddine.mourad** · 09/03/2015, 14h28

Oui sa marcha aussi, merci
et bonne continuation

Chercher mot dans une feuille, afficher résultat sur listBox [XL-2010]

Macros et VBA Excel

Discussions similaires

Partager

Partager