Discussion :

[ksaier]

Bonjour,

j'ai commencé à utiliser les macros et j'ai besoin d'aide à ce niveau.

j'ai une plage de donnée sous Excel (format de lignes et colonnes) :

C1 C2 C3 C4 C5 C6
D1 D2 D3 D4 D5 D6
E1 E2 E3 E4 E5 E6
.
.
n Lignes

Je veux afficher chaque ligne sous une autre format en utilisant une macro, comme par exemple :

C1 C3 C5
C2 C3 C4 C6
C5
espace
D1 D3 D5
D2 D3 D4 D6
D5
espace
E1 E3 E5
E2 E3 E4 E6
E5
espace
.
.
.n répétition

Merci beaucoup pour votre aide.

[Invité]

Bonjour,

Une proposition :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
Sub TestPresenterSur4Lignes()
 
Dim J As Integer
 
    For J = 5 To 7
        With ActiveSheet
             MsgBox PresenterSur4Lignes(.Range(.Cells(J, 1), .Cells(J, 6)))
        End With
    Next J
 
End Sub
 
Function PresenterSur4Lignes(ByVal AireAPresenter As Range) As String
 
Dim I As Integer
 
    PresenterSur4Lignes = ""
    If AireAPresenter.Count = 6 Then
        With AireAPresenter
        PresenterSur4Lignes = .Cells(1, 1) & " " & .Cells(1, 3) & " " & .Cells(1, 5) & Chr(10) _
                              & .Cells(1, 2) & " " & .Cells(1, 3) & " " & .Cells(1, 4) & " " & .Cells(1, 6) & Chr(10) _
                              & .Cells(1, 5) & Chr(10) _
                              & " " & Chr(10)
        End With
    End If
 
End Function

Cordialement.

[ksaier]

Bonjour Eric,

Merci bien pour votre réponse.
En fait j'ai un autre souci ( désolé je suis débutant en langage macro) c'est que mon tableau de donnée se trouve dans un onglet1 et je veux bien afficher les résultat dans un onglet 2.

Merci énormément de votre aide .

[Menhir]

Les onglets, en VBA, c'est l'objet Worksheet (voir l'aide VBA intégrée à Excel en tapant ce mot dans la recherche).

[Invité]

En fait j'ai un autre souci ( désolé je suis débutant en langage macro) c'est que mon tableau de donnée se trouve dans un onglet1 et je veux bien afficher les résultat dans un onglet 2.

Deux solutions :

Solution 1 : Décomposition sur une cellule dans la feuille cible

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
 
Sub TestPresenterSur4Lignes()
 
Dim J As Long
 
Dim FeuilleSource As Worksheet
Dim PremiereLigneSource As Long
Dim DerniereLigneSource As Long
 
Dim FeuilleCible As Worksheet
Dim LigneCibleEnCours As Long
 
    Set FeuilleSource = Sheets("Feuil1")
    Set FeuilleCible = Sheets("Feuil2")
    LigneCibleEnCours = 2
 
 
    With FeuilleSource
         PremiereLigneSource = 5 ' à adapter
         DerniereLigneSource = .Cells(.Rows.Count, 1).End(xlUp).Row
 
         For J = PremiereLigneSource To DerniereLigneSource
                With FeuilleCible.Cells(LigneCibleEnCours, 1)
                 .WrapText = True
                 .Value = PresenterSur4Lignes(FeuilleSource.Range(FeuilleSource.Cells(J, 1), FeuilleSource.Cells(J, 6)))
                 LigneCibleEnCours = LigneCibleEnCours + 1
                End With
         Next J
 
    End With
 
    Set FeuilleSource = Nothing
    Set FeuilleCible = Nothing
 
End Sub
 
 
Function PresenterSur4Lignes(ByVal AireAPresenter As Range) As String
 
Dim I As Integer
 
    PresenterSur4Lignes = ""
    If AireAPresenter.Count = 6 Then
        With AireAPresenter
        PresenterSur4Lignes = .Cells(1, 1) & " " & .Cells(1, 3) & " " & .Cells(1, 5) & Chr(10) _
                              & .Cells(1, 2) & " " & .Cells(1, 3) & " " & .Cells(1, 4) & " " & .Cells(1, 6) & Chr(10) _
                              & .Cells(1, 5) & Chr(10) _
                              & " " & Chr(10)
        End With
    End If
 
End Function

Solution 2 : Décomposition sur 4 lignes dans la feuille cible

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
 
Sub TestPresenterSur4LignesV2()
 
Dim J As Long
 
Dim FeuilleSource As Worksheet
Dim PremiereLigneSource As Long
Dim DerniereLigneSource As Long
 
Dim FeuilleCible As Worksheet
Dim LigneCibleEnCours As Long
 
 
    Set FeuilleSource = Sheets("Feuil1")
    Set FeuilleCible = Sheets("Feuil2")
    LigneCibleEnCours = 2
 
 
    With FeuilleSource
         PremiereLigneSource = 5 ' à adapter
         DerniereLigneSource = .Cells(.Rows.Count, 1).End(xlUp).Row
 
         For J = PremiereLigneSource To DerniereLigneSource
 
                With FeuilleCible.Cells(LigneCibleEnCours, 1)
                 .Value = FeuilleSource.Cells(J, 1) & " " & FeuilleSource.Cells(J, 3) & " " & FeuilleSource.Cells(J, 5)  'PresenterSur4Lignes(FeuilleSource.Range(FeuilleSource.Cells(J, 1), FeuilleSource.Cells(J, 6)))
                 .Offset(1, 0) = FeuilleSource.Cells(J, 2) & " " & FeuilleSource.Cells(J, 3) & " " & FeuilleSource.Cells(J, 4) & " " & FeuilleSource.Cells(J, 6)
                 .Offset(2, 0) = FeuilleSource.Cells(J, 5)
                 .Offset(3, 0) = ""
                 LigneCibleEnCours = LigneCibleEnCours + 4
 
                End With
         Next J
    End With
 
    Set FeuilleSource = Nothing
    Set FeuilleCible = Nothing
 
End Sub

Cordialement.

[ksaier]

YESSSSSSS YESSSSSS ça fonctionne

Merci beaucoup à vous tous.