Discussion :

[Blaiz58]

Bonjour à tous,

je bloque sur une chose surement très bête mais je n'arrive pas à voir le problême. En fait, j'enregistre dans un tableau(sous VBA) des variables et je souhaiterais ensuite retranscrire ce tableau sur ma page excel mais cela ne prend que la première valeur du tableau :/

Voila mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
 
Sub General()
Dim TabFigureGM As Variant, TabTemplateGM As Variant, cmpt1 As Long, cmpt2 As Long
TabFigureGM = Feuil1.Range("G6:N" & Feuil1.Cells(60000, 7).End(xlUp).Row).Value
TabTemplateGM = Feuil2.Range("A2:C433").Value
Dim TabTemp (1 to 432)
 
 
For cmpt1 = LBound(TabTemplateGM, 1) To UBound(TabTemplateGM, 1)
Nbr = 0
    For cmpt2 = LBound(TabFigureGM, 1) To UBound(TabFigureGM, 1)
        If (Month(TabTemplateGM(cmpt1, 3)) = Month(TabFigureGM(cmpt2, 1))) And (Year(TabTemplateGM(cmpt1, 3)) = Year(TabFigureGM(cmpt2, 1))) Then
            If (TabTemplateGM(cmpt1, 1) = TabFigureGM(cmpt2, 2)) And (TabTemplateGM(cmpt1, 2) = TabFigureGM(cmpt2, 4)) Then
                   Nbr = Nbr + TabFigureGM(cmpt2, 7)
            End If
        End If
    Next cmpt2
TabTemp(cmpt1) = Nbr
Next cmpt1
    Feuil2.Range("H2:H433").Value = TabTemp
End Sub

Merci pour votre aide

[Kimy_Ire]

Bonjour Blaiz58,

Tes variables TabFigureGM et TabTemplateGM ont des LBound et des UBound identiques puisque tu ne les définies pas en tant que tableau.
Donc, c'est normal que tu n'ai qu'une seule valeur.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Dim TabFigureGM() As Variant, TabTemplateGM() As Variant

Si tu fais des ReDim sur ces-derniers après.
Ou assigne directement ton nombre de valeurs comme ton TabTemp.

Cordialement,
Kimy

[Blaiz58]

J'ai fais des ReDim mais je n'ai toujours que une seule valeur qui en ressort du tableau TabTemp

Mais si je regarde 1 par 1 les valeurs du tableau TabTemp, je les ai bien toutes dedans ...

Voila le code que j'ai refait du coup.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Sub General()
Dim TabFigureGM As Variant, TabTemplateGM As Variant, cmpt1 As Long, cmpt2 As Long
ReDim TabFigureGM(1 To Feuil1.Cells(60000, 7).End(xlUp).Row - 5, 1 To 8)
ReDim TabTemplateGM(1 To 432, 1 To 3)
TabFigureGM = Feuil1.Range("G6:N" & Feuil1.Cells(60000, 7).End(xlUp).Row).Value
TabTemplateGM = Feuil2.Range("A2:C433").Value
Dim TabTemp (1 to 432)
 
 
For cmpt1 = LBound(TabTemplateGM, 1) To UBound(TabTemplateGM, 1)
Nbr = 0
    For cmpt2 = LBound(TabFigureGM, 1) To UBound(TabFigureGM, 1)
        If (Month(TabTemplateGM(cmpt1, 3)) = Month(TabFigureGM(cmpt2, 1))) And (Year(TabTemplateGM(cmpt1, 3)) = Year(TabFigureGM(cmpt2, 1))) Then
            If (TabTemplateGM(cmpt1, 1) = TabFigureGM(cmpt2, 2)) And (TabTemplateGM(cmpt1, 2) = TabFigureGM(cmpt2, 4)) Then
                   Nbr = Nbr + TabFigureGM(cmpt2, 7)
            End If
        End If
    Next cmpt2
TabTemp(cmpt1) = Nbr
Next cmpt1
    Feuil2.Range("H2:H433").Value = TabTemp
End Sub

[casefayere]

Sans avoir analyser, as-tu essayé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Feuil2.Range("H2").Resize(UBound(TabTemp, 1)) = TabTemp

ou

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Feuil2.Range("H2:H433").Value = Application.Transpose(TabTemp)

[Kimy_Ire]

J'ai fais des ReDim mais je n'ai toujours que une seule valeur qui en ressort du tableau TabTemp

Mais si je regarde 1 par 1 les valeurs du tableau TabTemp, je les ai bien toutes dedans ...

Je dois avouer que je ne sais pas trop la faisabilité de "coller" l'ensemble des valeurs d'un tableau sur une plage.
Un plus expert pourra peut-être proposer une méthode.

Je te propose donc ceci :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
For i = 1 to 432
    Feuil2.Range("H1").Offset(i, 0) = TabTemp(i)
Next i

Ceci fonctionnera forcément.

Cordialement,
Kimy

[Marc-L]

Blaiz58, Kimy, c'est juste un problème d'observation et donc de logique !
Suffit d'affecter une plage de cellules à une variable non déclarée (donc de type Variant) puis de regarder dans
la fenêtre des Variables locales : une plage de cellules correspond à un tableau à deux dimensions comme la propriété Cells.

Donc lorsqu'une variable tableau n'a qu'une dimension, il faut bien la transposer pour l'afficher en colonne …

[casefayere]

ce que j'ai proposé

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Feuil2.Range("H2").Resize(UBound(TabTemp, 1)) = TabTemp

devrait fonctionner, je n'ai pas vu la variable Nbr déclarée, j'en déduit que "Option Explicit" n'a peu-être pas été spécifié

[Blaiz58]

Ta 2ème solution fonctionne casefayere Merci beaucoup.

Marc-L, pour répondre à ta question, j'ai rien dans variable locale.

Merci Kimy_Ire pour ton aide. Oui j'avais pensé à cette solution mais ça alourdissait un peu le code.

[casefayere]

Alors, celle-ci aussi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Feuil2.Range("H2").Resize(UBound(TabTemp, 1)) = Application.Transpose(TabTemp)

[Blaiz58]

Effectivement, elle fonctionne également ! C'est d'ailleur celle que je vais retenir au cas où les dimensions du tableau bougeraient.

Merci beaucoup