somme des éléments d'une colonne

**raicolin** · 18/12/2014, 00h32

Bonsoir,

je suis un débutant en VBA et j'ai programmé un code voici un exemple pour faciliter la compréhension du problème

quantité	produits
5165		A
15		B
16		A
51		C
5621		B

le code doit afficher la somme des quantité pour chaque produit
voici le code que j'ai réalisé :

les quantité débute depuis Cells(2, 3) jusqu’à Cells(33, 3)
les produits débute depuis Cells(2, 4) jusqu’à Cells(33, 4)
le résultat doit être écrit sur la feuil3

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
Sub qte()
Dim i As Integer
Dim j As Integer
Dim s As Integer
k = 2
 
For i = Cells(k, 4) To Cells(33, 4)
s = 0
For m = Cells(2, 4) To i
If m.Value <> i.Value Then
For j = Cells(k + 1, 4) To Cells(33, 4)
If j.Value = i.Value Then
s = s + Cells(k, 3).Value
k = k + 1
Next
Next
Next
 Sheets("Feuil3").Activate
 For f = 0 To 100
 Sheets("Feuil3").Cells(f, 1).Value = s
End Sub

merci d'avance

**Marc-L** · 18/12/2014, 00h38

Bonsoir, bonsoir !

Pourquoi en passer par du code alors qu'une simple formule de calculs suffit amplement ?! Via SOMME.SI par exemple …

Et sachant la plupart des fonctions de formules de calculs utilisables en VBA !
Sans compter un tableau croisé dynamique …

**casefayere** · 18/12/2014, 01h08

Bonsoir Marc, raicolin

Sans compter un tableau croisé dynamique …

tu as raison Marc, mais juste pour le plaisir et pour que raicolin puisse étudier

un code à adapter

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub essai()
Dim Dl As Range, Plg As Range, Tbl, Tbresult(), Tbdoublon
Dim x As Long
With Sheets("Feuil2") 'à changer par ton nom de feuille
  Set Dl = .Range("C" & .Rows.Count).End(xlUp) 'derniere cellule utilisée en col C
  Set Plg = .Range("C2", Dl(1, 2))
  Tbl = .Range("D2", Dl(1, 2))
  .Range("D2", Dl(1, 2)).RemoveDuplicates Columns:=1, Header:=xlNo
  Set Dl = .Range("D" & .Rows.Count).End(xlUp)
  Tbdoublon = .Range("D2", Dl)
  .Range("D2").Resize(UBound(Tbl)) = Tbl
  ReDim Tbresult(1 To UBound(Tbdoublon), 1 To 2)
  For x = 1 To UBound(Tbdoublon)
    Tbresult(x, 1) = Tbdoublon(x, 1)
    Tbresult(x, 2) = WorksheetFunction.SumIf(Plg.Columns(2), Tbdoublon(x, 1), Plg.Columns(1))
  Next
  Sheets("Feuil3").Range("A2").Resize(UBound(Tbresult, 1), UBound(Tbresult, 2)) = Tbresult
 
End With
End Sub

bonne nuit

**raicolin** · 18/12/2014, 12h39

Bonjour M.casafayere
Je vous remercie de votre aide, en réalité il s’agit d’une situation un peu plus compliqué car je dispose de deux colonnes dans le fichier excel dans lequel je devrais faire la somme pour chaque code de la longueur correspondante il s’agit des colonnes C3 et C4 de la feuille CUTTING DATA -Roof family.
Je n’est pas pu sélectionné ces deux colonne en se basant sur le code que vous m’avez fournit
est ce que vous pouvez m'aider svp

**casefayere** · 18/12/2014, 12h52

Bonjour,

déjà, ça m'embête quand j'ai la témérité d'ouvrir un fichier joint (j'ai déjà rencontré beaucoup de problème), ensuite je m'aperçois que tu es en option "L1C1", ce que je ne fais jamais (mais bon !)

en réalité il s’agit d’une situation un peu plus compliqué car je dispose de deux colonnes dans le fichier excel dans lequel je devrais faire la somme pour chaque code de la longueur correspondante il s’agit des colonnes C3 et C4 de la feuille CUTTING DATA -Roof family.

tu me parles de col C3 C4 or C3 et C4 sont des cellules, maintenant, expliques-toi mieux si tu veux que je continue à t'aider ou si d'autres intervenants souhaitent se mêler à la discussion.

Bon courage et n'hésites pas

**raicolin** · 18/12/2014, 13h04

Merci beaucoup d’avoir accepté de m’aider, pour corriger mon erreur il s‘agit de la cellule L2C3 jusqu’à L33C3 pour la première colonne et de la cellule L2C4 jusqu’à L33C4 pour la deuxième colonne
Je voudrais effectuer la somme de la longueur pour chaque code donné
Je vous remercie beaucoup d’avance

**casefayere** · 18/12/2014, 13h23

Ok,

mais mon code envoie toujours le résultat dans "Feuil3" qui n'existe pas, tu aurais dû adapter, alors dans quelle feuille ?, imaginons "Feuil5"

Ton tableau est filtré, j'enlève les filtres
De plus, Marc te préconisait un tableau dynamique et je viens de remarquer qu'en "feuil6" tu en as un, il suffisait de l'adapter.

sinon, essaies ce code qui tient comptes des vides, tu devrais comprendre la démarche ensuite, dans le cas contraire, je t'expliquerai pas à pas mais la réponse sera suivant le temps dont je dispose

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
Sub essai()
Dim Dl As Range, Plg As Range, Tbl, Tbresult(), Tbdoublon
Dim x As Long
With Sheets("CUTTING DATA -Roof family")
  Set Dl = .Range("C" & .Rows.Count).End(xlUp)
  Set Plg = .Range("C2", Dl(1, 2))
  Tbl = .Range("D2", Dl(1, 2))
  .Range("D2", Dl(1, 2)).RemoveDuplicates Columns:=1, Header:=xlNo
  Set Dl = .Range("D" & .Rows.Count).End(xlUp)
  Tbdoublon = .Range("D2", Dl)
  .Range("D2").Resize(UBound(Tbl)) = Tbl
  ReDim Tbresult(1 To UBound(Tbdoublon), 1 To 2)
  For x = 1 To UBound(Tbdoublon)
    Tbresult(x, 1) = Tbdoublon(x, 1)
    Tbresult(x, 2) = WorksheetFunction.SumIf(Plg.Columns(2), Tbdoublon(x, 1), Plg.Columns(1))
  Next
  Sheets("Feuil5").Range("A2").Resize(UBound(Tbresult, 1), UBound(Tbresult, 2)) = Tbresult
 
End With
End Sub

**raicolin** · 19/12/2014, 13h35

Bonjour monsieur Dom je vous remercie infiniment de votre aide , bien sur si vous avez un peu de temps je serai reconnaissant de m'expliquer le code étape par étape comme je suis novice en vba
bonne journée
rai

**casefayere** · 19/12/2014, 13h52

Bonjour raicolin, re le forum
la partie de code et ses explications, lesquells, j'espère seront suffisantes, mais tu ne dis pas si le code fonctionne chez toi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
With Sheets("CUTTING DATA -Roof family") 'évite les répétitions
  Set Dl = .Range("C" & .Rows.Count).End(xlUp) 'derniere cellule utilisée en col C
  Set Plg = .Range("C2", Dl(1, 2)) 'une plage de C2 à D et dernière ligne
  Tbl = .Range("D2", Dl(1, 2)) 'une variable tableau stockant les valeurs de D
  .Range("D2", Dl(1, 2)).RemoveDuplicates Columns:=1, Header:=xlNo 'on élimine les doublon en D (Depuis excel 2007)
  Set Dl = .Range("D" & .Rows.Count).End(xlUp) 'derniere cellule utilisée en col D
  Tbdoublon = .Range("D2", Dl) 'une variable tableau stockant les valeurs de D modifiée (sans doublon)
  .Range("D2").Resize(UBound(Tbl)) = Tbl 'je rends les valeurs originales à D grace à la variable Tbl
  'ci-dessus pour "Resize", voir l'aide
  ReDim Tbresult(1 To UBound(Tbdoublon), 1 To 2) 'je redimensionne la variable tableau du nombre de valeurs sans doublon
  'sur 2 dimensions (voir le forum pour l'utilisation des tableau
  For x = 1 To UBound(Tbdoublon) 'je fais une boucle jusqu'à la fin du tableau
    Tbresult(x, 1) = Tbdoublon(x, 1) 'je donne les valeurs de Tbdoublon à la 1ère dimension de Tbrésult
    'ci-dessous je calcule les valeurs de la 2ème dimension avec SumiF (Somme.Si)
    Tbresult(x, 2) = WorksheetFunction.SumIf(Plg.Columns(2), Tbdoublon(x, 1), Plg.Columns(1))
  Next
  'et enfin je mets le résultat obtenu dans Feuil5, à partir de A2
  Sheets("Feuil5").Range("A2").Resize(UBound(Tbresult, 1), UBound(Tbresult, 2)) = Tbresult
 
End With

**raicolin** · 19/12/2014, 18h57

Bonsoir casafayere
le code fonctionne à merveille, merci encore de votre aide et des explications fournies
bon weekend

somme des éléments d'une colonne

Macros et VBA Excel

Discussions similaires

Partager

Partager