IdentifiantMot de passe
Loading...
Mot de passe oublié ?Je m'inscris ! (gratuit)
Navigation

Inscrivez-vous gratuitement
pour pouvoir participer, suivre les réponses en temps réel, voter pour les messages, poser vos propres questions et recevoir la newsletter

Macros et VBA Excel Discussion :

Extraction d'une chaine de caractères


Sujet :

Macros et VBA Excel

  1. #1
    Membre habitué
    Profil pro
    Inscrit en
    Novembre 2010
    Messages
    98
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : Novembre 2010
    Messages : 98
    Points : 132
    Points
    132
    Par défaut Extraction d'une chaine de caractères
    Bonjour,

    J'ai lu cette contribution.
    Si le contenu des cellules est de ce type :
    Nom : Dupont - Eric / Tél : 0612345678
    Je n'ai pas testé ce code mais je ne doute pas qu'il fonctionne bien. J'ai une problématique un peu similaire. Je voudrais extraire d'une chaine de caractères un code à 7 chiffres mais qui n'est jamais dans la même position à l'intérieur de la chaine, dont la seule caractéristique est de toujours commencer par 22, (mais 22 peut se trouver ailleurs dans la chaine !!) et il n'y a aucune balise avant ou après ce numéro.
    Ma cellule ressemble à çà : F2370403338865 192,00 21/07/2014 NOM Prénom-Composé - 1991234567890 59 3,66 2259966 43,80 43,80.
    Je cherche à récupérer le code 2259966. Sur des centaines de lignes la chaine de caractère est différente en nombre de caractères et la position du code recherché n'est pas fixe.
    Si vous aviez une piste en VBA ou en formule texte je serai intéressé.
    Merci.

  2. #2
    Membre expérimenté
    Homme Profil pro
    Ingénieur développement matériel électronique
    Inscrit en
    Septembre 2013
    Messages
    783
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : France, Isère (Rhône Alpes)

    Informations professionnelles :
    Activité : Ingénieur développement matériel électronique
    Secteur : High Tech - Électronique et micro-électronique

    Informations forums :
    Inscription : Septembre 2013
    Messages : 783
    Points : 1 562
    Points
    1 562
    Par défaut
    Bonjour,

    Similaire à ce qui a été proposé, sauf erreur:
    => Vous pouvez par la fonction split, qui vous ressort un tableau sur la base du séparateur (" ") ici si j'ai bien compris
    du style
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    ' en supposant que cl point sur la valeur à traiter
    MyDataAR = Split(cl.value, " ") ' retourne tout le tableau
     
    If UBound(MyDataAR, 1) > 4 then 'par exemple
       MyData = MyDataAR (4) ' a affiner
    End If
    Bonne journée
    "Idéalement nous sommes ce que nous pensons. Dans la réalité, nous sommes ce que nous accomplissons." A.Senna
    et n'oubliez-pas de développer des .... sourires ^_^

  3. #3
    Membre habitué
    Profil pro
    Inscrit en
    Novembre 2010
    Messages
    98
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : Novembre 2010
    Messages : 98
    Points : 132
    Points
    132
    Par défaut
    Merci pour la réactivité mais j'avoue que je ne comprends pas comment adapter cela par rapport à votre premier code.

  4. #4
    Membre expérimenté
    Homme Profil pro
    Ingénieur développement matériel électronique
    Inscrit en
    Septembre 2013
    Messages
    783
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : France, Isère (Rhône Alpes)

    Informations professionnelles :
    Activité : Ingénieur développement matériel électronique
    Secteur : High Tech - Électronique et micro-électronique

    Informations forums :
    Inscription : Septembre 2013
    Messages : 783
    Points : 1 562
    Points
    1 562
    Par défaut
    Ca ne marche que si l'enregistrement que vous voulez extraire est à une position fixe (9ème espace ici), sinon, il faut comprendre la logique

    Si en A1 de Sheet1 j'ai:
    F2370403338865 192,00 21/07/2014 NOM Prénom-Composé - 1991234567890 59 3,66 2259966 43,80 43,80.
    ça ressort en B1 la valeur (String ici) 2259966
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    Sub Extract_Data()
     
    Dim InpRng As Range, InpCl As Range
    Dim ClValExtr As String, ClValAR As Variant
    Dim RecPos As Integer
     
    ' A adapter sur la feuille et la cellule
    Set InpRng = ThisWorkbook.Worksheets("Sheet1").Range("A1").CurrentRegion
    RecPos = 9 'Record à extraire
     
    ' A adapter (Columns)
    For Each InpCl In InpRng.Columns(1).Cells
     
        Debug.Print InpCl.Value
        'Je crée un tableau ClValAR contenant tous les enregistrements entre le " "
        ClValAR = Split(InpCl.Value, " ")
     
        ' Si le nombre d'élèments retournés à supéreiur à l'extract que je recherche
        If UBound(ClValAR, 1) >= RecPos Then
     
            ' Attention au type: ici on retourne un string
            ClValExtr = ClValAR(RecPos)
            InpCl.Offset(0, 1) = ClValExtr  'J'écris sur la colonne suivante
     
        End If
     
    Next InpCl
     
    End Sub
    Bonne journée
    "Idéalement nous sommes ce que nous pensons. Dans la réalité, nous sommes ce que nous accomplissons." A.Senna
    et n'oubliez-pas de développer des .... sourires ^_^

  5. #5
    Membre habitué
    Profil pro
    Inscrit en
    Novembre 2010
    Messages
    98
    Détails du profil
    Informations personnelles :
    Localisation : France

    Informations forums :
    Inscription : Novembre 2010
    Messages : 98
    Points : 132
    Points
    132
    Par défaut
    Merci bien. Mais justement la position de la donnée à extraire n'est pas forcément à la même place. Mais votre solution avec les espaces peut m'aider. Je revois cela demain...

  6. #6
    Membre expérimenté
    Homme Profil pro
    Ingénieur développement matériel électronique
    Inscrit en
    Septembre 2013
    Messages
    783
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : France, Isère (Rhône Alpes)

    Informations professionnelles :
    Activité : Ingénieur développement matériel électronique
    Secteur : High Tech - Électronique et micro-électronique

    Informations forums :
    Inscription : Septembre 2013
    Messages : 783
    Points : 1 562
    Points
    1 562
    Par défaut
    Citation Envoyé par taquatzieu Voir le message
    Merci bien. Mais justement la position de la donnée à extraire n'est pas forcément à la même place. Mais votre solution avec les espaces peut m'aider. Je revois cela demain...
    Si l'enregistrement n'est pas toujours à la même place, quelle est la logique derrière? Comment le savoir?
    Bonne soirée
    "Idéalement nous sommes ce que nous pensons. Dans la réalité, nous sommes ce que nous accomplissons." A.Senna
    et n'oubliez-pas de développer des .... sourires ^_^

  7. #7
    Invité
    Invité(e)
    Par défaut
    Bonjour

    En prenant en compte que ton chiffre commence toujours par 22, on peut utiliser ce genre de fonction :

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    Public Function Extraction(strValeur As String) As String
        ' déclaration
        Dim tabEx() As String
        Dim i As Integer
     
        ' éclatage de la chaine
        tabEx() = Split(strValeur, " ")
     
        ' recherche de la valeur
        For i = 0 To UBound(tabEx()) - 1
            If Left(tabEx(i), 2) = "22" And Len(tabEx(i)) = 7 Then
                Extraction = tabEx(i)
               ' on a trouvé, on sort de la boucle
                Exit For
            End If
        Next i
     
     
    End Function
    Ex :

    extraction("F2370403338865 192,00 21/07/2014 NOM Prénom-Composé - 91234567890 59 3,66 2259966 43,80 43,80")

    renvoi

    2259966

    Quel que soit la position dans la chaine.

    Par contre si 22 se trouve n'importe où, alors il faut faire un test sur la longueur en premier avec la fonction Len et si c'est bon, faire une recherche de la valeur avec InStr.

    Philippe
    Dernière modification par Invité ; 20/11/2014 à 08h44.

  8. #8
    Expert éminent sénior Avatar de mercatog
    Homme Profil pro
    Inscrit en
    Juillet 2008
    Messages
    9 435
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : Autre

    Informations forums :
    Inscription : Juillet 2008
    Messages : 9 435
    Points : 31 877
    Points
    31 877
    Par défaut
    Bonjour

    Une autre proposition utilisant les RegExp.
    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    Function Extract(ByVal Tmp As String) As String
    Dim Rg As Object, Seq As Object
     
    Set Rg = CreateObject("VbScript.RegExp")
    With Rg
        .Pattern = "(\s)(22\d{5})(\s)"
        Set Seq = .Execute(" " & Tmp & " ")
        If Seq.Count > 0 Then Extract = Seq(0).SubMatches(1)
        Set Seq = Nothing
    End With
    Set Rg = Nothing
    End Function
    Cordialement.
    J'utilise toujours le point comme séparateur décimal dans mes tests.

Discussions similaires

  1. extraction d'une chaine de caractère d'un fichier texte
    Par c_salsabil dans le forum Général Java
    Réponses: 1
    Dernier message: 31/12/2009, 16h27
  2. Réponses: 7
    Dernier message: 05/04/2009, 11h40
  3. Réponses: 2
    Dernier message: 05/03/2009, 17h06
  4. Extraction d'une chaine de caractère
    Par ozzy75 dans le forum Développement
    Réponses: 0
    Dernier message: 26/10/2008, 12h23
  5. Extraction d'une chaine de caractères
    Par megane dans le forum Langage
    Réponses: 2
    Dernier message: 05/01/2004, 15h52

Partager

Partager
  • Envoyer la discussion sur Viadeo
  • Envoyer la discussion sur Twitter
  • Envoyer la discussion sur Google
  • Envoyer la discussion sur Facebook
  • Envoyer la discussion sur Digg
  • Envoyer la discussion sur Delicious
  • Envoyer la discussion sur MySpace
  • Envoyer la discussion sur Yahoo