Discussion :

[formabox]

Hello le forum,

Je suis en train de sécher depuis 1 heure pour savoir comment je peux rendre obligatoire la saisie de tous les champs d'un formulaire Word.

J'ai trouvé que sur chaque champ, on peut exécuter une macro à la sortie et j'ai essayé le code suivant. Le test fonctionne lorsque je sors du champ mais Word se place sur le champ suivant alors que je lui dit de sélectionner le champ Nom car je souhaite que si celui-ci n'est pas compléter, il est impossible d'aller au champ suivant.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
Sub ChampsObligatoires()
 
If ActiveDocument.FormFields("nom").Result = "" Then
 
MsgBox ("Ce champ doit être complété")
ActiveDocument.FormFields("nom").Select
End If
 
End Sub

Je pense qu'il doit exister un code spécifique car mon idéal sera que tous les champs soient obligatoires. Est-ce que je peux placer ma macro à l'enregistrement de mon fichier afin que tous les champs soient tester et m'afficher un message si des champs ne sont pas complétés afin que le document ne puisse pas être enregistré ou imprimer si l'ensemble du formulaire n'est pas complété...

AieAieAie, j'espère être claire ;-) et merci pour vos lumières

[Heureux-oli]

Salut,

Il faut aller à un autre champ pour revenir à celui que l'on vient de quitter.

Mais ça ne rendra pas ce champ obligatoire, si je n'y passe pas, la macro ne va pas s'exécuter.
Tu auras besoin d'une autre code pour tous les champs sur un évènement choisi.

[formabox]

Pour info, voici le code pour que ça fonctionne ;-)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
Private Function IsFieldEmpty(FF As FormField) As Boolean
    IsFieldEmpty = False ' default
 
    If FF.Type = wdFieldFormTextInput Then
        If Len(Trim(FF.Result)) = 0 Then
            MsgBox prompt:="Field " & FF.Name & _
                " must not be blank.", Title:="Empty Field"
            FF.Range.Select
            IsFieldEmpty = True
        End If
    End If
End Function
 
Sub FilePrint()
    Dim FrmFld As FormField
    Dim StopPrint As Boolean
 
    For Each FrmFld In ActiveDocument.FormFields
        StopPrint = IsFieldEmpty(FrmFld)
        If StopPrint Then Exit For
    Next FrmFld
 
    If Not StopPrint Then
        Dialogs(wdDialogFilePrint).Show
    End If
End Sub
 
Sub FilePrintDefault()
    Dim FrmFld As FormField
    Dim StopPrint As Boolean
 
    For Each FrmFld In ActiveDocument.FormFields
        StopPrint = IsFieldEmpty(FrmFld)
        If StopPrint Then Exit For
    Next FrmFld
 
    If Not StopPrint Then
        ActiveDocument.PrintOut
    End If
End Sub
 
Sub FileSave()
    Dim FrmFld As FormField
    Dim StopSave As Boolean
 
    For Each FrmFld In ActiveDocument.FormFields
        StopSave = IsFieldEmpty(FrmFld)
        If StopSave Then Exit For
    Next FrmFld
 
    If Not StopSave Then
        ActiveDocument.Save
    End If
End Sub
 
Sub FileSaveAs()
    Dim FrmFld As FormField
    Dim StopSave As Boolean
 
    For Each FrmFld In ActiveDocument.FormFields
        StopSave = IsFieldEmpty(FrmFld)
        If StopSave Then Exit For
    Next FrmFld
 
    If Not StopSave Then
        Dialogs(wdDialogFileSaveAs).Show
    End If
End Sub
 
Sub AutoClose()
    Dim FrmFld As FormField
    Dim StopSave As Boolean
 
    For Each FrmFld In ActiveDocument.FormFields
        StopSave = IsFieldEmpty(FrmFld)
        If StopSave Then Exit For
    Next FrmFld
 
    If StopSave Then
        ActiveDocument.Saved = False
        SendKeys "{ESC}"
    End If
End Sub