Discussion :

[taken1401]

Bonsoir,
j'ai un souci sur la mise en formule et vba de mon pb
en effet, ce que je recherche à faire, c'est de comptabilisé le nombre de fois qu'apparait à chaque fois le résultat de la dernière colonne à l'identique dans la plage de cellule defini. la variation de cette plage doit être défini par la valeur de la cell CR21.
Fichier image ci-joint.

Si par exemple je change la valeur de la cellule CR21 par la valeur 4, je veux réduire la plage de cellule a 4 colonnes, comme l'exemple sur le fichier ci-joint, sachant que la colonne de référence est toujours la dernière qui apparait,
ex: après avoir cliquer sur le bouton +1 jusqu'à la colonne 25, la je change la valeur de CR21 par 7 et la il me faut la plage de DK à DQ.

Je patauge dans les formules sans succès
Y a t'il une autre méthode ?
si qq'un a une idée !

[Stef999]

Bonjour,

En CY21 j'ai saisi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ESTVIDE(CY1);"";SOMMEPROD(1*(RECHERCHE(CY2;6:6)=INDIRECT("L2C"&SOMME(COLONNE())-$CR$21 & ":L2C" & SOMME(COLONNE())-1;FAUX)*(RECHERCHE(CY3;6:6)=INDIRECT("L3C"&SOMME(COLONNE())-$CR$21 & ":L3C" & SOMME(COLONNE())-1;FAUX))*(RECHERCHE(CY4;6:6)=INDIRECT("L4C"&SOMME(COLONNE())-$CR$21 & ":L4C" & SOMME(COLONNE())-1;FAUX)))))

S3 test.xlsm

Indirect() me sert à fabrique une plage qui dépend de CR21 (nombre de colonnes retenues) ... colonne() le numéro de la colonne active (je la prends avec somme car sinon la valeur de la colonne est retournée sous forme matricielle, je pense que c'est parce que colonne() est dans sommeprod() )

Cordialement,
Stéphane

[taken1401]

Bonjour Stef999,
avant tout, merci pour votre aide.
J'ai testé votre formule en effet elle fonctionne, mais ce que je comprend moins bien, c'est le vecteur de recherche !
en effet, la valeur du vecteur dans la formule est de 6:6 pour les 3 fonction RECHERCHE(dans cette configuration ça fonctionne),
pourquoi quand je remplace cette valeur par 2:2 pour la 1ere RECHERCHE, puis par 3:3 pour la 2eme RECHERCHE et 4:4 pour la 3 RECHERCHE, ces vecteurs sont censés représenter les lignes de recherche, donc les lignes 2,3, et 4, mais la j'ai une erreur #N/A !

=SI(ESTVIDE(CY1);"";SOMMEPROD(1*(RECHERCHE(CY2;2:2)=INDIRECT("L2C"&SOMME(COLONNE())-$CR$21 & ":L2C" & SOMME(COLONNE())-1;FAUX)*(RECHERCHE(CY3;3:3)=INDIRECT("L3C"&SOMME(COLONNE())-$CR$21 & ":L3C" & SOMME(COLONNE())-1;FAUX))*(RECHERCHE(CY4;4:4)=INDIRECT("L4C"&SOMME(COLONNE())-$CR$21 & ":L4C" & SOMME(COLONNE())-1;FAUX)))))

QQ chose m'échappe t'il ?

[Stef999]

Bonjour,

La modif que j'ai faite vise uniquement à prendre en compte un nombre de colonne variable à partir de la formule initiale ....
Ce que vous vouliez faire avec cette formule initiale et le pourquoi de cette fonction recherche je ne le sais pas !!
Dans les faits elle vérifie l’existence d'un nombre dans la dernière ligne, la 6, si le nombre n'y est pas elle renvoie NA (effectivement) et s'il est présent c'est le nombre qui est renvoyé ... Si l'objectif était uniquement de compter des triplets, sans autre contrainte, on peut tout à fait se passer de cette recherche et saisir en CT21 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SI(ESTVIDE(CT1);"";SOMMEPROD(1*(CT2=INDIRECT("L2C"&SOMME(COLONNE())-$CR$21 & ":L2C" & SOMME(COLONNE())-1;FAUX)*(CT3=INDIRECT("L3C"&SOMME(COLONNE())-$CR$21 & ":L3C" & SOMME(COLONNE())-1;FAUX))*(CT4=INDIRECT("L4C"&SOMME(COLONNE())-$CR$21 & ":L4C" & SOMME(COLONNE())-1;FAUX)))))

Cordialement,
Stéphane

[taken1401]

bonjour,
mon pb est résolu.
En effet, à partir de vos propositions et à force de chercher, bidouiller, j'ai trouvé une alternative de formule

=SI(ESTVIDE(CY1);"";NB.SI.ENS(INDIRECT("L2C"&SOMME(COLONNE())-$CR$21 & ":L2C" & SOMME(COLONNE())-1;FAUX);CY2;INDIRECT("L3C"&SOMME(COLONNE())-$CR$21 & ":L3C" & SOMME(COLONNE())-1;FAUX);CY3;INDIRECT("L4C"&SOMME(COLONNE())-$CR$21 & ":L4C" & SOMME(COLONNE())-1;FAUX);CY4)*1)

Merci d'avoir consacré votre aide.