Discussion :

[shayw]

il faut plutot utiliser le keydown event

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
Private Sub TextBox1_KeyDown(sender As Object, e As System.Windows.Forms.KeyEventArgs) Handles TextBox1.KeyDown
        If (e.KeyValue = Keys.Decimal) Then
            e.SuppressKeyPress = True
            DirectCast(sender, TextBox).AppendText(",")
        End If
    End Sub

[worm83]

Plûtot que de nous engueuler, demande plûtot comment factoriser le code cela sera plus productif.

Il y a peut être des dizaine de façon de faire, mutualiser les handle, deriver la textbox, passer par des validateur, passer par du binding ect....

[Adakhum]

heu.. c'est moi qui t'es engueulé ? Faut pas te sentir persécuté comme ça 0.o je vous ai déjà tous remercié
Je veux une méthode qui tiennent en quelques lignes au début du code si possible pour dire au programme : je veux utiliser le point comme virgule ou transformer le point en virgule, si c'était pas clair voilà qui est fait

[worm83]

heu.. c'est moi qui t'es engueulé ? Faut pas te sentir persécuté comme ça 0.o je vous ai déjà tous remercié
Je veux une méthode qui tiennent en quelques lignes au début du code si possible pour dire au programme : je veux utiliser le point comme virgule ou transformer le point en virgule, si c'était pas clair voilà qui est fait

Engueuler était un peu fort, j ai mal interprété ce que tu as dit aussi.

[wallace1]

Allez les gars une petite accolade et on n'en parle plus

@Adakhum : Si ton pb est résolu alors préfixe ton topic stp.

[rv26t]

Bonjour,

Je veux une méthode qui tiennent en quelques lignes au début du code si possible pour dire au programme : je veux utiliser le point comme virgule ou transformer le point en virgule, si c'était pas clair voilà qui est fait

En supposant que tes TextBox sont sur Form1
(si tes Textbox sont dans un conteneur, il suffit de remplacer me par le nom du conteneur ; ex pour un panel : For Each ctrl In Panel1.Controls.OfType(Of TextBox)())

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
    Sub SetEventTxtsKeyPress()
        For Each ctrl In Me.Controls.OfType(Of TextBox)()
            AddHandler ctrl.KeyPress, AddressOf PointEnVirgule
        Next
    End Sub
    Sub PointEnVirgule(sender As System.Object, e As System.Windows.Forms.KeyPressEventArgs)
        If (e.KeyChar = ".") Then
            e.Handled = True
            TryCast(sender, TextBox).AppendText(",")
        End If
    End Sub

Si tu veux simplifier l'écriture de "PointEnVirgule" tu peux l'écrire ainsi :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
    Sub PointEnVirgule(sender As System.Object, e As System.Windows.Forms.KeyPressEventArgs)
        e.Handled = (e.KeyChar = ".")
        If e.Handled Then TryCast(sender, TextBox).AppendText(",")
    End Sub

Si tes TextBox sont dans plusieurs conteneurs, tu peux faire une méthode récursive.

Il suffit d'appeler "SetEventTxtsKeyPress" dans le "load" de ta feuille.

Après, comme indiqué tout au long de ce fil, il existe plusieurs façon de traiter ce problème.
Bonne programmation

[mactwist69]

Ou n'ème proposition

Tu te crées un User Control : Tu prends un Textbox, tu crées l’événement dont on vient de parler... Et voilà, Et tu utilise ce textbox personnalisé partout. Ce qu'il fait que le point sera remplacé, sans avoir à écrire le code de partout... Tu ne l'auras écris qu'une seule fois.

C'est exactement le cas de figure de la bonne utilisation d'un UserControl.

[Adakhum]

Si je met ce code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
 
    Sub SetEventTxtsKeyPress()
        For Each ctrl In Panel1.Controls.OfType(Of TextBox)())
            AddHandler ctrl.KeyPress, AddressOf PointEnVirgule
        Next
    End Sub
    Sub PointEnVirgule(sender As System.Object, e As System.Windows.Forms.KeyPressEventArgs)
        If (e.KeyChar = ".") Then
            e.Handled = True
            TryCast(sender, TextBox).AppendText(",")
        End If
    End Sub
 
    Sub PointEnVirgule(sender As System.Object, e As System.Windows.Forms.KeyPressEventArgs)
        e.Handled = (e.KeyChar = ".")
        If e.Handled Then TryCast(sender, TextBox).AppendText(",")
    End Sub

C'est sensé transformé un point en virgule ? je peux le mettre au début de ma classe de mon programme principal ? Et si je fais une autre fenetre et donc une autre classe, je dois remettre le code ? Si je pose les questions c'est que j'ai essayé quelque chose mais ça ne fonctionne pas.. mes valeurs qui normalement se calculent en temps réel restent figées.
Merci de votre patience :o

[rv26t]

C'est sensé transformé un point en virgule ?

Oui, sur une saisie utilisateur lorsqu'il appuie sur la touche.

je peux le mettre au début de ma classe de mon programme principal ? Et si je fais une autre fenetre et donc une autre classe, je dois remettre le code ?

Dans ce cas tu crés une classe outils ou tu places tes fonctions générales (le plus simple étant de les mettre en shared)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
Public Class Outils
 
    Public Shared Sub SetEventTxtsKeyPress(conteneur As Control)
        For Each ctrl In conteneur.Controls.OfType(Of TextBox)()
            AddHandler ctrl.KeyPress, AddressOf OnPointEnVirgule
        Next
    End Sub
 
    Public Shared Sub OnPointEnVirgule(sender As System.Object, e As System.Windows.Forms.KeyPressEventArgs)
        e.Handled = (e.KeyChar = ".")
        If e.Handled Then TryCast(sender, TextBox).AppendText(",")
    End Sub
 
End Class

Dans chaque évènement Load de tes fenêtres tu places cette ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Outils.SetEventTxtsKeyPress(Me)

Si je pose les questions c'est que j'ai essayé quelque chose mais ça ne fonctionne pas.

Possible un copier/coller n'est pas une saisie utilisateur, donc les points passent. Idem pour une affectation.

mes valeurs qui normalement se calculent en temps réel restent figées.

Après sans connaître les autres évènements déclenchant les calculs, ni voir ton code, difficile de deviner.

_______________________________________
Sinon,

- Faire une textbox personnalisé qui parserais la chaine pour la remplacer.

Tu te crées un User Control : Tu prends un Textbox, ... Et voilà, Et tu utilise ce textbox personnalisé partout. Ce qu'il fait que le point sera remplacé, sans avoir à écrire le code de partout... Tu ne l'auras écris qu'une seule fois.

C'est exactement le cas de figure de la bonne utilisation d'un UserControl.

Te permettrons de gérer tous les cas de figures.

_______________________________________
Parenthèse ;
Pour traiter les conteneurs imbriqués, je te propose 2 solutions :
- Parcours des contrôles classique

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
    Public Shared Sub SetEventTxtsKeyPress(conteneur As Control)
        For Each ctrl As Control In conteneur.Controls  ' parcour de la collection des contrôles du conteneur
            Select Case True                            ' select sur true (condition vrai), qui sera vérifié sur chaque case si "ctrl" correspond au type de controle 
                Case TypeOf ctrl Is TextBox
                    AddHandler ctrl.KeyPress, AddressOf OnPointEnVirgule
                Case TypeOf ctrl Is Panel, TypeOf ctrl Is GroupBox
                    SetEventTxtsKeyPress(ctrl)
            End Select
        Next
    End Sub
    Public Shared Sub OnPointEnVirgule(sender As System.Object, e As System.Windows.Forms.KeyPressEventArgs)
        e.Handled = (e.KeyChar = ".")
        If e.Handled Then TryCast(sender, TextBox).AppendText(",")
    End Sub

-
Ou une autre méthode proposé par un membre : boucler sur toutes les textbox d'un formulaire
Utilisable ainsi

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
    Public Shared Sub SetEventTxtsKeyPress(conteneur As Control)
        Array.ForEach(GetAllControls(Of TextBox)(conteneur).ToArray, Sub(tb) AddHandler tb.KeyPress, AddressOf OnPointEnVirgule)
    End Sub
 
    Public Shared Function GetAllControls(Of TControl As Control)(source As Control) As IEnumerable(Of TControl)
        Dim children = source.Controls.Cast(Of Control)()
        Return children.SelectMany(Function(child) GetAllControls(Of TControl)(child)).OfType(Of TControl).Concat(children.OfType(Of TControl))
    End Function
    Public Shared Sub OnPointEnVirgule(sender As System.Object, e As System.Windows.Forms.KeyPressEventArgs)
        e.Handled = (e.KeyChar = ".")
        If e.Handled Then TryCast(sender, TextBox).AppendText(",")
    End Sub

Touijours l'appel dans le Load de chaque formulaire.
[Edit]
Mais à mon avis il faut placer ces textbox dans un conteneur (panel, grroupbox) et appliquer la restriction uniquement sur ceux-ci. (il y a bien des endroits ou le point pourra être saisi dans une chaine de caractère)

[Adakhum]

Merci beaucoup pour ta réponse complète, tu te donnes beaucoup pour quelqu'un qui comprend rien comme moi

je met deux images de mon programme pour visualiser la chose :




Donc en effet j'ai des TextBox dans des Panel et des Groupbox les uns dans les autres... Mais le fait que ton code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
Select Case True                            ' select sur true (condition vrai), qui sera vérifié sur chaque case si "ctrl" correspond au type de controle 
                Case TypeOf ctrl Is TextBox
                    AddHandler ctrl.KeyPress, AddressOf OnPointEnVirgule
                Case TypeOf ctrl Is Panel, TypeOf ctrl Is GroupBox
                    SetEventTxtsKeyPress(ctrl)

permet de prendre directement TOUS les Textbox contenus dans les groupbox et les panels, il travaille par type de controle et non par noms de controle ?
Si je met ton code dans une classe outils, je met la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Outils.SetEventTxtsKeyPress(Me)

dans mon

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Public Sub App_TubesSurPlaques_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

permet de ne pas mettre cette ligne dans tous mes autres sub qui suivent ?

[rv26t]

Donc en effet j'ai des TextBox dans des Panel et des Groupbox les uns dans les autres... Mais le fait que ton code :
permet de prendre directement TOUS les Textbox contenus dans les groupbox et les panels, il travaille par type de controle et non par noms de controle ?

Oui

Si je met ton code dans une classe outils, je met la ligne

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Outils.SetEventTxtsKeyPress(Me)

dans mon

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

Public Sub App_TubesSurPlaques_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

permet de ne pas mettre cette ligne dans tous mes autres sub qui suivent ?

Exact, teste, tu verras.

(tu peux aussi seulement passer le nom d'un de tes contrôles panel ou groupbox au lieu de la form : Outils.SetEventTxtsKeyPress(MonGroupBoxTube).

[Adakhum]

ben .. j'ai honte de mon incompétence, ça ne fonctionne pas : quand je rentre un point du pavé num ça rentre un point.
..et ça fait aucun calcul après

Edit : je sais pas si ça joue, j'ai visual studio 2008 .. Framework 3.5

[mactwist69]

Lol, c'est pas grave.

Pour t'aider à comprendre "tout seul", mets un point d'arrêt sur les fonctions que tu as écrites... Lorsque tu tapes un Point, le code devrait s’arrêter sur le point d'arrêt. Alors tu avances au pas à pas avec F10 ou F11 (pas a pas entrant), et tu verras si quelque chose cloche.

C'est cette méthode qui va te permettre de TOUT débugger.

[shayw]

quand je rentre un point du pavé num ça rentre un point

sur n'importe quel textbox ?

[youtpout978]

Moi avant j'utilisais les textbox pour toutes les données même pour les nombres ce qui me faisait rajouter du code pour la validation et j'ai découvert le control NumericUpDown pour la saisie des nombres et depuis plus de problème.

[Adakhum]

sur n'importe quel textbox ?

oui ...

@ youtpout978 : je me renseigne sur ça

@ mactwist69 : ce qu'est bizarre (enfin..) c'est que par contre dans le code faut rentrer toujours un Point pour faire une virgule sinon il est pas content..

[mactwist69]

C'est à dire, ça marche quand tu fais un point ?

[Adakhum]

ah non ça marche toujours pas, quand je met un point ça bloque tout et c'est là qu'il me met l'erreur :
L'exception CastInvalidException n'a pas été géré... parce qu'il essaie de faire le calcul avec un point mais il connait pas le point en tant que séparateur décimal

Mais quand je le lance, si y'a pas de point mais que des virgules, le programme marche très bien

[mactwist69]

Oui, donc ça veut dire que le point n'est pas remplacer...
Mais j'ai envie de dire... que le point devrait être remplacé par la virgule dès que tu le tapes non ?

Donc le problème est en amont.

As tu essayer de mettre des points d'arrêts pour voir ce qu'il se passe quand tu tapes sur le clavier un point ?
Pour voir dans quelles procédures il va, voir ce qu'il se passe au pas-a-pas...

[Adakhum]

"que le point devrait être remplacé par la virgule dès que tu le tapes non ?"

Oui ! ca serait trop bien et c'est ce qu'est censé faire le programme de rv26t, mais si le programme marchait correctement avec le point apres moi ça m'est égale !

oui j'ai fais pas a pas : En fait le moment où il bug c'est au moment où il essaie de faire le 1er calcul, parce qu'il peut accepter le caractere "." dans une TextBox du moment qu'il en fait rien, dès que le calcul commence, il bug.