Discussion :

[atchopba]

Bonjour,

je voudrai remplacer toute occurrence majuscule par minuscule en fonction d'un regex. Malheureusement pour moi, quand il trouve le regex dans une ligne, il change du regex jusqu'à la fin de la ligne.
Ligne: <texte id="cellule_10" taille="50" table="pap_MH" champ="DénOMINATI" label="Dénomination" unite="" ancrableable="oui" />
Commande shell :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sed -i 's/champ=\".*\".*/\L\0/' mon_fichier_qui_contient_le_texte.txt

Je voudrai juste mettre tout ce qui est dans champ="" en minuscule sur chaque ligne de mon fichier.

Merci bien.
Albin

[atchopba]

Même cette ligne de commande ne marche pas.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sed -i 's/champ=\".*\"/\L\0/'

mon_fichier_qui_contient_le_texte.txt

Merci bien,
Albin

[zipe31]

Salut,

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sed 's/\(champ="\)\([^"]*\)/\1\L\2/'

[atchopba]

Merci bien ! ça marche. Et j'ai un autre souci: remplacer maintenant les caractères accentués comme "é" par "e", "è" par "e", "à" par "a" toujours dans ce même contexte. Je ne trouve pas comment faire mon regex.

Toujours cette même ligne: <texte id="cellule_10" taille="50" table="pap_MH" champ="dénominati" label="Dénomination" unite="" ancrableable="oui" />

[zipe31]

Il n'y a pas de regex pour la substitution de caractères accentués, c'est du littéral à la façon de la commande tr :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sed 'y/àçéèëêïîöôùüûÀÇÉÈËÊÏÎÖÔÙÜÛ/aceeeeiioouuuACEEEEIIOOUUU/'

C'est la même chose avec

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

tr

:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

tr 'àçéèëêïîöôùüûÀÇÉÈËÊÏÎÖÔÙÜÛ' 'aceeeeiioouuuACEEEEIIOOUUU'

[atchopba]

Justement, je sais ça...mais c'est toujours le fameux champ="" que je veux les remplacer. Je ne sais pas comment m'y prendre.

[disedorgue]

Bonjour,

Voici un exemple pour le "é":

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sed -e 's/\(champ="[^"]*"\)/XXX\1YYY/;h;s/.*XXX/VVV/;s/YYY.*/WWW/;s/.*/\L&/;y/é/e/;G;s/vvv\(.*\)www\n\(.*\)XXX.*YYY/\2\1/'

En principe, la seule partie à compléter est sur la commande de substitution littéral (y/é/e/)

[zipe31]

Salut,

Bonjour,

Voici un exemple pour le "é":

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sed -e 's/\(champ="[^"]*"\)/XXX\1YYY/;h;s/.*XXX/VVV/;s/YYY.*/WWW/;s/.*/\L&/;y/é/e/;G;s/vvv\(.*\)www\n\(.*\)XXX.*YYY/\2\1/'

En principe, la seule partie à compléter est sur la commande de substitution littéral (y/é/e/)

Bien vu, fallait y penser

Concernant le y/é/e/, pour généraliser le tout, il suffit de déclarer 2 variables avant :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

A='àçéèëêïîöôùüûÀÇÉÈËÊÏÎÖÔÙÜÛ'; B='aceeeeiioouuuACEEEEIIOOUUU'

Puis de changer ta syntaxe par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sed -e 's/\(champ="[^"]*"\)/XXX\1YYY/;h;s/.*XXX/VVV/;s/YYY.*/WWW/;s/.*/\L&/;y/'${A}'/'${B}'/;G;s/vvv\(.*\)www\n\(.*\)XXX.*YYY/\2\1/'

[atchopba]

ça remplace bien les "é" par "e" par contre il duplique certaines lignes de mon fichier.
Ligne originale:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
<cellule id="cellule_9">
            <texte id="cellule_10" taille="50" table="cof_gp_MH" champ="DénOMINATI" label="Dénomination" />
          </cellule>
          <cellule id="cellule_13">
            <texte id="cellule_14" taille="254" table="cof_gp_MH" champ="élémENTS_P" label="Element principal" />
          </cellule>

Ligne après le passage de la commande shell:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
<cellule id="cellule_9">
          <cellule id="cellule_9">
            <texte id="cellule_10" taille="50" table="cof_gp_MH" champ="denominati" label="Dénomination" />
          </cellule>
          </cellule>
          <cellule id="cellule_13">
          <cellule id="cellule_13">
            <texte id="cellule_14" taille="254" table="cof_gp_MH" champ="elements_p" label="Element principal" />
          </cellule>

[zipe31]

Rajoute /champ=/{…} comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sed -e '/champ=/{s/\(champ="[^"]*"\)/XXX\1YYY/;h;s/.*XXX/VVV/;s/YYY.*/WWW/;s/.*/\L&/;y/'${A}'/'${B}'/;G;s/vvv\(.*\)www\n\(.*\)XXX.*YYY/\2\1/}'

[Flodelarab]

Bonjour,

attention, ça pique les yeux:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
$ cat sedtest.txt
<texte id="cellule_10" taille="50" table="pap_MH" champ="DénOMINATI" label="Dénomination" unite="" ancrableable="oui" />

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
$ sed '/champ=/{s/\(.*\)\(champ="[^"]*"\)\(.*\)/\2\n\1\n\3/;h;s/\n.*//;y/àçéèëêïîöôùüûÀÇÉÈËÊÏÎÖÔÙÜÛ/aceeeeiioouuuACEEEEIIOOUUU/;s/\(champ="\)\([^"]*\)/\1\L\2/;G;s/\(.*\)\n\(.*\)\n\(.*\)\n\(.*\)/\3\1\4/}' sedtest.txt
<texte id="cellule_10" taille="50" table="pap_MH" champ="denominati" label="Dénomination" unite="" ancrableable="oui" />

[atchopba]

ça marche magnifiquement bien.
Merci à Flodelarab, zipe31 et disedorgue.

Respect !

[disedorgue]

Rajoute /champ=/{…} comme ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sed -e '/champ=/{s/\(champ="[^"]*"\)/XXX\1YYY/;h;s/.*XXX/VVV/;s/YYY.*/WWW/;s/.*/\L&/;y/'${A}'/'${B}'/;G;s/vvv\(.*\)www\n\(.*\)XXX.*YYY/\2\1/}'

Juste un petit détail: pour une meilleur compatibilité des différents sed, ne pas oublier le ";" avant la fermeture du bloc de commande:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sed -e '/champ=/{s/\(champ="[^"]*"\)/XXX\1YYY/;h;s/.*XXX/VVV/;s/YYY.*/WWW/;s/.*/\L&/;y/'${A}'/'${B}'/;G;s/vvv\(.*\)www\n\(.*\)XXX.*YYY/\2\1/;}'

[zipe31]

Juste un petit détail: pour une meilleur compatibilité des différents sed, ne pas oublier le ";" avant la fermeture du bloc de commande:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

sed -e '/champ=/{s/\(champ="[^"]*"\)/XXX\1YYY/;h;s/.*XXX/VVV/;s/YYY.*/WWW/;s/.*/\L&/;y/'${A}'/'${B}'/;G;s/vvv\(.*\)www\n\(.*\)XXX.*YYY/\2\1/;}'

C'est vrai, merci. Bien que nous soyons dans le forum "Shell et commandes GNU", comme GNU sed

[Flodelarab]

Puisqu'on évoque les détails: XXX YYY et WWW peuvent se trouver dans la ligne. Mais pas \n .

Voilà pourquoi c'est plus robuste de prendre \n comme séparateur repérable.

[disedorgue]

C'est vrai, sauf si dans les regex comprenant les XXX,YYY,VVV,WWW (ainsi que les vvv,www...) , j'avais préciser le pattern de base \(champ="[^\]*"\). Mais je reconnais que je l'ai joué faignasse