Discussion :

[Oupsy]

Bonjour à tous,

Je viens vers vous car je suis assez embêté concernant un problème dans la fermeture de Lync 2013

Je souhaiterai forcer les utilisateurs à laisser ouvert Lync 2013 et pour cela j'avais l'idée en tête d'un script permettant de désactiver la "croix rouge" de la fenêtre Lync.
Ou bien de ré ouvrir la fenêtre de Lync quand on appuie sur la croix.

Savez vous s'il est possible d'effectuer cette manipulation avec un script VBS ?

Merci de votre aide

Cordialement

[hackoofr]

Vous pouvez adapter ce script en changeant juste le chemin de votre application à lancer
Dans ce script, on vérifie l'existence de Internet explorer

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
Option Explicit
Dim ProcessPath
ProcessPath = "%ProgramFiles%\Internet Explorer\iexplore.exe"
Do
    Call CheckProcess(DblQuote(ProcessPath))
    Call Pause(5)
Loop
'**************************************************************************
Sub CheckProcess(ProcessPath)
    Dim strComputer,objWMIService,colProcesses,WshShell,Tab,ProcessName
    strComputer = "."
    Tab = Split(ProcessPath,"\")
    ProcessName = Tab(UBound(Tab))
    ProcessName = Replace(ProcessName,Chr(34),"")
    'Msgbox ProcessName
    Set objWMIService = GetObject("winmgmts:" _
    & "{impersonationLevel=impersonate}!\\" & strComputer & "\root\cimv2")
    Set colProcesses = objWMIService.ExecQuery _
    ("Select * from Win32_Process Where Name = '"& ProcessName & "'")
    If colProcesses.Count = 0 Then
        Set WshShell = CreateObject("WScript.Shell")
        WshShell.Run ProcessPath
    Else
        Exit Sub
    End if
End Sub
'**************************************************************************
'Fonction pour ajouter les doubles quotes dans une variable
Function DblQuote(Str)
    DblQuote = Chr(34) & Str & Chr(34)
End Function
'**************************************************************************
Sub Pause(NSeconds)
    Wscript.Sleep(NSeconds*1000)
End Sub  
'**************************************************************************

[Oupsy]

Bonjour hackooff

Désolé pour ma réponse tardive mais j'étais parti en vacances

je te remercie de ton aide ! Vraiment cool ce petit script !

Par contre j'ai une question :
Lync se relance automatiquement lorsque qu'on le ferme mais par contre les utilisateurs peuvent se déconnecter.
Connaissez vous un moyen qui pourrait interdire la déconnexion ou bien comme le script précédent , relancer automatiquement la connexion ?

Merci en tout cas pour votre aide !

[Oupsy]

Personne à une petite idée du coup sur le petit script ?(pour empêcher la déconnexion de Lync)

Merci !