Discussion :

[rag83]

Bonjour,

Une petite question si tu passes par la LedZeppII, qu'est ce qui, dans ton code suivant

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
Sub CreerMenuCtxl_mnCtxlHyperlink()
Dim cmdBar As Object        'Office.CommandBar
Dim cmdPopup As Object      'Office.CommandBarPopup
Dim ctlButton As Object, ctlTmpBtn As Object 'Office.CommandBarButton
Dim sMenu As String
Dim i As Integer
Const msoBarPopup = 5
 
sMenu = "mnCtxlHyperlink"
On Error Resume Next
Set cmdBar = Application.CommandBars(sMenu)
On Error GoTo 0
 
If Not (cmdBar Is Nothing) Then
   cmdBar.Delete
End If
 
Set cmdBar = Application.CommandBars.Add(sMenu, msoBarPopup, False, False)
' Bouton Copier
Application.CommandBars("Database").FindControl(, 19).Copy cmdBar
' Bouton Couper
Application.CommandBars("Database").FindControl(, 21).Copy cmdBar
' Bouton Coller
Application.CommandBars("Database").FindControl(, 22).Copy cmdBar
' Bouton Coller spécial
Application.CommandBars.FindControl(, 755).Copy cmdBar
 
' Bouton supprimer hypertexte personnalisé, pour être visible en runtime
Set ctlButton = cmdBar.Controls.Add(msoControlButton, , , , False)
ctlButton.Caption = "Supprimer lien hypertexte"
ctlButton.Style = msoButtonIconAndCaption
ctlButton.OnAction = "=fnMyDeleteHyperlink()"
Set cmdPopup = Application.CommandBars("Form DataSheet Cell").FindControl(, 30094)
For i = 1 To cmdPopup.Controls.Count
    If cmdPopup.Controls(i).ID = 3626 Then
       Set ctlTmpBtn = cmdPopup.Controls(i)
       ctlTmpBtn.CopyFace
       ctlButton.PasteFace
    End If
Next
 
cmdBar.Enabled = True
End Sub

fait en sorte que l’icône qui s'affiche à gauche de "supprimer lien hypertexte" est celle des liens hypertexte.

Si je veux utiliser ce code pour d'autres fonctions, comment mettre une autre icône que celle des liens hypertextes ?

Merci

[LedZeppII]

Bonjour,

Ce sont les lignes 6 à 13 qui créent l'image:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
' Bouton supprimer hypertexte personnalisé, pour être visible en runtime
Set ctlButton = cmdBar.Controls.Add(msoControlButton, , , , False)
ctlButton.Caption = "Supprimer lien hypertexte"
ctlButton.Style = msoButtonIconAndCaption
ctlButton.OnAction = "=fnMyDeleteHyperlink()"
Set cmdPopup = Application.CommandBars("Form DataSheet Cell").FindControl(, 30094)
For i = 1 To cmdPopup.Controls.Count
    If cmdPopup.Controls(i).ID = 3626 Then
       Set ctlTmpBtn = cmdPopup.Controls(i)
       ctlTmpBtn.CopyFace
       ctlButton.PasteFace
    End If
Next

La ligne 6 récupère le sous-menu dont l'identifiant est 30094.
Ensuite je parcours les contrôles du sous-menu jusqu'à trouver l'élément de menu dont l'identifiant est 3626 (Supprimer le lien hypertexte).
Une fois trouvé, je copie son image avec .CopyFace et je la colle avec .PasteFace.

J'ai trouvé ces identifiants de contrôles grâce à un outil que je me suis créé pour parcourir les menus (CommandBars) d'Access.
Si tu veux créer ta propre image regarde ici : image perso menu personnalisé

A+

[rag83]

D'accord, ce n'est donc pas si simple.

Si tu as créé un outil pour ça, c'est qu'il ne doit pas exister de liste où on pourrait voir les icônes correspondantes aux menus, c'est bien dommage.

J'aimerais utiliser l’icône supprimer (la croix grise) du menu générateur d'images d'access pour un petit code personnalisé.

Pourrais-tu me dire quel code lui correspond ?

Merci

[LedZeppII]

Bonsoir,

Tu remplaces:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
Set cmdPopup = Application.CommandBars("Form DataSheet Cell").FindControl(, 30094)
For i = 1 To cmdPopup.Controls.Count
    If cmdPopup.Controls(i).ID = 3626 Then
       Set ctlTmpBtn = cmdPopup.Controls(i)
       ctlTmpBtn.CopyFace
       ctlButton.PasteFace
    End If
Next

par:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Set ctlTmpBtn = Application.CommandBars("Edit").FindControl(, 478)
ctlTmpBtn.CopyFace
ctlButton.PasteFace

Cela va copier/coller l'image de l'élément de menu Supprimer du sous-menu Edition de l'ancien menu principal d'Acess 2003.
C'est ce que j'ai trouvé de plus approchant de l'image dont tu parles.

A+

[rag83]

Mais c'est parfait, ça ne s'approche pas de l'image dont je parle, c'est exactement celle-la

Je te remercie LedZeppII.