Discussion :

[Alex_42]

bonjour à tous,

mon objectif :

faire un compteur d'utilisation ; dans le principe, lorsqu'on lance l'appli pour la première fois , ajouter , dans une table, la date du jour et un à compteur 1, si on lance à nouveau l'appli dans la même journée je veux passer ce compteur à 2, etc .... et le lendemain créer une nouvelle ligne avec la date du jour avec un compteur à 1, et ainsi de suite :

Mon code actuel qui ne fonctionne pas, bien évidement :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
    Dim db As DAO.Database
    Dim rst As DAO.Recordset
    Dim StrJour As Date
 
    Set db = CurrentDb()
    Set rst = db.OpenRecordset("T_Date", dbOpenDynaset)
 
    StrJour = Date
 
    rst.FindFirst "[suivi JPM date] =" & StrJour 'recherche dans la table si la date du jour est déjà présente
    If rst.NoMatch Then              'si je ne trouve pas de date dans la table égale à la date du jour alors je créé une nouvelle ligne avec date du jour + compteur = 1
        rst.AddNew
        rst("suivi JPM nb") = 1
        rst("suivi JPM date") = StrJour
        Else                                'si je trouve une date dans la table égale à la date du jour , j'incrémente le compteur de 1
            rst.Edit
            rst("suivi JPM nb") = "suivi JPM nb" + 1
            rst.Update
    End If

je découvre l'utilisation des RecordSet et j'avoue que je rame un peu

Merci d'avance.

[madefemere]

Re-,

J'allais continuer dans l'autre sujet mais comme tu en as ouvert un autre.
L'utilisation des dates comme paramètre est particulière :
- Il faut les mettre entre croisillons "#".
- Ne pas oublier de les mettre sous format US en VBA.
Donc le Findfirst devrait être :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

 rst.FindFirst "[suivi JPM date] =#" & Format(StrJour, "mm/dd/yyyy") & "#"

Et tu as oublié un rst.UpDate après avoir appliqué le rst.AddNew.
Ce qui donnerait :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
    Dim db As DAO.Database
    Dim rst As DAO.Recordset
    Dim StrJour As Date
      Set db = CurrentDb()
    Set rst = db.OpenRecordset("T_Date", dbOpenDynaset)
 
    StrJour = Date
 
    rst.FindFirst "[suivi JPM date] =#" & Format(StrJour, "mm/dd/yyyy") & "#" 'recherche dans la table si la date du jour est déjà présente
    'Debug.Print "[suivi JPM date]=#" & Format(StrJour, "mm/dd/yyyy") & "#"
    'MsgBox "Date : " & rst("[suivi JPM date]")
    If rst.NoMatch Then              'si je ne trouve pas de date dans la table égale à la date du jour alors je créé une nouvelle ligne avec date du jour + compteur = 1
            rst.AddNew
            rst("suivi JPM nb") = 1
            rst("suivi JPM date") = StrJour
            rst.Update
        Else                                'si je trouve une date dans la table égale à la date du jour , j'incrémente le compteur de 1
            rst.Edit
            rst("suivi JPM nb") = [suivi JPM nb] + 1
            rst.Update
    End If

Cordialement,

[ClaudeLELOUP]

Bonjour, tu peux y arriver plus simplement :

En définissant ta table ainsi :




et en exécutant ces 2 requêtes à l'ouverture de la BdD :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
INSERT INTO T_date ( [Suivi JPM date] )
SELECT Date() AS Expr1;

N.B. Elle sera sans effet dès la 2e exécution.
et

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
UPDATE T_date SET T_date.[Suivi JPM nb] = [Suivi JPM nb]+1
WHERE (((T_date.[Suivi JPM date])=Date()));

Edit : Bonjour Mandresy. Tu as posté pendant que rédigeais.

[madefemere]

Bonjour Claude,

En fait le titre est très vague par rapport à ses besoins. Il a un problème dans l'utilisation d'une expression de critère avec Date dans un FindFirst (ça ne lui donne rien).
Mais ta proposition lui permettra de découvrir un autre moyen d'utiliser le SQL pour une mise à jour ou rajout.

La balle est dans le camp d'Alex_42.

Cordialement,

[Alex_42]

Merci à vous , et surtout à Madefemere
ca marche enfin avec les recordset et franchement le seule différence et le format de date dont tu parles.
j'aurais pu chercher longtemps ....

Merci encore !

A++