Discussion :

[prendel]

Bonjour à tous,

J'ai réaliser une macro depuis excel qui apres avoir mis à jour un fichier va lancer une macro access afin qu'access importe les données mises à jour, or quand je lance la macro une première fois tout ca passe bien mais quand je la relance peu de temps apres j'ai une erreur d'execution '462' Le serveur distant n'existe pas ou n'est pas disponible sur la ligne se trouvant juste apres celle du with:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
With Access.Application
    .OpenCurrentDatabase "CheminVersMaBase"
    .Run "ImportFromExcel", arg1, Chemin
    .CloseCurrentDatabase
    .Quit
End With

Que puis je faire pour ne plus avoir cette erreur

Merci pour vos réponses

[LedZeppII]

Bonjour,

Voici un exemple de code qui s'exécute dans Excel et qui fonctionne correctement dans mon cas:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Sub ExportDansAccess()
Dim accApp As Object                ' objet Access.Application
Dim sFichXlCheminComplet As String  ' ce fichier Excel
Dim sBddCheminComplet As String     ' bdd à ouvrir
Dim sNomTable As String             ' table dans laquelle Access doit importer
 
sBddCheminComplet = "C:\Temp\bd_cible.accdb"
sNomTable = "TableXL"
sFichXlCheminComplet = Application.ThisWorkbook.FullName
 
' Crée une nouvelle instance d'Access
Set accApp = CreateObject("Access.Application")
' Ouvre la base données
accApp.OpenCurrentDatabase sBddCheminComplet
' Exécute la sub ImportExcel
accApp.Run "ImportExcel", sNomTable, sFichXlCheminComplet
' Ferme la base de données
accApp.CloseCurrentDatabase
' Ferme Access
accApp.Quit
' Libère la ressource Access.Application
Set accApp = Nothing
End Sub

Dans mon exemple la sub ImportExcel (macro VBA Access) attend en arguments le nom de la table dans laquelle il faut importer, et le nom complet du fichier Excel.

A+

[prendel]

Merci beaucoup, je n'ai plus de soucis à cause de cette erreur, tout fonctionne correctement