Discussion :

[frabey]

Bonjour,


j'essai sous Access 2010, de lire des tables pour les Ecrire sous excel 2003 (plusieurs onglet de data pour mettre a jour des tableaux dynamiques) . La fonction d'écriture marche très bien mais ma fonction de mise à jour des tableaux se plante une fois sur deux ( et marche une fois sur deux ) . J'ai un code erreur 462 :" Le serveur distant n'existe pas ou n'est pas disponible"

Si vous pouvez m'aider, je ne trouve aucune solution : voici mon code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
Public Function maj_tdbd()
 
Dim pvt As PivotTable
Dim sh As Worksheet
 
 On Error GoTo ErrorHandler
 
For Each sh In Worksheets
    If sh.PivotTables.Count >= 1 Then
        For Each pvt In sh.PivotTables
            pvt.RefreshTable
 
        Next pvt
 
    End If
Next sh
 
 
 
Exit Function
ErrorHandler:
    Call gest_err("Mise à jour des TDB", "xls_liste_osg", Err.Number, Err.Description)
End Function

MERCI

[paidge]

Bonjour,
Peut-être qu'une partie du code est omise volontairement, mais voilà comment je procèderais :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
Public Function maj_tdbd()
    On Error GoTo Err_maj_tdbd
    Dim xlApp As Excel.Application, xlBook As Excel.Workbook, xlSheet As Excel.Worksheet
    Dim pvt As PivotTable
 
    ' ===== Initialisation des variables =====
    Set xlApp = CreateObject("Excel.Application")
    xlApp.Visible = False
    Set xlBook = xlApp.Workbooks.Open("c:\toto.xls")
 
    For Each xlSheet In xlBook.Worksheets
        If xlSheet.PivotTables.Count >= 1 Then
            For Each pvt In xlSheet.PivotTables
                pvt.RefreshTable
            Next pvt
        End If
    Next xlSheet
 
Exit_maj_tdbd:
    xlBook.Save
    ' Libération des variables
    xlApp.Quit
    Set xlSheet = Nothing
    Set xlBook = Nothing
    Set xlApp = Nothing
    Exit Function
 
Err_maj_tdbd:
    MsgBox "Error n°" & Err.Number & vbCrLf & "Description : " & Err.Description & vbCrLf & "Source : " & Err.Source, vbCritical, "Error"
    Resume Exit_maj_tdbd
End Function

[frabey]

en fait j'ai un main qui lance trois fonctions : l'init (initialisation des variables) , l’écriture et la mise a jour des tableaux. Donc je pense être dans
le même cas que ce que vous proposez ....

[paidge]

Je ne suis pas un spécialiste des modules de classe en VBA. Mais, par expérience, je sais que l'automation a du mal à marcher si on ne libère pas correctement les variables. Donc c'est une piste à creuser éventuellement.
Vérifies, notamment à chaque plantage de ta fonction, que tu n'as pas des instances Excel encore en mémoire dans le gestionnaire des tâches.

EDIT : J'ai fait cette proposition de code car, dans le tien, la collection Worksheets est appelée mais on ne sait pas sur quel objet

[frabey]

MERCI beaucoup. En vous lisant je me suis aperçu que je mettais "In Worksheets" au lieu de "In xlBook.Worksheets". Cela semble tourner impeccable en le rajoutant.
Un peu capricieux le monsieur ....

[paidge]

Bah non c'est normal, la collection Worksheets est une propriété des classes Excel.Application et Excel.Workbook...
marques le sujet comme résolu si c'est le cas

[frabey]

c est résolu grace à vous. Mais pourquoi cela fonctionnait une fois sur deux , si j'avais eu l'erreur a chaque fois peut être que j'aurai trouvé ...
encore merci