Ajout nom du doc avant impression

**nicdes** · 17/06/2014, 10h09

Bonjour à tous,

Je dois imprimer plusieurs centaines de documents word que je devrais ensuite trier en fonction de certaines de leurs caractéristiques.
Mon problème est que pour mon tri ultérieur le nom du document ne figure pas nulle part.
Connaissez-vous un moyen simple d'apposer à la volée (pour plusieurs centaines de doc...) le nom d'un document sur ledit document ?

Grand merci d'avance !

**Sepia** · 18/06/2014, 02h29

Salut nicdes,

Après avoir modifié ton message pour le comprendre, vérifie que c'est bien le sens de ta demande.

Si c'est le cas, la solution la plus simple consiste à regarder les paramètres de ton imprimante. Dans la majorité des imprimantes vieilles de moins 10 ans, tu peux ajouter des entêtes/pieds de pages d'impression dans les options comme la date & l'heure d'impression, le nom de la personne qui imprime (basé sur son login), le nom du document...

Vérifie en détails les options de ton pilote d'impression. Cherche de façon détaillée, car si tu utilises un serveur d'imprimante ou une imprimante réseau, l'option est présente mais parfois elle est bien cachée. Je ne peux pas t'aider plus en détails car les options dépendent des pilotes d'impression et des imprimantes.

Après plutôt qu'ajouter le nom du doc sur le doc ou sur la page de garde, ce qui oblige à modifier le doc et à écrire à un endroit où tu as peut-être déjà du texte, ce qui pourrait rendre le résultat illisible, une solution consiste à insérer une page d'intercalaire avec juste le nom du document. Cette technique est déjà utilisé depuis plus 25 ans sur les serveurs d'impression dans les fac, par exemple mais elle est consommatrice de papier ce qui n'est pas très écologique surtout si tes documents ont peu de pages.

@+

**nicdes** · 23/06/2014, 09h51

Bonjour Sepia,
Tout d'abord merci pour ta réponse. Je ne la découvre qu'aujourd'hui. Il faut que je modifie mes paramètres de compte car j'attendais une alerte en cas de réponse...
Ta modif me convient

Mon message faisait suite à diverses tentatives infructueuses via nos imprimantes réseau d'ajouter le nom ; ton message me redonne tout de même un peu d'espoir dans ce sens, je vais donc continuer d'explorer cette voie...
J'avais aussi expérimenté l'impression d'une page supplémentaire (intercalaire) avec les propriétés du doc, mais c'est comme tu le dis trop consommateur en papier, n'arrivant pas à générer cette page supplémentaire sur le verso de la page originale...
@+

**Sepia** · 23/06/2014, 16h29

Salut nicdes,

Tiens-nous au courant.

@+

**nicdes** · 25/06/2014, 11h21

Hello,
Rien de neuf sous le soleil...aucune option dans le paramétrage de nos imprimantes ne me permet d'ajouter le nom du fichier imprimé...
Une idée ?
@+

**Sepia** · 26/06/2014, 01h14

Salut nicdes,

Une solution est d'utiliser une imprimante PDF (il y a en a même des gratuites), avec les options d'ajout du nom du fichier puis d'imprimer ce PDF généré.

C'est pas cher (voir gratuit), ce n'est pas long à mettre ne place mais tu doubles ton temps d'impression(impression en PDF puis impression physique) et tu dois avoir un espace disque suffisant pour stocker tes impressions temporaires. L'avantage est que cette technique est scriptable/automatisable (avec la majorité des imprimantes PDF) y compris pour la purge des fichiers temporaires et donc ce n'est pas trop contraignant. A toi de voir.

@+

**Souriane** · 26/06/2014, 18h12

Bonjour,

Sépia, je ne comprends pas pourquoi ne pas utiliser une macro?

Moi j'ai une macro que lorsque je lance, elle fait ceci :

1. Ouvre le 1er document du répertoire X
2. Ajout un pied de page au document avec le nom
3. Lance l'impression
4. Ferme le document sans sauvegarder
Et elle reprend avec le document suivant.

Je peux lancer la macro sur un répertoire qui contient 100 documents, je n'ai jamais eu de problème. Pourquoi utiliser PDF? ? Je ne suis pas le raisonnement

Souriane

**clementmarcotte** · 26/06/2014, 20h40

Bonjour,

Envoyé par Souriane

Bonjour,

Sépia, je ne comprends pas pourquoi ne pas utiliser une macro?

Moi j'ai une macro que lorsque je lance, elle fait ceci :

1. Ouvre le 1er document du répertoire X
2. Ajout un pied de page au document avec le nom
3. Lance l'impression
4. Ferme le document sans sauvegarder
Et elle reprend avec le document suivant.

Je peux lancer la macro sur un répertoire qui contient 100 documents, je n'ai jamais eu de problème. Pourquoi utiliser PDF? ? Je ne suis pas le raisonnement

Souriane

C'est que le demandeur ne sait pas ce qu'il veut. Il a commencé par dire que la solution du nom de fichier en pied de page convenait. Après, il est revenu se plaindre de son imprimante. La solution qui lui reste c'est le PDF, ou de convaincre le fabricant de son imprimante, ou un hacker, de modifier le pilote d'imprimante. Word ne peut pas ajouter des fonctionnalités à une imprimante et les pilotes d'imprimantes ne sont pas programmés par Microsoft...

Nul n'est tenu à l'impossible.

**Sepia** · 27/06/2014, 04h51

Salut Souriane,

Sépia, je ne comprends pas pourquoi ne pas utiliser une macro?

Moi j'ai une macro que lorsque je lance, elle fait ceci :

1. Ouvre le 1er document du répertoire X
2. Ajout un pied de page au document avec le nom
3. Lance l'impression
4. Ferme le document sans sauvegarder
Et elle reprend avec le document suivant.

Je peux lancer la macro sur un répertoire qui contient 100 documents, je n'ai jamais eu de problème. Pourquoi utiliser PDF? ? Je ne suis pas le raisonnement

Souriane

Tu as raison mais que pour toi Souriane. Si tu travailles avec des documents qui viennent de n'importe où, ils peuvent avoir déjà des entêtes ==> Nous quand on travaille on ne fait aucune supposition sur le contenu des documents, sinon c'est mort, il faut alors repasser sur le code, rejouer des tests... C'est fastidieux et c'est irrespectueux du contenu du document du client ==> on ne modifie pas le document même visuellement si on ne le connait pas. Enfin si on peut et ici c'est le cas même si ce n'est pas facile. La solution doit être adaptée à la demande pas simplement répondre pour les cas standards en laissant de côté tous les cas complexes. Je ne connais pas nicdes et peut-être qu'il travaille dans un milieu légal où les documents peuvent être signés (cas des contrats en milieu des affaires) ou pour lesquels les mots sont comptés (cas des actes notariés)... De plus il y a aussi des cas où les documents sont des formulaires et qui peuvent être des documents quelconques mais non modifiables ==> Donc on va essayer de faire un cas qui marche simplement mais pour tous les cas (enfin ceux que je connais).

Donc ici pas de macro sauf si nicdes dit que finalement il s'y résoudre parce que c'est plus simple, ça ne le gêne pas, qu'il connait les documents qu'il génère (type publipostage...) et que la macro peut se déployer sur tous les postes, qu'il n'a pas e problème de sécurité, qu'il peut installer des composants comme il veut... Toutes ces petites contraintes du monde industriel et du travail (car je soupçonne nicdes de demander à imprimer plusieurs centaines de documents en une fois pour des besoins liés à une activité commerciale et/ou associative et non à titre perso).

Et comme le dit clementmarcotte, "Nul n'est tenu à l'impossible."

@+

**nicdes** · 27/06/2014, 10h28

Envoyé par clementmarcotte

Bonjour,
C'est que le demandeur ne sait pas ce qu'il veut. Il a commencé par dire que la solution du nom de fichier en pied de page convenait. Après, il est revenu se plaindre de son imprimante. La solution qui lui reste c'est le PDF, ou de convaincre le fabricant de son imprimante, ou un hacker, de modifier le pilote d'imprimante. Word ne peut pas ajouter des fonctionnalités à une imprimante et les pilotes d'imprimantes ne sont pas programmés par Microsoft...
Nul n'est tenu à l'impossible.

J'ai posté dans ce forum (vba word) car après des tentatives infructueuses via les paramètres imprimante, j'ai estimé qu'une macro word ferait très bien, et mieux l'affaire...
Si le répondeur reprend et lit attentivement les post, il constatera que je ne me suis pas plaint de mon imprimante mais ai repris cette piste sur les conseils de sepia...mais qu'elle n'a finalement rien donné.
Pour les imprimantes PDF, la problématique semble être la même que pour les drivers d'imprimantes classiques. Les solutions pour rajouter un watermark dynamique existent mais je n'en ai trouvé que des payantes.
Mon besoin de modifier les flux d'impression est ponctuel dans le cadre d'une étude documentaire avant un migration éditique...

Envoyé par Souriane

Bonjour,
Moi j'ai une macro que lorsque je lance, elle fait ceci :

1. Ouvre le 1er document du répertoire X
2. Ajout un pied de page au document avec le nom
3. Lance l'impression
4. Ferme le document sans sauvegarder
Et elle reprend avec le document suivant.
Souriane

@Souriane : du coup, si tu as une macro "toute faite" pour ça, je suis preneur

**Sepia** · 30/06/2014, 02h01

Salut nicdes,

@Souriane : du coup, si tu as une macro "toute faite" pour ça, je suis preneur

Moi aussi

**Souriane** · 30/06/2014, 16h19

Bon matin!

Alors voici le code que j'utilise.

Il ne vous restera plus qu'à l'adapter.

Je le présente en deux codes séparés (Sub TraiterTsDocsDuRepertoire et Sub InsereNomFichierSurLaPage) car la première peut servir dans beaucoup d'autres situations. On pourrait par exemple vouloir exécuter un code qui effacerait toutes les occurences du mot abc. Il y a juste à changer le nom de la macro qui est appelée.

J'ai écrit "'---------À adapter ici : ---" au-dessus des lignes à modifier à votre goût.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
 
Sub TraiterTsDocsDuRepertoire()
'##################################################################
'Macro développée par Souriane grâce à l'aide inestimable de
'Développez.com et particulièrement Heureux-Oli depuis de très nombreuses années!
 
'Le code va passer à travers de tous les documents .doc* d'un répertoire donné
'Et exécuter la macro désirée sur chacun des documents.
'##################################################################
 
Dim monFichier As String
Dim PathToUse As String
Dim myDoc As Document
Dim Response As Long
 
'---------À adapter ici : -------------------------
''Indiquer ici le nom du répertoire où se trouvent les document à imprimer
PathToUse = "C:\temp\1234\"
 
''Gestion de l'erreur
On Error Resume Next
 
''Ferme tous les documents avant de commencer
Documents.Close savechanges:=wdPromptToSaveChanges
 
''Chacun leur tour, la variable monFichier sera attribuée aux fichiers du répertoire déterminé.
    monFichier = Dir$(PathToUse & "*.doc*")
 
''Tant que la variable monFichier n'est pas vide, ce qui suit va se répéter en boucle
    While monFichier <> ""
        ''Désactive les macros automatiques sur ouverture
            WordBasic.DisableAutoMacros 1
        ''Ouvre le document
            Set myDoc = Documents.Open(PathToUse & monFichier)
 
 
'---------À adapter ici : -------------------------
        ''Procédure à exécuter ici - il pourrait s'agir d'une autre macro que celle suggérée.  En autant qu'elle referme le document à la fin.
            InsereNomFichierSurLaPage
 
         ''Passe au fichier suivant dans le répertoire
             monFichier = Dir$()
    Wend
 
 
WordBasic.DisableAutoMacros 0
     On Error GoTo 0
End Sub
 
 
 
 
Sub InsereNomFichierSurLaPage()
 
'##################################################################
'''Macro développée par Souriane grâce à l'aide inestimable de
'''Développez.com et particulièrement Heureux-Oli depuis de très nombreuses années!
'Le code insère le nom du fichier et son nom de répertoire dans une forme rectangulaire
'placée dans le coin inférieur droit à 1,5 cm de la marge inférieure du document.
'La forme semi-transparente cachera masquera légèrement le texte pouvant se trouver dans 'cette zone
'##################################################################
 
''Gèle la mise à jour de l'écran
Application.ScreenUpdating = False
 
''Enlève la protection sur le document s'il y a lieu
If ActiveDocument.ProtectionType <> wdNoProtection Then
ActiveDocument.Unprotect Password:=""
Else
End If
 
Dim MaForm As Shape       'La forme qui contiendra le chemin d'accès
 
'Insère une forme rectangulaire qui contiendra le nom du fichier
Set MaForm = ActiveDocument.Shapes.AddTextbox(msoTextOrientationHorizontal, CentimetersToPoints(0), CentimetersToPoints(0), CentimetersToPoints(18), CentimetersToPoints(2))
 
     With MaForm
    .Fill.Solid
    .Fill.Transparency = 0.75   'Transparence de la forme
    .Line.Weight = 0.75
    .Line.DashStyle = msoLineSolid
    .Line.Style = msoLineSingle
    .Line.Transparency = 0#
    .Line.Visible = msoFalse
    .LockAspectRatio = msoFalse
    .height = 60.9
    .Width = 510.5
    .RelativeHorizontalPosition = wdRelativeHorizontalPositionPage
    .Left = wdShapeRight
    .TextFrame.MarginLeft = 0#
    .TextFrame.MarginRight = 20
    .TextFrame.MarginTop = 0#
    .TextFrame.MarginBottom = 0#
    .LockAnchor = False
    .LayoutInCell = False
    .WrapFormat.AllowOverlap = False
    .WrapFormat.Side = wdWrapBoth
    .WrapFormat.DistanceTop = InchesToPoints(0)
    .WrapFormat.DistanceBottom = InchesToPoints(0)
    .WrapFormat.DistanceLeft = InchesToPoints(0.13)
    .WrapFormat.DistanceRight = InchesToPoints(0.13)
    .WrapFormat.Type = 3
    .ZOrder 4
    .TextFrame.AutoSize = False
    .TextFrame.WordWrap = True
 
     End With
 
MaForm.Select
 
''Appuie le texte à droite et s'assure du format 0 pt avant et après.
      With Selection.ParagraphFormat
     .Alignment = wdAlignParagraphRight
    .LineUnitBefore = 0
    .LineUnitAfter = 0
     End With
 
''Mise en forme du nom du fichier
     Selection.Font.name = "Arial"
     Selection.Font.Bold = True
     Selection.Font.Size = 14
 
     'NOTE : je ne sais pas pourquoi mais sans l'insertion d'un retour, la macro ne fonctionne pas...
     Selection.TypeParagraph
 
     'Insère le nom du fichier
     Selection.Fields.Add Range:=Selection.Range, Type:=wdFieldEmpty, Text:= _
    "FILENAME  ", PreserveFormatting:=True
 
     Selection.MoveUp Unit:=wdLine
     Selection.HomeKey Unit:=wdLine
     Selection.TypeBackspace
     Selection.EndKey Unit:=wdLine
     Selection.MoveDown Unit:=wdLine
     Selection.TypeParagraph
 
''Insère le nom du fichier au long
     Selection.Font.Size = 8
     Selection.Font.Bold = False
     Selection.Fields.Add Range:=Selection.Range, Type:=wdFieldEmpty, Text:= _
    "FILENAME  \p ", PreserveFormatting:=True
     Selection.TypeParagraph
 
  MaForm.RelativeVerticalPosition = wdRelativeVerticalPositionPage
  MaForm.Top = wdShapeBottom
 
''Si un erreur tel "marge trop proche", va ignorer l'erreur
     On Error Resume Next ' ignore printing errors
 
''Lancement de l'impression
Application.PrintOut Background:=True, Range:=wdPrintAllDocument
 
''Ferme sans sauvegarder
ActiveDocument.Close wdDoNotSaveChanges
 
End Sub

Vous m'en donnerez des nouvelles svp!

Merci!

Souriane

**nicdes** · 02/07/2014, 08h34

Bonjour Souriane,
Un grand bravo et merci !
En l'adaptant un tout petit peu, cette macro est parfaite pour moi !

Je marque le sujet comme résolu.

Ajout nom du doc avant impression [WD-2003]

VBA Word

Discussions similaires

Partager

Partager