[VBA]recupération du nombre d'enregistrements concernés par une requête action [Fait] [Résolu]

[borisa]

Bonjour,
je ne parviens pas à savoir si l'on peut recuperer les infos contenues dans le message emis lors du lancement d'une requete insert (requete objet MS Access).
Je souhaite en particulier obtenir le nb de lignes qui vont être insérées sans avoir à faire de "select count" avant (ou apres)... si c'est possible.
c'est le XXX du:
"you are about to insert XXX rws..."
merci de votre aide,
a+
b.

[Maxence HUBICHE]

voici un exemple de code qui utilise les ADO (Microsoft ActiveX Data Object x.xx Library)

Code :

1
2
3
4
5
6
7
8
9
10
11
12
13
 
Sub test()
    Const REQUETE As String = "raaa"
    Dim c As ADODB.Command
    Dim n As Long
    Set c = New ADODB.Command
 
    c.ActiveConnection = CurrentProject.Connection
    c.CommandText = REQUETE
    c.CommandType = adCmdStoredProc
    c.Execute n
    MsgBox n
End Sub

[borisa]

salut maxence et merci pour ton bout de code,

je n'ai pas précisé que j'utilise acc 97... donc j'ai remplacé currentproject par currentdb, mais j'ai :

Code :

operation not supported for this type of object

sur

Code :

currentdb.connection

Acc 97 permet-il d'executer ton code?
merci de ton aide.
a+
b.

[Maxence HUBICHE]

non.
Tu n'as pas ADO avec Access 97
par contre, tu peux le faire en DAO comme ceci :

Code :

1
2
3
4
5
6
7
8
9
10
 
 
Sub test2()
    Const REQUETE As String = "raaa"
    Dim q As DAO.QueryDef
    Dim n As Long
    Set q = CurrentDb.QueryDefs(REQUETE)
    q.Execute
    MsgBox q.RecordsAffected
End Sub

tu avais l'info dans la FAQ, ici :
http://access.developpez.com/faq/?page=SQL#qryActions

[borisa]

Oups, je réedite mon post : en fait ça amarche, mais je cherchais à faire ça avant execution, là c'est après puisqu'il faut passer execute avant de recupérer recordsaffected...j'ai testé ton code avant de regarder ce qu'il y avait dedans...desolé .

question subsidiaire : à quoi sert la référence ADO (MS activeX data object library 2.8..) dans access 97 si il n'y a pas d'ADO?
merci,
a+
b.

[Maxence HUBICHE]

Ben, c'est que tu dois avoir un truc d'installé sur ton PC qui nécessite les ADO. Sinon, la référence ne serait pas là.

[borisa]

ah ok, ça doit venir du fait que j'ai installé 97 en ecrasant 2000.
sinon, à ton avis récupérer l'info recordsaffected avant d'executer (pour proposer un message perso à la place de celui d'access par exemple) ça ne peut se faire que par des "select count" avant l'execution du insert into...?
a+
b.

[Tofalu]

Ou bien avec une transaction je pense.

Sub test2()
Const REQUETE As String = "raaa"
Dim q As DAO.QueryDef

Dim n As Long
DBEngine.BeginTrans
Set q = CurrentDb.QueryDefs(REQUETE)
q.Execute
If MsgBox("Vous allez insérer " & q.RecordsAffected & _
" nouveaux enregistrements." & vbCrLf & _
"Etes vous sûr de vouloir continuer ?", vbYesNo + vbQuestion, "Insertion") = vbYes Then

DBEngine.CommitTrans
Else
DBEngine.Rollback
End If
End Sub

Pas testé

[borisa]

ouuula! ça c'est magnifique! je teste pour voir...meme si dans mon cas c'est un peu le bulldozer pour enlever trois brins d'herbe, ça peut toujours servir.
a+
b.

[borisa]

Ok c'est parfait et en plus j'aime bien, c'est propre et c'est exactement ce que je voulais. Merci à tous les deux!
a+
b.