Discussion :

[sovan]

Bonjour,

J'ai trouvé un scripte pour changer nom de poste pour Windows 7, mais à chaque fois quand j'ai lancer le scripte et bien il fait un retour Erreur 0
Je suis sur une session administrateur

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
		Function RenameHost(Name)
				dim WS
				Set WS = CreateObject("WScript.shell")
 
				Password = "" 
				Username = ""
 
				Set objWMIService = GetObject("Winmgmts:root\cimv2" )
 
				' Call always gets only one Win32_ComputerSystem object.
				For Each objComputer in _
					objWMIService.InstancesOf("Win32_ComputerSystem" )
 
						Return = objComputer.rename(Name,Password,Username)
						If Return <> 0 Then
						   Msgbox "Impossible de modifier le nom du poste en  "& Name &" "  & Err.Number
					  	exit Function
						Else
						   Msgbox "Le poste a été modifié en " & Name &_
							   " .Le nouveau nom sera effectif après un redéamarrage"
						WS.run "Shutdown /f /r -t 30"
						End If
				Next
		End Function

Avez vous d'autre idée pour un scripte de changement de nom ?

Merci à tous

[pitchalov]

Bonjour,

D'après la documentation de la méthode rename, les paramètres UserName et Password doivent être NULL, et non pas des chaines de caractère vide, pour ne pas envoyer de credentials.
De plus, il me semble normal que le numéro d'erreur soit 0, car c'est plutôt le code retour de la commande qu'il faudrait afficher, vu que c'est celui-ci qui est testé :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
Function RenameHost(Name)
	dim WS
	Set WS = CreateObject("WScript.shell")
 
	Password = NULL
	Username = NULL
 
	Set objWMIService = GetObject("Winmgmts:root\cimv2" )
 
	' Call always gets only one Win32_ComputerSystem object.
	For Each objComputer in _
		objWMIService.InstancesOf("Win32_ComputerSystem" )
		Return = objComputer.rename(Name,Password,Username)
		If Return <> 0 Then
			Msgbox "Impossible de modifier le nom du poste en  "& Name &" "  & Return
		Else
			Msgbox "Le poste a été modifié en " & Name &_
				" .Le nouveau nom sera effectif après un redéamarrage"
			WS.run "Shutdown /f /r -t 30"
		End If
	Next
End Function

Bonne continuation.