Discussion :

[Catarssis]

Bonjour,

J'ai un souci quand j'essai de copier/coller des lignes depuis une feuille vers une autre, une boite de dialog s'ouvre automatiquement apres chaque ligne, voici le code :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
 
Sub Incidents()
 
 
Dim i As Long
Dim iDest As Long
Dim Test As String
 
iDest = 2
 
'List les données feuil1
For j = 3 To 789
Sheets("Sites FM 2013").Select
Test = Range("A" & j).Text
Sheets("INCIDENT").Select
For i = 3 To Range("A:A").End(xlDown).Row
    If Range("F" & i) = Test Then
        Rows(i).Copy
        Sheets("Incidents Sites FMTK 2013").Range("A" & iDest).PasteSpecial
        iDest = iDest + 1
    End If
Next i
Next j
 
End Sub

Aidez moi s'il vous plait

[Marc-L]

Bonjour, bonjour,

la solution est certainement dans le message de la boite de dialogue, non ?

Il serait aussi vraiment judicieux de consulter l'aide de la méthode PasteSpecial
afin de corriger le code en ajoutant au moins un paramètre selon le besoin …

Lire aussi l'aide de la méthode Copy car elle pourrait suffire à elle seule sans recourir à PasteSpecial …

[Catarssis]

Bonjour,

tout d'abord je voudrai vous remercier pour votre réponse et votre réactivité ,

en fait la boite de dialg est une boite pour parcourir mon ordinateur et enregistrer une nouvelle copie de mon classeur, donc je ne pourrai pas avoir de réponse la dessus

Cordialement

[Marc-L]

Cela n'a donc alors aucun rapport avec le code présenté !

Avec autant d'imprécision, qui pourrait répondre sauf peut-être un génie (avec ou sans lampe …) ?!

[Catarssis]

Je dois préciser quoi à part que je suis sur Excel 2013 ?

Par ce que je n'ai jamais rencontré un problème pareil.

[Marc-L]

une boite de dialog s'ouvre automatiquement apres chaque ligne

« une boite de dialogue » : là on est vraiment bien avancé !

« après chaque ligne » : là aussi, c'est vraiment lumineux comme une nuit orageuse sans lune !

en fait la boite de dialg est une boite pour parcourir mon ordinateur et enregistrer une nouvelle copie de mon classeur

Où est donc le rapport avec le code présenté ?

Suivre le code en mode pas à pas (via la touche F8) afin d'indiquer le numéro de la ligne dans le code présenté
déclenchant « la boite de dialogue » …

Un bon code est sans Select car cela ralentit la procédure et fait clignoter l'écran …

[Catarssis]

Merci beaucoup pour votre aide, mais vos réponses pourrais être mieux sans ce sarcasme, les forums sont faits pour les débutants.

Merci de m'aider en étant objectif et sans mots qui n'ont rien à faire dans vos réponses ou ne pas le faire.

[mercatog]

On peut voir le problème autrement (je parle du code et non du message que tu as car comme insistait Marc_L, tes explications restent vagues et sans sarcasme je pense)

On peut bien sûr faire 2 boucles et copier les lignes correspondantes
On peut faire une boucle sur les lignes de Sites FM 2013 et faire des filtres automatiques sur INCIDENTS et reporter successivement les résultats des filtres
On peut copier l'ensemble des lignes et supprimer ceux ne répondant pas à ton critère
On peut aussi travailler avec des variables tableaux au cas d'un grand nombre de données
...etc (j'en oubli sûrement)

Je te propose une autre variante, une boucle accompagnée de la méthode Find ( regarde l'aide sur la méthode Find de l'objet Range, tu y trouves un exemple)

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
Option Explicit
 
Sub Incidents()
Dim Test As String, Prem As String
Dim j As Long, iDest As Long
Dim c As Range
 
Application.ScreenUpdating = False
iDest = 2
With Worksheets("INCIDENT")
    For j = 3 To 789
        Test = Worksheets("Sites FM 2013").Range("A" & j).Text
        If Test <> "" Then
            With .Range("F:F")
                Set c = .Find(Test, LookIn:=xlValues, LookAt:=xlWhole)
                If Not c Is Nothing Then
                    Prem = c.Address
                    Do
                        c.EntireRow.Copy Worksheets("Incidents Sites FMTK 2013").Range("A" & iDest)
                        iDest = iDest + 1
                        Set c = .FindNext(c)
                    Loop While Not c Is Nothing And c.Address <> Prem
                End If
            End With
        End If
    Next j
End With
End Sub

PS. Peut être je ne répond pas à ta question mais au cas où!