Discussion :

[fafabzh6]

Bonjour,

J'ai une table contenant une clé multiple : identifiant, entretien et résultat.
Je souhaite obtenir le max de la variable résultat pour chaque identifiant et entretien.

Ma table à la forme suivante :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
identifiant   entretien      resultat
1               1                5
1               1                2
1               1                4
1               2                2
1               2                1
2               1                3
2               1                1
2               2                2 
2               2                3

Je souhaite obtenir cette table

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
identifiant   entretien      resultat
1               1                5
1               2                2
2               1                3
2               2                3

Pour faire cette manipulation via une PROC SQL pas de problème, mais comment la faire avec uniquement une étape DATA ?

Merci

[p.pfeiffer]

Bonjour,

Vous pouvez le faire dans une étape data avec un retain .

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
data a ;
input identifiant   entretien      resultat;
cards ;
1               1                5
1               1                2
1               1                4
1               2                2
1               2                1
2               1                3
2               1                1
2               2                2 
2               2                3
;run;
 
 
data b(rename=(maxi=resultat));
set a ;
retain maxi;
by identifiant entretien;
if first.entretien then maxi= resultat ;
maxi=max(maxi,resultat) ;
if last.entretien ;
drop resultat;
run;

Il faut indiquer dans le by les 2 variables identifiant entretien et initialiser votre maximum avec la valeur de la première ligne de la variable entretien.

Cordialement, Pascal

[edward carnby]

Bonjour,

Vous pouvez le faire dans une étape data avec un retain .

Uniquement si les tables sont bien triées ....

Sinon, pourquoi pas une proc means tout simplement ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
proc means data=matable max;
class identifiant entretien;
var resultat;
output out=matable2 (where=(_type_=3) drop=_freq_) max=resultat;
run;

[fafabzh6]

C'est parfait !