Discussion :

[marlene65]

Bonjour,

Voilà mon problème sur Excel 2010 (Fichier Joint !!!) :

J'ai une colonne "Désignation" qui est extraite d'un progiciel. Le progiciel considère qu'il y a une phrase entière de désignation, mais moi je voudrai faire une colonne "Nature" indiquant le type de nature afin de pouvoir par la suite créer un TCD.

Pour cela j'ai crée une Base de donnée dans la feuille 1 appelée "Table".
Et j'aimerai dans ma feuille "Data" lorsque dans la colonne A, ligne 2 il y a marqué "Approvisionnement" dans la phrase "aaa bbb ccc Approvisionnement aaa bbb ccc", une formule me permettant en colonne B, ligne 2 d'avoir le type de nature "Approvisionnement" , etc....

Pour cela j'ai crée une formule :
=RECHERCHEV(data_s!A2;table!$A$1:$A$6;1;VRAI)

J'espère être clair....

exemple.xlsx

[papouclo]

Bonjour,
Ecrire en B2 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(INDEX(table!$B$2:$B$6;SOMMEPROD(NB.SI(A2:A2;"*"&table!$B$2:$B$6&"*")*(LIGNE(table!$B$2:$B$6)-1)));"")

et recopier vers le bas
Cordialement
Claude

[boisgontierjacques]

Bonsoir,

code =table!$B$2:$B$6


=INDEX(code;EQUIV(1;EQUIV("*"&code&"*";A2;0);0))
Valider avec maj+ctrl+entrée

Jacques Boisgontier

[marlene65]

Super je vous remercie de la rapidité de la réponse !

Par contre est-il possible d'avoir les explications afin de comprendre le fonctionnement Claude ?

Encore merci.

[marlene65]

Bonsoir Jacques Boisgontier,

Votre formule fonctionne aussi mais quand je supprime la colonne A de la feuille "Table" (car elle est inutile), elle ne fonctionne plus...
Pouvez-vous m'expliquer aussi votre formule ?

Merci

[boisgontierjacques]

http://boisgontierjacques.free.fr/fi.../Rechcode3.xls

Jacques Boisgontier

[marlene65]

J'ai parlé un peu vite ... Sur mon fichier source la formule devient incorrect dans certain cas particulier.

Je vous met un autre exemple pour le visualiser :
"Table 3" et "data 3"
exemple.xlsx

[papouclo]

Bonjour,
Je n'ai vu votre dernier exemple qu'hier soir.
Les erreurs pour le trosième exemple proviennent d'erreurs de "saisie" (voulues je pense); pour excel "M650" et "M 650" sont deux termes différents.
Mais cela a mis en évidence une erreur d'analyse que j'ai faite en répondant trop rapidement ; sans mettre de test, on risque d'avoir des surprises avec la fonction INDEX lorsqu'un des arguments
n° de ligne ou n° de colonne est zéro.
J'ai rectifié la formule de façon que la lecture dans la feuille data d'une chaine ne contenant aucun des éléments de la table de référence ne puisse pas renvoyer d'argument 0 mais un argument
trop grand pour avoir une réponse.
J'en ai profité pour donner un nom dynamique à cette table de référence au moyen de la fonction DECALER car je m'étais aperçu que dans votre troisième exemple, vous n'aviez pas modifié
la hauteur de la plage (A2:A6) dans laquelle on cherche à lire avec la fonction INDEX alors que cette nouvelle table (A2:A9) contenait 8 cellules au lieu de 5.
La plage de référence dans la feuille table a été nommée tableref et définie par :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=DECALER(table!$A$2;;;NBVAL(table!$A:$A)-1;1)

La formule en B2 dans la feuille data_s est une formule matricielle :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

=SIERREUR(INDEX(tableref;MIN(SI(NB.SI(A2:A2;"*"&tableref&"*")=1;LIGNE(tableref)-1;NBVAL(tableref)+1)));"")

à valider par Ctrl + Maj + Entrée et à recopier vers le bas.
Cordialement
Claude

[marlene65]

Super plus aucune erreur dans mon fichier source !
Merci beaucoup

Pourriez-vous m'expliquer la démarche, et la formule svp ?

Bonne journée