IdentifiantMot de passe
Loading...
Mot de passe oublié ?Je m'inscris ! (gratuit)
Navigation

Inscrivez-vous gratuitement
pour pouvoir participer, suivre les réponses en temps réel, voter pour les messages, poser vos propres questions et recevoir la newsletter

Macros et VBA Excel Discussion :

Sauvegarder le fichier sous un autre répertoire


Sujet :

Macros et VBA Excel

  1. #1
    Nouveau membre du Club
    Homme Profil pro
    Responsable Commercial
    Inscrit en
    Mars 2014
    Messages
    51
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 53
    Localisation : France

    Informations professionnelles :
    Activité : Responsable Commercial
    Secteur : Finance

    Informations forums :
    Inscription : Mars 2014
    Messages : 51
    Points : 30
    Points
    30
    Par défaut Sauvegarder le fichier sous un autre répertoire
    Bonjour,

    En faisant qq recherches en VBA, je tombe sur le code de la discussion "Macro pour sauvegarde multiples d'un même fichier", très bien adapté à ma problématique.
    J'aimerais connaitre la syntaxe pour sauvegarder le fichier sous un autre répertoire, et pas sous le même répertoire comme ici (ce qui permet d'isoler les fichiers de sauvegarde du fichier principal, et éviter aux utilisateurs d'ouvrir le mauvais fichier).
    Pouvez-vous m'aider SVP, je n' "Excel" pas encore comme vous en VBA.
    D'avance merci.

  2. #2
    Membre averti Avatar de arosec
    Homme Profil pro
    Chef de projet en SSII
    Inscrit en
    Mai 2009
    Messages
    167
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Localisation : France, Marne (Champagne Ardenne)

    Informations professionnelles :
    Activité : Chef de projet en SSII
    Secteur : High Tech - Éditeur de logiciels

    Informations forums :
    Inscription : Mai 2009
    Messages : 167
    Points : 324
    Points
    324
    Par défaut
    Bonjour,

    Ci-joint une macro qui automatise le "versionning" du fichier Excel.
    Les sauvegardes seront dans le dossier "backup" au même endroit que le fichier Excel d'origine.
    Il y aura une nouvelle version après chaque enregistrement.

    La macro doit être copiée dans l'objet ThisWorkbook

    Code : Sélectionner tout - Visualiser dans une fenêtre à part
    1
    2
    3
    4
    5
    6
    7
    8
    9
    10
    11
    12
    13
    14
    15
    16
    17
    18
    19
    20
    21
    22
    23
    24
    25
    26
    27
    28
    29
    30
    31
    32
    33
    34
    35
    36
     
    Option Explicit
     
    Private Sub Workbook_BeforeSave(ByVal SaveAsUI As Boolean, Cancel As Boolean)
        Cancel = True
        Application.EnableEvents = False
        Me.Save
        Call AfterSave
        Application.EnableEvents = True
    End Sub
     
    Sub AfterSave()
    Dim fso
    Dim fil
    Dim strNameOrig As String
    Dim strBackPath As String
    Dim strBackFile As String
     
      Set fso = CreateObject("Scripting.FileSystemObject")
     
      'Nom complet du fichier
      strNameOrig = fso.BuildPath(ThisWorkbook.Path, ThisWorkbook.Name)
     
      'Répertoire de sauvegarde
      strBackPath = fso.BuildPath(ThisWorkbook.Path, "backup")
      If Not fso.FolderExists(strBackPath) Then fso.CreateFolder strBackPath
     
      'Faire une sauvegarde du fichier après enregistrement
      Set fil = fso.GetFile(strNameOrig)
      strBackFile = Format(fil.DateLastModified, "yyyymmddhhmmss") & "_" & ThisWorkbook.Name
      fso.CopyFile strNameOrig, fso.BuildPath(strBackPath, strBackFile), True
      Set fil = Nothing
     
      Set fso = Nothing
     
    End Sub
    Cdlt.
    Les ordinateurs sont inutiles. Ils ne savent que donner des réponses.
    Pablo Picasso

  3. #3
    Nouveau membre du Club
    Homme Profil pro
    Responsable Commercial
    Inscrit en
    Mars 2014
    Messages
    51
    Détails du profil
    Informations personnelles :
    Sexe : Homme
    Âge : 53
    Localisation : France

    Informations professionnelles :
    Activité : Responsable Commercial
    Secteur : Finance

    Informations forums :
    Inscription : Mars 2014
    Messages : 51
    Points : 30
    Points
    30
    Par défaut
    Bonsoir,
    Je vous remercie vivement, votre code est impeccable.
    Cordialement.

+ Répondre à la discussion
Cette discussion est résolue.

Discussions similaires

  1. Réponses: 9
    Dernier message: 18/01/2007, 00h37
  2. Sauvegarde de fichiers sous Knoppix
    Par helter_skelter dans le forum Administration système
    Réponses: 4
    Dernier message: 08/05/2006, 22h05
  3. Sauvegarder un fichier sous...
    Par The Lord of Nesquik dans le forum C++
    Réponses: 12
    Dernier message: 22/04/2006, 23h51
  4. Réponses: 3
    Dernier message: 12/04/2006, 21h44
  5. Déplacer un fichier dans un autre répertoire
    Par t_om84 dans le forum Général Python
    Réponses: 2
    Dernier message: 16/05/2005, 10h36

Partager

Partager
  • Envoyer la discussion sur Viadeo
  • Envoyer la discussion sur Twitter
  • Envoyer la discussion sur Google
  • Envoyer la discussion sur Facebook
  • Envoyer la discussion sur Digg
  • Envoyer la discussion sur Delicious
  • Envoyer la discussion sur MySpace
  • Envoyer la discussion sur Yahoo