Discussion :

[clemclem2121]

J'ai besoin de quelque éclairage.

Je crée un module que j'appel ClePresente avec ce code

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
Function ClePresente(sSN As String) As Boolean
Dim strComputer As String, sReq As String, sClass As String
Dim objWMIService As Object, colItems As Object, objItem As Object
Dim sPnPid As String, bSNtrouve As Boolean
 
On Error GoTo ErrH
 
bSNtrouve = False
strComputer = "."
sClass = "Win32_DiskDrive"
sReq = "Select * from " & sClass
 
Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
Set colItems = objWMIService.ExecQuery(sReq)
 
If colItems.Count > 0 Then
   For Each objItem In colItems
       sPnPid = objItem.PNPDeviceID
       ' Teste si l'identificateur de disque contient le numéro
       ' de série recherché, après le 2e antislash
       If sPnPid Like "USB*\*\*" & sSN & "*" Then
          bSNtrouve = True
          Exit For
       End If
   Next
End If
 
ExitR:
    Set objItem = Nothing
    Set colItems = Nothing
    Set objWMIService = Nothing
    ' Valeur à retourner
    ClePresente = bSNtrouve
    Exit Function
 
ErrH:
    MsgBox "Erreur No." & Err.Number & ": " & Err.Description, vbExclamation
    Resume ExitR
End Function

Puis après sur mon formulaire de bienvenue je veux créer un bouton qui au clic cherchera la présence de la clé et qui ouvrira un autre formulaire et si la clé n'est pas présente il ferme l'application.

Qu'est ce que je fais de la partie

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
Dim sNumeroSerie As String
 
' Numéro de série disque USB recherché
sNumeroSerie = "AA000123465"
 
If ClePresente(sNumeroSerie) Then
   DoCmd.OpenForm(NOMform)
Else
   DoCmd.Quit
End If

[LedZeppII]

Bonjour,

Il faut remplacer "AA000123465" par le vrai numéro de série.

A+

[clemclem2121]

Oui j'ai bien compris qu'il fallait que je remplace le numero de serie mais ce dernier code est ce que je le met dans un nouveau module si oui comment l'appeller et aussi sur mon formulaire comment faire pour qu'au clic d'un bouton il execute ce code

[LedZeppII]

Bonjour,

Tu n'es pas obligé de mettre ce dernier bout de code dans un module.
Tu le mets dans la procédure événementielle de l'événement "Sur clic' de ton bouton.

Si ton bouton s'appelle cmdValiderCle, tu auras cette procédure événementielle (dans le module de code du formulaire):

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
Private Sub cmdValiderCle_Click()

End Sub

Il suffit d'insérer le code dans le corps de la procédure:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
Private Sub cmdValiderCle_Click()
Dim sNumeroSerie As String
 
' Numéro de série disque USB recherché
sNumeroSerie = "AA000123465"
 
If ClePresente(sNumeroSerie) Then
   DoCmd.OpenForm(NOMform)
Else
   DoCmd.Quit
End If
End Sub

A+

[clemclem2121]

Haaaa enfin j'y suis arrivé grâce à vous tous. Un grand merci je clos cette discussion.