Discussion :

[WDKyle]

Bonsoir,

Dans mon application, je souhaite que l'on puisse utiliser une base de données locale en HF Classic ou alors serveur en HF C/S.

J'ai donc créer une procédure que voici :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
HGèreREP(Faux)
 
SI Config_BDD:p_Mode = 1 ALORS
	// CONNEXION A LA BASE DE DONNEES HYPERFILESQL CLASSIC (LOCALE)
	fRepCrée(Config_Donnees:p_Dossier_Local + "\Donnees")
	HChangeRep("*", Config_Donnees:p_Dossier_Local + "\Donnees")
SINON
	// CONNEXION A LA BASE DE DONNEES HYPERFILESQL C/S (SERVEUR)
	Connexion_HFSQL..Provider = hAccèsHFClientServeur
	Connexion_HFSQL..Utilisateur = Config_BDD:p_Utilisateur
	Connexion_HFSQL..MotDePasse = Config_BDD:p_Motdepasse
	Connexion_HFSQL..Serveur = Config_BDD:p_Serveur + ":" + Config_BDD:p_Port
	Connexion_HFSQL..BaseDeDonnées = Config_BDD:p_Base
	Connexion_HFSQL..Cryptage = hCryptageStandard
 
	HOuvreConnexion(Connexion_HFSQL)
	HChangeConnexion("*", Connexion_HFSQL)
FIN
 
// CREATION DES FICHIERS DE DONNEES
HCréationSiInexistant("*")

Par défaut, au premier lancement l'application utilise HF Classic et crée donc les fichiers de données en locale. Tout est ok à ce stade !

Ça coince au moment de changer l'accès en HF C/S et j'ai une erreur sur HCréationSiInexistant("*") que voici :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
 
Erreur à la ligne 35 du traitement Procédure globale BDD_Connexion.
Vous avez appelé la fonction HCréationSiInexistant.
Erreur renvoyée par le serveur <Damien-7.lan:4900> :
Vous avez spécifié le chemin <C:\ProgramData\Applications WinDev\MON_APPLI_XXX\Donnees\> dans l'analyse ou via un HChangeRep. L'utilisation d'un chemin absolu est interdit. Vous devez spécifier un chemin relatif à la base de données <RU-Gestion-XXX>.

Cette procédure est lancé au démarrage de l'application sans soucis mais lorsque je souhaite changer "à la volée" l'accès à la base de données, bim erreur

Une idée svp ?

Merci !

[Yusep]

Bonsoir
Avant de changer de conexion, teste:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
 
SI HOuvreConnexion(Connexion_HFSQL) = Vrai ALORS
    INFO("OK")
SINON
    HErreurInfo()
FIN

[WDKyle]

J'ai testé, et j'ai OK... Donc ça ne viens pas de la ?

[Yusep]

Je me souviens avoir eu le même problème et le résoudre en fermant la conexion antérieure.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

HFermeConnexion(sConexion)

[WDKyle]

Le soucis, c'est que je ne suis pas encore connecté...

J'ai fait les tests dans le sens Classic > C/S

EDIT : Je viens d'essayer un HFermeConnexion(Connexion_HFSQL) tout en haut dans mon code et j'ai toujours le souci

[hpascal]

Bonsoir

J'ai survolé vite fait le message mais essaye de faire une annulation du HChangeRep quand tu passes en C/S

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

HChangeRep("*", "")

[WDKyle]

D'accord, j'essai ca demain et je vous tiens au courant.

Bonne soiree

[hpascal]

Re

Je viens de faire un test vite fait avec une base HF C/S qui contient un fichier "Article". J'ai le même fichier en HF Classic mais qui ne contient pas le même nombre d'enregistrements (pour le test)

Je teste à partir de 2 boutons :

Bouton 1 :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
HFermeConnexion(gcnxHFCS)
HChangeConnexion("*","")
HChangeRep("*", fRepExe() + "\fic")
Info(HNbEnr(Article))

Bouton 2

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
gcnxHFCS..Provider = hAccèsHFClientServeur
gcnxHFCS..Serveur = "localhost"
gcnxHFCS..Utilisateur = "admin"
gcnxHFCS..MotDePasse = "monmotdepasse"
gcnxHFCS..BaseDeDonnées = "MaBase"
 
HChangeRep("*","")
HChangeConnexion("*",gcnxHFCS)
SI HOuvreConnexion(gcnxHFCS) ALORS
	Info(HNbEnr(Article))
SINON
	Erreur(HErreurInfo())
FIN

En complément de mon message précédent il faut ajouter HChangeConnexion("*","") lorsque tu actives l'accès HF Classic

Je passe de l'un à l'autre sans problème

[WDKyle]

Bonjour,

D'accord, donc il faut "désactiver" l'ancien mode avant de passé à l'autre en fait

Merci pour ton aide hpascal

[hpascal]

A noter que pour l'exemple j'ai mis les propriétés de la connexion HF C/S (globale) dans le bouton mais il faut le faire ailleurs et une seule fois

[WDKyle]

Je l'ai une seule fois dans ma procédure BDD_Connexion mais la connexion est déclarée dans le code du projet.

EDIT : Ca fonctionne nikel ! Merci