Discussion :

[Claude_Azoulai]

Bonjour et bonne année à tous
Je travaille sous Visual Studio 2012 et voudrais créer un menu contextuel sur un PictureBox.
J'ai trouvé un début d'exemple en C# que j'ai modifié en VB.
Quand j'effectue un clic droit sue ce contrôle, j'ai bien un menu avec trois items.
Mon problème : Comment déclencher une routine avec un clic gauhe sur chacun des trois items ?

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
 
    Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        Dim contextMenu1 As ContextMenu
        contextMenu1 = New ContextMenu()
        Dim menuItem1 As MenuItem
        menuItem1 = New MenuItem()
        Dim menuItem2 As MenuItem
        menuItem2 = New MenuItem()
        Dim menuItem3 As MenuItem
        menuItem3 = New MenuItem()
 
        contextMenu1.MenuItems.AddRange(New MenuItem() {menuItem1, menuItem2, menuItem3})
        menuItem1.Index = 0
        menuItem1.Text = "MenuItem1"
        menuItem2.Index = 1
        menuItem2.Text = "MenuItem2"
        menuItem3.Index = 2
        menuItem3.Text = "MenuItem3"
 
        PictureBox1.ContextMenu = contextMenu1
 
    End Sub

Merci de votre aide.

Claude Azoulai

[Paul Van Walleghem]

Une des solutions est que tu déclares tes variables avec la clause WithEvents et, ensuite, tu déclares tes Sub avec la clause Handle. Comme dans l'exemple ci-dessous pour un ToolStripButton.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
 
    Dim WithEvents oToolStripButtonRotDroite As New System.Windows.Forms.ToolStripButton
 
    Private Sub oToolStripButtonRotDroite_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) _
                Handles oToolStripButtonRotDroite.Click
 
End Sub

Bonne année!

[rv26t]

Bonjour,

Pour chaque élément du menu il faut associer un évènement à une procédure qui sert de gestionnaire d'évènement.

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
    Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        Dim contextMenu1 As ContextMenu = New ContextMenu()
        Dim menuItem1 As MenuItem = New MenuItem()
        menuItem1.Index = 0
        menuItem1.Text = "MenuItem1"
        AddHandler menuItem1.Click, AddressOf MC1_Click
        Dim menuItem2 As MenuItem = New MenuItem()
        menuItem2.Index = 1
        menuItem2.Text = "MenuItem2"
        AddHandler menuItem2.Click, AddressOf MC2_Click
        Dim menuItem3 As MenuItem = New MenuItem()
        menuItem3.Index = 2
        menuItem3.Text = "MenuItem3"
        AddHandler menuItem3.Click, AddressOf MC3_Click
        contextMenu1.MenuItems.AddRange(New MenuItem() {menuItem1, menuItem2, menuItem3})
        PictureBox1.ContextMenu = contextMenu1
    End Sub
    ' Les procédures liées aux évènements.
    Sub MC1_Click()
        MessageBox.Show("clic sur menu 1 ")
    End Sub
    Sub MC2_Click()
        MessageBox.Show("clic sur menu 2 ")
    End Sub
    Sub MC3_Click()
        MessageBox.Show("clic sur menu 3 ")
    End Sub

[Paul Van Walleghem]

Oui. Les deux techniques reviennent au même. Non?

[MABROUKI]

bonjour

tu peux faire comme ceci si tout est fait par code:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
 
Public Class Form1
 
    Private Sub Form1_Load(ByVal sender As Object, ByVal e As System.EventArgs) Handles Me.Load
        Dim contextMenu1 As ContextMenu
        contextMenu1 = New ContextMenu()
        Dim menuItem1 As MenuItem
        menuItem1 = New MenuItem()
        Dim menuItem2 As MenuItem
        menuItem2 = New MenuItem()
        Dim menuItem3 As MenuItem
        menuItem3 = New MenuItem()
 
        contextMenu1.MenuItems.AddRange(New MenuItem() {menuItem1, menuItem2, menuItem3})
        menuItem1.Index = 0
        menuItem1.Text = "MenuItem1"
        menuItem2.Index = 1
        menuItem2.Text = "MenuItem2"
        menuItem3.Index = 2
        menuItem3.Text = "MenuItem3"
        For Each item As MenuItem In contextMenu1.MenuItems
            AddHandler item.Click, AddressOf item_Click
        Next
 
 
        PictureBox1.ContextMenu = contextMenu1
        Me.ContextMenu = contextMenu1
 
    End Sub
 
    Private Sub item_Click(ByVal sender As Object, ByVal e As System.EventArgs)
        Dim ctl As MenuItem = CType(sender, MenuItem)
        Dim ctxMenu As ContextMenu = CType(ctl.Parent, ContextMenu)
        MessageBox.Show(ctl.Text & ctxMenu.SourceControl.Name)
        If ctxMenu.SourceControl Is PictureBox1 Then
            OnMenuPic(ctl.Index)
        ElseIf ctxMenu.SourceControl Is Me Then
            OnMenuFrm(ctl.Index)
 
        End If
 
    End Sub
    Private Sub OnMenuPic(ByVal index As Integer)
            Select Case index
                Case 0
                MessageBox.Show("index" & index.ToString & " =>pic")
                Case 1
                MessageBox.Show("index" & index.ToString & " =>pic")
                Case 2
                MessageBox.Show("index" & index.ToString & " =>pic")
            End Select
 
 
    End Sub
    Private Sub OnMenuFrm(ByVal index As Integer)
 
        Select Case index
            Case 0
                MessageBox.Show("index" & index.ToString & " =>form")
            Case 1
                MessageBox.Show("index" & index.ToString & " =>form")
            Case 2
                MessageBox.Show("index" & index.ToString & " =>form")
        End Select
 
 
    End Sub
End Class

Ou bien:
utilises la declaration WithEvents au niveau form et la clause Handles,tout depend du besoin......

[Claude_Azoulai]

Merci à vous tous.
Tous vos exemples sont intéressants et mènent à la solution de mon problème, qui n'en n'est plus un.
J'ai choisi (car j'avais le choix), la solution de rv26t qui nécessite le moins d'écriture, à mon avis.
A 80 ans, j'essaie d'être le plus concis possible.
En tous les cas, vous m'avez bien aidé.

Claude Azoulai

[Paul Van Walleghem]

C'était un plaisir.