Discussion :

[plambert123]

Bonjour,

J'ai un champ table qui est chargé par programmation selon que je sélectionne une semaine ou une date de début et de fin.

Le code utilisé pour chargé le champ table est le suivant:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
PROCEDURE Remplir_Planification_Vernis()
 
I est un entier
I = 1
 
TableSupprimeTout(TABLE_Planif_Vernis)
TableSupprimeTout(TABLE_Planif_VernisRV)
 
Sablier(Vrai)
 
HExécuteRequête(REQ_QuantitéEnCommande,hRequêteDéfaut,SAI_DateDébut,SAI_DateFin)
HLitPremier(REQ_QuantitéEnCommande)
TANTQUE PAS HEnDehors(REQ_QuantitéEnCommande)
	HLitRecherchePremier(SW00SX005,stocknumber,REQ_QuantitéEnCommande.stockordered)
	SI HTrouve(SW00SX005) ALORS
		TableAjouteLigne(TABLE_Planif_Vernis)
		TABLE_Planif_Vernis.COL_Couleur[I] = SW00SX005.couleurdesc
		TABLE_Planif_Vernis.COL_Essence[I] = SW00SX005.essence
		TABLE_Planif_Vernis.COL_Grade[I] = SW00SX005.grade
		TABLE_Planif_Vernis.COL_Largeur[I] = SW00SX005.largeur
		TABLE_Planif_Vernis.COL_QtéRequise[I] = REQ_QuantitéEnCommande.la_somme_quantityordered - REQ_QuantitéEnCommande.la_somme_qtycanceled
		TABLE_Planif_Vernis.COL_NuméroStock[I] = REQ_QuantitéEnCommande.stockordered
		TABLE_Planif_Vernis.COL_Type[I] = SW00SX005.recordtype
		TABLE_Planif_Vernis.COL_Source[I] = SW00SX005.sourcepf
		HLitRecherchePremier(SW00XX099,stocknumber,REQ_QuantitéEnCommande.stockordered)
		SI HTrouve(SW00XX099) ALORS
			TABLE_Planif_Vernis.COL_QtéProduire[I] = SW00XX099.QtéProduire
			TABLE_Planif_Vernis.COL_Commentaire[I] = SW00XX099.Commentaire
		SINON
			TABLE_Planif_Vernis.COL_QtéProduire[I] = ""
			TABLE_Planif_Vernis.COL_Commentaire[I] = ""
		FIN
		HLitRecherchePremier(SW00XD031,recordkey,SW00SX005.recordkey)
		SI HTrouve(SW00XD031) ALORS
			TABLE_Planif_Vernis.COL_��paisseur[I] = SW00XD031.epaisseur
			TABLE_Planif_Vernis.COL_Boite[I] = SW00XD031.codeboite
			TABLE_Planif_Vernis.COL_QtéBoite[I] = (REQ_QuantitéEnCommande.la_somme_quantityordered - REQ_QuantitéEnCommande.la_somme_qtycanceled) / SW00XD031.piedparboite
			TABLE_Planif_Vernis.COL_Gloss[I] = SW00XD031.gloss
		FIN
		HLitRecherchePremier(SW00XD040,recordkey,SW00SX005.recordkey)
		SI HTrouve(SW00XD040) ALORS
			TABLE_Planif_Vernis.COL_Teinture[I] = SW00XD040.teinturecode
			TABLE_Planif_Vernis.COL_Intensité[I] = SW00XD040.teintintensite
		FIN
	FIN
	I = I + 1
	HLitSuivant(REQ_QuantitéEnCommande)
FIN

Mon problème est le suivant:

À ma première sélection tout se passe bien mon champ table est chargé.

Cependant si je fait une seconde sélection toutes les lignes du champ table sont à blanc sauf la dernière qui correspond au dernier record lu.

Si je roule mon programme étape par étape je vois la ligne 1 dans mon champ table.
Lorsque je continue pour la ligne 2 la ligne 1 est mis à blanc et la ligne 2 s'affiche et ainsi de suite jusqu'à la fin.

Merci pour votre aide.

Bonne fin de journée

[hpascal]

Bonjour

Un petit conseil pour commencer : au lieu d'incrémenter I à la main, avec le risque de le faire au mauvais moment ou au mauvais endroit tu peux faire ça :

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

I = TableAjouteLigne(TABLE_Planif_Vernis)

comme ça tu seras toujours sur que correspond bien à la nouvelle ligne ajoutée (pense bien sur à enlever ton incrémentation manuelle)

Dans ton exemple tu incrémentes I même si la ligne n'est pas ajoutée dans la table (si SW00SX005 n'est pas trouvé)

Autre chose : ne peux tu pas faire une jointure avec SW00SX005 dans ta requête initiale ? ça simplifierait les choses
Idem pour les autres fichiers

[laurent30s]

Ton problème doit provenir entre l'incrémentation du I et le TableAjouteLigne() qui doivent se mélanger les pinceaux.

J'aurais tendance à faire plutôt quelque chose qui ressemblerait à ça...

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
nQtéProduire,nEpaisseur,nQtéBoite,nIntensité sont des entiers
sCommentaire,sCodeBoite,sGloss,sTeinture sont des chaînes
 
TableSupprimeTout(TABLE_Planif_Vernis)
TableSupprimeTout(TABLE_Planif_VernisRV)
 
Sablier(Vrai)
 
HExécuteRequête(REQ_QuantitéEnCommande,hRequêteDéfaut,SAI_DateDébut,SAI_DateFin)
HLitPremier(REQ_QuantitéEnCommande)
TANTQUE PAS HEnDehors(REQ_QuantitéEnCommande)
	HLitRecherchePremier(SW00SX005,stocknumber,REQ_QuantitéEnCommande.stockordered)
	SI HTrouve(SW00SX005) ALORS
		HLitRecherchePremier(SW00XX099,stocknumber,REQ_QuantitéEnCommande.stockordered)
		SI HTrouve(SW00XX099) ALORS
			nQtéProduire = SW00XX099.QtéProduire
			sCommentaire = SW00XX099.Commentaire
		SINON
			nQtéProduire = 0
			sCommentaire = ""
		FIN
		HLitRecherchePremier(SW00XD031,recordkey,SW00SX005.recordkey)
		SI HTrouve(SW00XD031) ALORS
			nEpaisseur = SW00XD031.epaisseur
			sCodeBoite = SW00XD031.codeboite
			nQtéBoite  = (REQ_QuantitéEnCommande.la_somme_quantityordered - REQ_QuantitéEnCommande.la_somme_qtycanceled) / SW00XD031.piedparboite
			sGloss     = SW00XD031.gloss
		SINON
			nEpaisseur = 0
			sCodeBoite = ""
			nQtéBoite  = 0
			sGloss     = ""
		FIN
		HLitRecherchePremier(SW00XD040,recordkey,SW00SX005.recordkey)
		SI HTrouve(SW00XD040) ALORS
			sTeinture = SW00XD040.teinturecode
			nIntensité = SW00XD040.teintintensite
		SINON
			sTeinture  = ""
			nIntensité = 0
		FIN
 
		TableAjouteLigne(TABLE_Planif_Vernis,SW00SX005.couleurdesc, ...
							SW00SX005.essence, ...
							SW00SX005.grade, ...
							SW00SX005.largeur, ...
							REQ_QuantitéEnCommande.la_somme_quantityordered - REQ_QuantitéEnCommande.la_somme_qtycanceled, ...
							REQ_QuantitéEnCommande.stockordered, ...
							SW00SX005.recordtype, ...
							SW00SX005.sourcepf, ...
							nQtéProduire, ...
							sCommentaire, ...
							sCodeBoite, ...
							nQtéBoite, ...
							sGloss, ...
							sTeinture, ...
							nIntensité)
	FIN
	HLitSuivant(REQ_QuantitéEnCommande)
FIN

A toi te voir pour les types de variables, sans précision j'ai fais comme je l'ai senti...

Autre chose importante l'ordre des colonnes dans le TableAjouteLigne() est important.
Pareil, là j'ai les valeurs dans qu'elles apparaissent dans la boucle, à toi de faire correspondre les valeurs avec les bonnes colonnes...

[digi12]

bonjour

le coup classique des tris

ne pas oublier de faire un tabletri(nomdelatable,faux) après le tablesupprimetout pour les 2 tables

bon devs

[plambert123]

Bonjour,

J'ai résolu mon problème en suivant la suggestion suivante:

Code :

Sélectionner tout - Visualiser dans une fenêtre à part

I = TableAjouteLigne(Table_Planif_Vernis)

Merci à ceux qui ont pris le temps de me répondre.

Bonne fin de journée